sys/amd64/amd64/locore.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  *      from: @(#)locore.s      7.3 (Berkeley) 5/13/91
  37  * $FreeBSD$
  38  *
  39  *              originally from: locore.s, by William F. Jolitz
  40  *
  41  *              Substantially rewritten by David Greenman, Rod Grimes,
  42  *                      Bruce Evans, Wolfgang Solfrank, Poul-Henning Kamp
  43  *                      and many others.
  44  */
  45
  46 #include "opt_bootp.h"
  47 #include "opt_ddb.h"
  48 #include "opt_nfsroot.h"
  49 #include "opt_userconfig.h"
  50
  51 #include <sys/syscall.h>
  52 #include <sys/reboot.h>
  53
  54 #include <machine/asmacros.h>
  55 #include <machine/cputypes.h>
  56 #include <machine/psl.h>
  57 #include <machine/pmap.h>
  58 #include <machine/specialreg.h>
  59
  60 #include "assym.s"
  61
  62 /*
  63  *      XXX
  64  *
  65  * Note: This version greatly munged to avoid various assembler errors
  66  * that may be fixed in newer versions of gas. Perhaps newer versions
  67  * will have more pleasant appearance.
  68  */
  69
  70 /*
  71  * PTmap is recursive pagemap at top of virtual address space.
  72  * Within PTmap, the page directory can be found (third indirection).
  73  */
  74         .globl  _PTmap,_PTD,_PTDpde
  75         .set    _PTmap,(PTDPTDI << PDRSHIFT)
  76         .set    _PTD,_PTmap + (PTDPTDI * PAGE_SIZE)
  77         .set    _PTDpde,_PTD + (PTDPTDI * PDESIZE)
  78
  79 /*
  80  * APTmap, APTD is the alternate recursive pagemap.
  81  * It's used when modifying another process's page tables.
  82  */
  83         .globl  _APTmap,_APTD,_APTDpde
  84         .set    _APTmap,APTDPTDI << PDRSHIFT
  85         .set    _APTD,_APTmap + (APTDPTDI * PAGE_SIZE)
  86         .set    _APTDpde,_PTD + (APTDPTDI * PDESIZE)
  87
  88 /*
  89  * Globals
  90  */
  91         .data
  92         ALIGN_DATA              /* just to be sure */
  93
  94         .globl  HIDENAME(tmpstk)
  95         .space  0x2000          /* space for tmpstk - temporary stack */
  96 HIDENAME(tmpstk):
  97
  98         .globl  _boothowto,_bootdev
  99
 100         .globl  _cpu,_cpu_vendor,_cpu_id,_bootinfo
 101         .globl  _cpu_high, _cpu_feature
 102
 103 _cpu:           .long   0                       /* are we 386, 386sx, or 486 */
 104 _cpu_id:        .long   0                       /* stepping ID */
 105 _cpu_high:      .long   0                       /* highest arg to CPUID */
 106 _cpu_feature:   .long   0                       /* features */
 107 _cpu_vendor:    .space  20                      /* CPU origin code */
 108 _bootinfo:      .space  BOOTINFO_SIZE           /* bootinfo that we can handle */
 109
 110 _KERNend:       .long   0                       /* phys addr end of kernel (just after bss) */
 111 physfree:       .long   0                       /* phys addr of next free page */
 112
 113 #ifdef SMP
 114                 .globl  _cpu0prvpage
 115 cpu0pp:         .long   0                       /* phys addr cpu0 private pg */
 116 _cpu0prvpage:   .long   0                       /* relocated version */
 117
 118                 .globl  _SMPpt
 119 SMPptpa:        .long   0                       /* phys addr SMP page table */
 120 _SMPpt:         .long   0                       /* relocated version */
 121 #endif /* SMP */
 122
 123         .globl  _IdlePTD
 124 _IdlePTD:       .long   0                       /* phys addr of kernel PTD */
 125
 126 #ifdef SMP
 127         .globl  _KPTphys
 128 #endif
 129 _KPTphys:       .long   0                       /* phys addr of kernel page tables */
 130
 131         .globl  _proc0paddr
 132 _proc0paddr:    .long   0                       /* address of proc 0 address space */
 133 p0upa:          .long   0                       /* phys addr of proc0's UPAGES */
 134
 135 vm86phystk:     .long   0                       /* PA of vm86/bios stack */
 136
 137         .globl  _vm86paddr, _vm86pa
 138 _vm86paddr:     .long   0                       /* address of vm86 region */
 139 _vm86pa:        .long   0                       /* phys addr of vm86 region */
 140
 141 #ifdef BDE_DEBUGGER
 142         .globl  _bdb_exists                     /* flag to indicate BDE debugger is present */
 143 _bdb_exists:    .long   0
 144 #endif
 145
 146 #ifdef PC98
 147         .globl  _pc98_system_parameter
 148 _pc98_system_parameter:
 149         .space  0x240
 150 #endif
 151
 152 /**********************************************************************
 153  *
 154  * Some handy macros
 155  *
 156  */
 157
 158 #define R(foo) ((foo)-KERNBASE)
 159
 160 #define ALLOCPAGES(foo) \
 161         movl    R(physfree), %esi ; \
 162         movl    $((foo)*PAGE_SIZE), %eax ; \
 163         addl    %esi, %eax ; \
 164         movl    %eax, R(physfree) ; \
 165         movl    %esi, %edi ; \
 166         movl    $((foo)*PAGE_SIZE),%ecx ; \
 167         xorl    %eax,%eax ; \
 168         cld ; \
 169         rep ; \
 170         stosb
 171
 172 /*
 173  * fillkpt
 174  *      eax = page frame address
 175  *      ebx = index into page table
 176  *      ecx = how many pages to map
 177  *      base = base address of page dir/table
 178  *      prot = protection bits
 179  */
 180 #define fillkpt(base, prot)               \
 181         shll    $2,%ebx                 ; \
 182         addl    base,%ebx               ; \
 183         orl     $PG_V,%eax              ; \
 184         orl     prot,%eax               ; \
 185 1:      movl    %eax,(%ebx)             ; \
 186         addl    $PAGE_SIZE,%eax         ; /* increment physical address */ \
 187         addl    $4,%ebx                 ; /* next pte */ \
 188         loop    1b
 189
 190 /*
 191  * fillkptphys(prot)
 192  *      eax = physical address
 193  *      ecx = how many pages to map
 194  *      prot = protection bits
 195  */
 196 #define fillkptphys(prot)                 \
 197         movl    %eax, %ebx              ; \
 198         shrl    $PAGE_SHIFT, %ebx       ; \
 199         fillkpt(R(_KPTphys), prot)
 200
 201         .text
 202 /**********************************************************************
 203  *
 204  * This is where the bootblocks start us, set the ball rolling...
 205  *
 206  */
 207 NON_GPROF_ENTRY(btext)
 208
 209 #ifdef PC98
 210         /* save SYSTEM PARAMETER for resume (NS/T or other) */
 211         movl    $0xa1400,%esi
 212         movl    $R(_pc98_system_parameter),%edi
 213         movl    $0x0240,%ecx
 214         cld
 215         rep
 216         movsb
 217 #else   /* IBM-PC */
 218 #ifdef BDE_DEBUGGER
 219 #ifdef BIOS_STEALS_3K
 220         cmpl    $0x0375c339,0x95504
 221 #else
 222         cmpl    $0x0375c339,0x96104     /* XXX - debugger signature */
 223 #endif
 224         jne     1f
 225         movb    $1,R(_bdb_exists)
 226 1:
 227 #endif
 228 #endif  /* PC98 */
 229
 230 /* Tell the bios to warmboot next time */
 231         movw    $0x1234,0x472
 232
 233 /* Set up a real frame in case the double return in newboot is executed. */
 234         pushl   %ebp
 235         movl    %esp, %ebp
 236
 237 /* Don't trust what the BIOS gives for eflags. */
 238         pushl   $PSL_KERNEL
 239         popfl
 240
 241 /*
 242  * Don't trust what the BIOS gives for %fs and %gs.  Trust the bootstrap
 243  * to set %cs, %ds, %es and %ss.
 244  */
 245         mov     %ds, %ax
 246         mov     %ax, %fs
 247         mov     %ax, %gs
 248
 249         call    recover_bootinfo
 250
 251 /* Get onto a stack that we can trust. */
 252 /*
 253  * XXX this step is delayed in case recover_bootinfo needs to return via
 254  * the old stack, but it need not be, since recover_bootinfo actually
 255  * returns via the old frame.
 256  */
 257         movl    $R(HIDENAME(tmpstk)),%esp
 258
 259 #ifdef PC98
 260         /* pc98_machine_type & M_EPSON_PC98 */
 261         testb   $0x02,R(_pc98_system_parameter)+220
 262         jz      3f
 263         /* epson_machine_id <= 0x0b */
 264         cmpb    $0x0b,R(_pc98_system_parameter)+224
 265         ja      3f
 266
 267         /* count up memory */
 268         movl    $0x100000,%eax          /* next, talley remaining memory */
 269         movl    $0xFFF-0x100,%ecx
 270 1:      movl    0(%eax),%ebx            /* save location to check */
 271         movl    $0xa55a5aa5,0(%eax)     /* write test pattern */
 272         cmpl    $0xa55a5aa5,0(%eax)     /* does not check yet for rollover */
 273         jne     2f
 274         movl    %ebx,0(%eax)            /* restore memory */
 275         addl    $PAGE_SIZE,%eax
 276         loop    1b
 277 2:      subl    $0x100000,%eax
 278         shrl    $17,%eax
 279         movb    %al,R(_pc98_system_parameter)+1
 280 3:
 281 #endif
 282
 283         call    identify_cpu
 284
 285 /* clear bss */
 286 /*
 287  * XXX this should be done a little earlier.
 288  *
 289  * XXX we don't check that there is memory for our bss and page tables
 290  * before using it.
 291  *
 292  * XXX the boot program somewhat bogusly clears the bss.  We still have
 293  * to do it in case we were unzipped by kzipboot.  Then the boot program
 294  * only clears kzipboot's bss.
 295  *
 296  * XXX the gdt and idt are still somewhere in the boot program.  We
 297  * depend on the convention that the boot program is below 1MB and we
 298  * are above 1MB to keep the gdt and idt  away from the bss and page
 299  * tables.  The idt is only used if BDE_DEBUGGER is enabled.
 300  */
 301         movl    $R(_end),%ecx
 302         movl    $R(_edata),%edi
 303         subl    %edi,%ecx
 304         xorl    %eax,%eax
 305         cld
 306         rep
 307         stosb
 308
 309         call    create_pagetables
 310
 311 /*
 312  * If the CPU has support for VME, turn it on.
 313  */
 314         testl   $CPUID_VME, R(_cpu_feature)
 315         jz      1f
 316         movl    %cr4, %eax
 317         orl     $CR4_VME, %eax
 318         movl    %eax, %cr4
 319 1:
 320
 321 #ifdef BDE_DEBUGGER
 322 /*
 323  * Adjust as much as possible for paging before enabling paging so that the
 324  * adjustments can be traced.
 325  */
 326         call    bdb_prepare_paging
 327 #endif
 328
 329 /* Now enable paging */
 330         movl    R(_IdlePTD), %eax
 331         movl    %eax,%cr3                       /* load ptd addr into mmu */
 332         movl    %cr0,%eax                       /* get control word */
 333         orl     $CR0_PE|CR0_PG,%eax             /* enable paging */
 334         movl    %eax,%cr0                       /* and let's page NOW! */
 335
 336 #ifdef BDE_DEBUGGER
 337 /*
 338  * Complete the adjustments for paging so that we can keep tracing through
 339  * initi386() after the low (physical) addresses for the gdt and idt become
 340  * invalid.
 341  */
 342         call    bdb_commit_paging
 343 #endif
 344
 345         pushl   $begin                          /* jump to high virtualized address */
 346         ret
 347
 348 /* now running relocated at KERNBASE where the system is linked to run */
 349 begin:
 350         /* set up bootstrap stack */
 351         movl    _proc0paddr,%esp        /* location of in-kernel pages */
 352         addl    $UPAGES*PAGE_SIZE,%esp  /* bootstrap stack end location */
 353         xorl    %eax,%eax                       /* mark end of frames */
 354         movl    %eax,%ebp
 355         movl    _proc0paddr,%eax
 356         movl    _IdlePTD, %esi
 357         movl    %esi,PCB_CR3(%eax)
 358
 359         movl    physfree, %esi
 360         pushl   %esi                            /* value of first for init386(first) */
 361         call    _init386                        /* wire 386 chip for unix operation */
 362         popl    %esi
 363
 364         .globl  __ucodesel,__udatasel
 365
 366         pushl   $0                              /* unused */
 367         pushl   __udatasel                      /* ss */
 368         pushl   $0                              /* esp - filled in by execve() */
 369         pushl   $PSL_USER                       /* eflags (IOPL 0, int enab) */
 370         pushl   __ucodesel                      /* cs */
 371         pushl   $0                              /* eip - filled in by execve() */
 372         subl    $(13*4),%esp                    /* space for rest of registers */
 373
 374         pushl   %esp                            /* call main with frame pointer */
 375         call    _mi_startup                     /* autoconfiguration, mountroot etc */
 376
 377         hlt             /* never returns to here */
 378
 379 /*
 380  * When starting init, call this to configure the process for user
 381  * mode.  This will be inherited by other processes.
 382  */
 383 NON_GPROF_ENTRY(prepare_usermode)
 384         /*
 385          * Now we've run main() and determined what cpu-type we are, we can
 386          * enable write protection and alignment checking on i486 cpus and
 387          * above.
 388          */
 389 #if defined(I486_CPU) || defined(I586_CPU) || defined(I686_CPU)
 390         cmpl    $CPUCLASS_386,_cpu_class
 391         je      1f
 392         movl    %cr0,%eax                       /* get control word */
 393         orl     $CR0_WP|CR0_AM,%eax             /* enable i486 features */
 394         movl    %eax,%cr0                       /* and do it */
 395 1:
 396 #endif
 397         /*
 398          * on return from main(), we are process 1
 399          * set up address space and stack so that we can 'return' to user mode
 400          */
 401         movl    __ucodesel,%eax
 402         movl    __udatasel,%ecx
 403
 404 #if 0   /* ds/es/fs are in trap frame */
 405         movl    %cx,%ds
 406         movl    %cx,%es
 407         movl    %cx,%fs
 408 #endif
 409         movl    %cx,%gs                         /* and ds to gs */
 410         ret                                     /* goto user! */
 411
 412
 413 /*
 414  * Signal trampoline, copied to top of user stack
 415  */
 416 NON_GPROF_ENTRY(sigcode)
 417         call    SIGF_HANDLER(%esp)              /* call signal handler */
 418         lea     SIGF_UC(%esp),%eax              /* get ucontext_t */
 419         pushl   %eax
 420         movl    $SYS_osigreturn,%eax
 421         pushl   %eax                            /* junk to fake return addr. */
 422         int     $0x80                           /* enter kernel with args */
 423                                                 /* on stack */
 424 1:
 425         jmp     1b
 426         ALIGN_TEXT
 427 _esigcode:
 428
 429         .data
 430         .globl  _szsigcode
 431 _szsigcode:
 432         .long   _esigcode-_sigcode
 433         .text
 434
 435 /**********************************************************************
 436  *
 437  * Recover the bootinfo passed to us from the boot program
 438  *
 439  */
 440 recover_bootinfo:
 441         /*
 442          * This code is called in different ways depending on what loaded
 443          * and started the kernel.  This is used to detect how we get the
 444          * arguments from the other code and what we do with them.
 445          *
 446          * Old disk boot blocks:
 447          *      (*btext)(howto, bootdev, cyloffset, esym);
 448          *      [return address == 0, and can NOT be returned to]
 449          *      [cyloffset was not supported by the FreeBSD boot code
 450          *       and always passed in as 0]
 451          *      [esym is also known as total in the boot code, and
 452          *       was never properly supported by the FreeBSD boot code]
 453          *
 454          * Old diskless netboot code:
 455          *      (*btext)(0,0,0,0,&nfsdiskless,0,0,0);
 456          *      [return address != 0, and can NOT be returned to]
 457          *      If we are being booted by this code it will NOT work,
 458          *      so we are just going to halt if we find this case.
 459          *
 460          * New uniform boot code:
 461          *      (*btext)(howto, bootdev, 0, 0, 0, &bootinfo)
 462          *      [return address != 0, and can be returned to]
 463          *
 464          * There may seem to be a lot of wasted arguments in here, but
 465          * that is so the newer boot code can still load very old kernels
 466          * and old boot code can load new kernels.
 467          */
 468
 469         /*
 470          * The old style disk boot blocks fake a frame on the stack and
 471          * did an lret to get here.  The frame on the stack has a return
 472          * address of 0.
 473          */
 474         cmpl    $0,4(%ebp)
 475         je      olddiskboot
 476
 477         /*
 478          * We have some form of return address, so this is either the
 479          * old diskless netboot code, or the new uniform code.  That can
 480          * be detected by looking at the 5th argument, if it is 0
 481          * we are being booted by the new uniform boot code.
 482          */
 483         cmpl    $0,24(%ebp)
 484         je      newboot
 485
 486         /*
 487          * Seems we have been loaded by the old diskless boot code, we
 488          * don't stand a chance of running as the diskless structure
 489          * changed considerably between the two, so just halt.
 490          */
 491          hlt
 492
 493         /*
 494          * We have been loaded by the new uniform boot code.
 495          * Let's check the bootinfo version, and if we do not understand
 496          * it we return to the loader with a status of 1 to indicate this error
 497          */
 498 newboot:
 499         movl    28(%ebp),%ebx           /* &bootinfo.version */
 500         movl    BI_VERSION(%ebx),%eax
 501         cmpl    $1,%eax                 /* We only understand version 1 */
 502         je      1f
 503         movl    $1,%eax                 /* Return status */
 504         leave
 505         /*
 506          * XXX this returns to our caller's caller (as is required) since
 507          * we didn't set up a frame and our caller did.
 508          */
 509         ret
 510
 511 1:
 512         /*
 513          * If we have a kernelname copy it in
 514          */
 515         movl    BI_KERNELNAME(%ebx),%esi
 516         cmpl    $0,%esi
 517         je      2f                      /* No kernelname */
 518         movl    $MAXPATHLEN,%ecx        /* Brute force!!! */
 519         movl    $R(_kernelname),%edi
 520         cmpb    $'/',(%esi)             /* Make sure it starts with a slash */
 521         je      1f
 522         movb    $'/',(%edi)
 523         incl    %edi
 524         decl    %ecx
 525 1:
 526         cld
 527         rep
 528         movsb
 529
 530 2:
 531         /*
 532          * Determine the size of the boot loader's copy of the bootinfo
 533          * struct.  This is impossible to do properly because old versions
 534          * of the struct don't contain a size field and there are 2 old
 535          * versions with the same version number.
 536          */
 537         movl    $BI_ENDCOMMON,%ecx      /* prepare for sizeless version */
 538         testl   $RB_BOOTINFO,8(%ebp)    /* bi_size (and bootinfo) valid? */
 539         je      got_bi_size             /* no, sizeless version */
 540         movl    BI_SIZE(%ebx),%ecx
 541 got_bi_size:
 542
 543         /*
 544          * Copy the common part of the bootinfo struct
 545          */
 546         movl    %ebx,%esi
 547         movl    $R(_bootinfo),%edi
 548         cmpl    $BOOTINFO_SIZE,%ecx
 549         jbe     got_common_bi_size
 550         movl    $BOOTINFO_SIZE,%ecx
 551 got_common_bi_size:
 552         cld
 553         rep
 554         movsb
 555
 556 #ifdef NFS_ROOT
 557 #ifndef BOOTP_NFSV3
 558         /*
 559          * If we have a nfs_diskless structure copy it in
 560          */
 561         movl    BI_NFS_DISKLESS(%ebx),%esi
 562         cmpl    $0,%esi
 563         je      olddiskboot
 564         movl    $R(_nfs_diskless),%edi
 565         movl    $NFSDISKLESS_SIZE,%ecx
 566         cld
 567         rep
 568         movsb
 569         movl    $R(_nfs_diskless_valid),%edi
 570         movl    $1,(%edi)
 571 #endif
 572 #endif
 573
 574         /*
 575          * The old style disk boot.
 576          *      (*btext)(howto, bootdev, cyloffset, esym);
 577          * Note that the newer boot code just falls into here to pick
 578          * up howto and bootdev, cyloffset and esym are no longer used
 579          */
 580 olddiskboot:
 581         movl    8(%ebp),%eax
 582         movl    %eax,R(_boothowto)
 583         movl    12(%ebp),%eax
 584         movl    %eax,R(_bootdev)
 585
 586         ret
 587
 588
 589 /**********************************************************************
 590  *
 591  * Identify the CPU and initialize anything special about it
 592  *
 593  */
 594 identify_cpu:
 595
 596         /* Try to toggle alignment check flag; does not exist on 386. */
 597         pushfl
 598         popl    %eax
 599         movl    %eax,%ecx
 600         orl     $PSL_AC,%eax
 601         pushl   %eax
 602         popfl
 603         pushfl
 604         popl    %eax
 605         xorl    %ecx,%eax
 606         andl    $PSL_AC,%eax
 607         pushl   %ecx
 608         popfl
 609
 610         testl   %eax,%eax
 611         jnz     try486
 612
 613         /* NexGen CPU does not have aligment check flag. */
 614         pushfl
 615         movl    $0x5555, %eax
 616         xorl    %edx, %edx
 617         movl    $2, %ecx
 618         clc
 619         divl    %ecx
 620         jz      trynexgen
 621         popfl
 622         movl    $CPU_386,R(_cpu)
 623         jmp     3f
 624
 625 trynexgen:
 626         popfl
 627         movl    $CPU_NX586,R(_cpu)
 628         movl    $0x4778654e,R(_cpu_vendor)      # store vendor string
 629         movl    $0x72446e65,R(_cpu_vendor+4)
 630         movl    $0x6e657669,R(_cpu_vendor+8)
 631         movl    $0,R(_cpu_vendor+12)
 632         jmp     3f
 633
 634 try486: /* Try to toggle identification flag; does not exist on early 486s. */
 635         pushfl
 636         popl    %eax
 637         movl    %eax,%ecx
 638         xorl    $PSL_ID,%eax
 639         pushl   %eax
 640         popfl
 641         pushfl
 642         popl    %eax
 643         xorl    %ecx,%eax
 644         andl    $PSL_ID,%eax
 645         pushl   %ecx
 646         popfl
 647
 648         testl   %eax,%eax
 649         jnz     trycpuid
 650         movl    $CPU_486,R(_cpu)
 651
 652         /*
 653          * Check Cyrix CPU
 654          * Cyrix CPUs do not change the undefined flags following
 655          * execution of the divide instruction which divides 5 by 2.
 656          *
 657          * Note: CPUID is enabled on M2, so it passes another way.
 658          */
 659         pushfl
 660         movl    $0x5555, %eax
 661         xorl    %edx, %edx
 662         movl    $2, %ecx
 663         clc
 664         divl    %ecx
 665         jnc     trycyrix
 666         popfl
 667         jmp     3f              /* You may use Intel CPU. */
 668
 669 trycyrix:
 670         popfl
 671         /*
 672          * IBM Bluelighting CPU also doesn't change the undefined flags.
 673          * Because IBM doesn't disclose the information for Bluelighting
 674          * CPU, we couldn't distinguish it from Cyrix's (including IBM
 675          * brand of Cyrix CPUs).
 676          */
 677         movl    $0x69727943,R(_cpu_vendor)      # store vendor string
 678         movl    $0x736e4978,R(_cpu_vendor+4)
 679         movl    $0x64616574,R(_cpu_vendor+8)
 680         jmp     3f
 681
 682 trycpuid:       /* Use the `cpuid' instruction. */
 683         xorl    %eax,%eax
 684         .byte   0x0f,0xa2                       # cpuid 0
 685         movl    %eax,R(_cpu_high)               # highest capability
 686         movl    %ebx,R(_cpu_vendor)             # store vendor string
 687         movl    %edx,R(_cpu_vendor+4)
 688         movl    %ecx,R(_cpu_vendor+8)
 689         movb    $0,R(_cpu_vendor+12)
 690
 691         movl    $1,%eax
 692         .byte   0x0f,0xa2                       # cpuid 1
 693         movl    %eax,R(_cpu_id)                 # store cpu_id
 694         movl    %edx,R(_cpu_feature)            # store cpu_feature
 695         rorl    $8,%eax                         # extract family type
 696         andl    $15,%eax
 697         cmpl    $5,%eax
 698         jae     1f
 699
 700         /* less than Pentium; must be 486 */
 701         movl    $CPU_486,R(_cpu)
 702         jmp     3f
 703 1:
 704         /* a Pentium? */
 705         cmpl    $5,%eax
 706         jne     2f
 707         movl    $CPU_586,R(_cpu)
 708         jmp     3f
 709 2:
 710         /* Greater than Pentium...call it a Pentium Pro */
 711         movl    $CPU_686,R(_cpu)
 712 3:
 713         ret
 714
 715
 716 /**********************************************************************
 717  *
 718  * Create the first page directory and its page tables.
 719  *
 720  */
 721
 722 create_pagetables:
 723
 724         testl   $CPUID_PGE, R(_cpu_feature)
 725         jz      1f
 726         movl    %cr4, %eax
 727         orl     $CR4_PGE, %eax
 728         movl    %eax, %cr4
 729 1:
 730
 731 /* Find end of kernel image (rounded up to a page boundary). */
 732         movl    $R(_end),%esi
 733
 734 /* include symbols if loaded and useful */
 735 #ifdef DDB
 736         movl    R(_bootinfo+BI_ESYMTAB),%edi
 737         testl   %edi,%edi
 738         je      over_symalloc
 739         movl    %edi,%esi
 740         movl    $KERNBASE,%edi
 741         addl    %edi,R(_bootinfo+BI_SYMTAB)
 742         addl    %edi,R(_bootinfo+BI_ESYMTAB)
 743 over_symalloc:
 744 #endif
 745
 746 /* If we are told where the end of the kernel space is, believe it. */
 747         movl    R(_bootinfo+BI_KERNEND),%edi
 748         testl   %edi,%edi
 749         je      no_kernend
 750         movl    %edi,%esi
 751 no_kernend:
 752
 753         addl    $PAGE_MASK,%esi
 754         andl    $~PAGE_MASK,%esi
 755         movl    %esi,R(_KERNend)        /* save end of kernel */
 756         movl    %esi,R(physfree)        /* next free page is at end of kernel */
 757
 758 /* Allocate Kernel Page Tables */
 759         ALLOCPAGES(NKPT)
 760         movl    %esi,R(_KPTphys)
 761
 762 /* Allocate Page Table Directory */
 763         ALLOCPAGES(1)
 764         movl    %esi,R(_IdlePTD)
 765
 766 /* Allocate UPAGES */
 767         ALLOCPAGES(UPAGES)
 768         movl    %esi,R(p0upa)
 769         addl    $KERNBASE, %esi
 770         movl    %esi, R(_proc0paddr)
 771
 772         ALLOCPAGES(1)                   /* vm86/bios stack */
 773         movl    %esi,R(vm86phystk)
 774
 775         ALLOCPAGES(3)                   /* pgtable + ext + IOPAGES */
 776         movl    %esi,R(_vm86pa)
 777         addl    $KERNBASE, %esi
 778         movl    %esi, R(_vm86paddr)
 779
 780 #ifdef SMP
 781 /* Allocate cpu0's private data page */
 782         ALLOCPAGES(1)
 783         movl    %esi,R(cpu0pp)
 784         addl    $KERNBASE, %esi
 785         movl    %esi, R(_cpu0prvpage)   /* relocated to KVM space */
 786
 787 /* Allocate SMP page table page */
 788         ALLOCPAGES(1)
 789         movl    %esi,R(SMPptpa)
 790         addl    $KERNBASE, %esi
 791         movl    %esi, R(_SMPpt)         /* relocated to KVM space */
 792 #endif  /* SMP */
 793
 794 /* Map read-only from zero to the end of the kernel text section */
 795         xorl    %eax, %eax
 796 #ifdef BDE_DEBUGGER
 797 /* If the debugger is present, actually map everything read-write. */
 798         cmpl    $0,R(_bdb_exists)
 799         jne     map_read_write
 800 #endif
 801         xorl    %edx,%edx
 802
 803 #if !defined(SMP)
 804         testl   $CPUID_PGE, R(_cpu_feature)
 805         jz      2f
 806         orl     $PG_G,%edx
 807 #endif
 808
 809 2:      movl    $R(_etext),%ecx
 810         addl    $PAGE_MASK,%ecx
 811         shrl    $PAGE_SHIFT,%ecx
 812         fillkptphys(%edx)
 813
 814 /* Map read-write, data, bss and symbols */
 815         movl    $R(_etext),%eax
 816         addl    $PAGE_MASK, %eax
 817         andl    $~PAGE_MASK, %eax
 818 map_read_write:
 819         movl    $PG_RW,%edx
 820 #if !defined(SMP)
 821         testl   $CPUID_PGE, R(_cpu_feature)
 822         jz      1f
 823         orl     $PG_G,%edx
 824 #endif
 825
 826 1:      movl    R(_KERNend),%ecx
 827         subl    %eax,%ecx
 828         shrl    $PAGE_SHIFT,%ecx
 829         fillkptphys(%edx)
 830
 831 /* Map page directory. */
 832         movl    R(_IdlePTD), %eax
 833         movl    $1, %ecx
 834         fillkptphys($PG_RW)
 835
 836 /* Map proc0's UPAGES in the physical way ... */
 837         movl    R(p0upa), %eax
 838         movl    $UPAGES, %ecx
 839         fillkptphys($PG_RW)
 840
 841 /* Map ISA hole */
 842         movl    $ISA_HOLE_START, %eax
 843         movl    $ISA_HOLE_LENGTH>>PAGE_SHIFT, %ecx
 844         fillkptphys($PG_RW)
 845
 846 /* Map space for the vm86 region */
 847         movl    R(vm86phystk), %eax
 848         movl    $4, %ecx
 849         fillkptphys($PG_RW)
 850
 851 /* Map page 0 into the vm86 page table */
 852         movl    $0, %eax
 853         movl    $0, %ebx
 854         movl    $1, %ecx
 855         fillkpt(R(_vm86pa), $PG_RW|PG_U)
 856
 857 /* ...likewise for the ISA hole */
 858         movl    $ISA_HOLE_START, %eax
 859         movl    $ISA_HOLE_START>>PAGE_SHIFT, %ebx
 860         movl    $ISA_HOLE_LENGTH>>PAGE_SHIFT, %ecx
 861         fillkpt(R(_vm86pa), $PG_RW|PG_U)
 862
 863 #ifdef SMP
 864 /* Map cpu0's private page into global kmem (4K @ cpu0prvpage) */
 865         movl    R(cpu0pp), %eax
 866         movl    $1, %ecx
 867         fillkptphys($PG_RW)
 868
 869 /* Map SMP page table page into global kmem FWIW */
 870         movl    R(SMPptpa), %eax
 871         movl    $1, %ecx
 872         fillkptphys($PG_RW)
 873
 874 /* Map the private page into the SMP page table */
 875         movl    R(cpu0pp), %eax
 876         movl    $0, %ebx                /* pte offset = 0 */
 877         movl    $1, %ecx                /* one private page coming right up */
 878         fillkpt(R(SMPptpa), $PG_RW)
 879
 880 /* ... and put the page table table in the pde. */
 881         movl    R(SMPptpa), %eax
 882         movl    $MPPTDI, %ebx
 883         movl    $1, %ecx
 884         fillkpt(R(_IdlePTD), $PG_RW)
 885
 886 /* Fakeup VA for the local apic to allow early traps. */
 887         ALLOCPAGES(1)
 888         movl    %esi, %eax
 889         movl    $(NPTEPG-1), %ebx       /* pte offset = NTEPG-1 */
 890         movl    $1, %ecx                /* one private pt coming right up */
 891         fillkpt(R(SMPptpa), $PG_RW)
 892
 893 /* Initialize mp lock to allow early traps */
 894         movl    $1, R(_mp_lock)
 895 #endif  /* SMP */
 896
 897 /* install a pde for temporary double map of bottom of VA */
 898         movl    R(_KPTphys), %eax
 899         xorl    %ebx, %ebx
 900         movl    $1, %ecx
 901         fillkpt(R(_IdlePTD), $PG_RW)
 902
 903 /* install pde's for pt's */
 904         movl    R(_KPTphys), %eax
 905         movl    $KPTDI, %ebx
 906         movl    $NKPT, %ecx
 907         fillkpt(R(_IdlePTD), $PG_RW)
 908
 909 /* install a pde recursively mapping page directory as a page table */
 910         movl    R(_IdlePTD), %eax
 911         movl    $PTDPTDI, %ebx
 912         movl    $1,%ecx
 913         fillkpt(R(_IdlePTD), $PG_RW)
 914
 915         ret
 916
 917 #ifdef BDE_DEBUGGER
 918 bdb_prepare_paging:
 919         cmpl    $0,R(_bdb_exists)
 920         je      bdb_prepare_paging_exit
 921
 922         subl    $6,%esp
 923
 924         /*
 925          * Copy and convert debugger entries from the bootstrap gdt and idt
 926          * to the kernel gdt and idt.  Everything is still in low memory.
 927          * Tracing continues to work after paging is enabled because the
 928          * low memory addresses remain valid until everything is relocated.
 929          * However, tracing through the setidt() that initializes the trace
 930          * trap will crash.
 931          */
 932         sgdt    (%esp)
 933         movl    2(%esp),%esi            /* base address of bootstrap gdt */
 934         movl    $R(_gdt),%edi
 935         movl    %edi,2(%esp)            /* prepare to load kernel gdt */
 936         movl    $8*18/4,%ecx
 937         cld
 938         rep                             /* copy gdt */
 939         movsl
 940         movl    $R(_gdt),-8+2(%edi)     /* adjust gdt self-ptr */
 941         movb    $0x92,-8+5(%edi)
 942         lgdt    (%esp)
 943
 944         sidt    (%esp)
 945         movl    2(%esp),%esi            /* base address of current idt */
 946         movl    8+4(%esi),%eax          /* convert dbg descriptor to ... */
 947         movw    8(%esi),%ax
 948         movl    %eax,R(bdb_dbg_ljmp+1)  /* ... immediate offset ... */
 949         movl    8+2(%esi),%eax
 950         movw    %ax,R(bdb_dbg_ljmp+5)   /* ... and selector for ljmp */
 951         movl    24+4(%esi),%eax         /* same for bpt descriptor */
 952         movw    24(%esi),%ax
 953         movl    %eax,R(bdb_bpt_ljmp+1)
 954         movl    24+2(%esi),%eax
 955         movw    %ax,R(bdb_bpt_ljmp+5)
 956         movl    R(_idt),%edi
 957         movl    %edi,2(%esp)            /* prepare to load kernel idt */
 958         movl    $8*4/4,%ecx
 959         cld
 960         rep                             /* copy idt */
 961         movsl
 962         lidt    (%esp)
 963
 964         addl    $6,%esp
 965
 966 bdb_prepare_paging_exit:
 967         ret
 968
 969 /* Relocate debugger gdt entries and gdt and idt pointers. */
 970 bdb_commit_paging:
 971         cmpl    $0,_bdb_exists
 972         je      bdb_commit_paging_exit
 973
 974         movl    $_gdt+8*9,%eax          /* adjust slots 9-17 */
 975         movl    $9,%ecx
 976 reloc_gdt:
 977         movb    $KERNBASE>>24,7(%eax)   /* top byte of base addresses, was 0, */
 978         addl    $8,%eax                 /* now KERNBASE>>24 */
 979         loop    reloc_gdt
 980
 981         subl    $6,%esp
 982         sgdt    (%esp)
 983         addl    $KERNBASE,2(%esp)
 984         lgdt    (%esp)
 985         sidt    (%esp)
 986         addl    $KERNBASE,2(%esp)
 987         lidt    (%esp)
 988         addl    $6,%esp
 989
 990         int     $3
 991
 992 bdb_commit_paging_exit:
 993         ret
 994
 995 #endif /* BDE_DEBUGGER */