sys/amd64/ia32/ia32_sigtramp.S

   1 /*-
   2  * Copyright (c) 2003 Peter Wemm
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  * $FreeBSD$
  27  */
  28
  29 #include "opt_compat.h"
  30
  31 #include <machine/asmacros.h>
  32 #include <sys/syscall.h>
  33
  34 #include "ia32_assym.h"
  35
  36         .text
  37         .code32
  38 /*
  39  * Signal trampoline, copied to top of user stack
  40  * XXX may need to be MD to match backend sendsig handoff protocol
  41  */
  42         ALIGN_TEXT
  43         .globl  ia32_sigcode
  44 ia32_sigcode:
  45         calll   *IA32_SIGF_HANDLER(%esp)
  46         leal    IA32_SIGF_UC(%esp),%eax /* get ucontext */
  47         pushl   %eax
  48         movl    $SYS_sigreturn,%eax
  49         pushl   %eax                    /* junk to fake return addr. */
  50         int     $0x80                   /* enter kernel with args */
  51                                         /* on stack */
  52 1:
  53         jmp     1b
  54
  55 #ifdef COMPAT_FREEBSD4
  56         ALIGN_TEXT
  57 freebsd4_ia32_sigcode:
  58         calll   *IA32_SIGF_HANDLER(%esp)
  59         leal    IA32_SIGF_UC4(%esp),%eax/* get ucontext */
  60         pushl   %eax
  61         movl    $344,%eax               /* 4.x SYS_sigreturn */
  62         pushl   %eax                    /* junk to fake return addr. */
  63         int     $0x80                   /* enter kernel with args */
  64                                         /* on stack */
  65 1:
  66         jmp     1b
  67 #endif
  68
  69 #ifdef COMPAT_43
  70         ALIGN_TEXT
  71 ia32_osigcode:
  72         calll   *IA32_SIGF_HANDLER(%esp)/* call signal handler */
  73         leal    IA32_SIGF_SC(%esp),%eax /* get sigcontext */
  74         pushl   %eax
  75         movl    $103,%eax               /* 3.x SYS_sigreturn */
  76         pushl   %eax                    /* junk to fake return addr. */
  77         int     $0x80                   /* enter kernel with args */
  78 1:
  79         jmp     1b
  80
  81 /*
  82  * Our lcall $7,$0 handler remains in user mode (ring 3), since lcalls
  83  * don't change the interrupt mask, so if this one went directly to the
  84  * kernel then there would be a window with interrupts enabled in kernel
  85  * mode, and all interrupt handlers would have to be almost as complicated
  86  * as the NMI handler to support this.
  87  *
  88  * Instead, convert the lcall to an int0x80 call.  The kernel does most
  89  * of the conversion by popping the lcall return values off the user
  90  * stack and returning to them instead of to here, except when the
  91  * conversion itself fails.  Adjusting the stack here is impossible for
  92  * vfork() and harder for other syscalls.
  93  */
  94         ALIGN_TEXT
  95 lcall_tramp:
  96         int     $0x80
  97 1:      jmp     1b
  98 #endif
  99
 100         ALIGN_TEXT
 101 esigcode:
 102
 103         .data
 104         .globl  sz_ia32_sigcode
 105 sz_ia32_sigcode:
 106         .long   esigcode-ia32_sigcode
 107 #ifdef COMPAT_FREEBSD4
 108         .globl  sz_freebsd4_ia32_sigcode
 109 sz_freebsd4_ia32_sigcode:
 110         .long   esigcode-freebsd4_ia32_sigcode
 111 #endif
 112 #ifdef COMPAT_43
 113         .globl  sz_ia32_osigcode
 114 sz_ia32_osigcode:
 115         .long   esigcode-ia32_osigcode
 116         .globl  sz_lcall_tramp
 117 sz_lcall_tramp:
 118         .long   esigcode-lcall_tramp
 119 #endif