sys/amd64/include/asmacros.h

   1 /* -*- mode: asm -*- */
   2 /*-
   3  * Copyright (c) 1993 The Regents of the University of California.
   4  * All rights reserved.
   5  *
   6  * Copyright (c) 2018 The FreeBSD Foundation
   7  * All rights reserved.
   8  *
   9  * Portions of this software were developed by
  10  * Konstantin Belousov <kib@FreeBSD.org> under sponsorship from
  11  * the FreeBSD Foundation.
  12  *
  13  * Redistribution and use in source and binary forms, with or without
  14  * modification, are permitted provided that the following conditions
  15  * are met:
  16  * 1. Redistributions of source code must retain the above copyright
  17  *    notice, this list of conditions and the following disclaimer.
  18  * 2. Redistributions in binary form must reproduce the above copyright
  19  *    notice, this list of conditions and the following disclaimer in the
  20  *    documentation and/or other materials provided with the distribution.
  21  * 4. Neither the name of the University nor the names of its contributors
  22  *    may be used to endorse or promote products derived from this software
  23  *    without specific prior written permission.
  24  *
  25  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  27  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  28  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  29  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  30  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  31  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  32  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  33  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  34  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  35  * SUCH DAMAGE.
  36  *
  37  * $FreeBSD$
  38  */
  39
  40 #ifndef _MACHINE_ASMACROS_H_
  41 #define _MACHINE_ASMACROS_H_
  42
  43 #include <sys/cdefs.h>
  44
  45 /* XXX too much duplication in various asm*.h's. */
  46
  47 /*
  48  * CNAME is used to manage the relationship between symbol names in C
  49  * and the equivalent assembly language names.  CNAME is given a name as
  50  * it would be used in a C program.  It expands to the equivalent assembly
  51  * language name.
  52  */
  53 #define CNAME(csym)             csym
  54
  55 #define ALIGN_DATA      .p2align 3      /* 8 byte alignment, zero filled */
  56 #ifdef GPROF
  57 #define ALIGN_TEXT      .p2align 4,0x90 /* 16-byte alignment, nop filled */
  58 #else
  59 #define ALIGN_TEXT      .p2align 4,0x90 /* 16-byte alignment, nop filled */
  60 #endif
  61 #define SUPERALIGN_TEXT .p2align 4,0x90 /* 16-byte alignment, nop filled */
  62
  63 #define GEN_ENTRY(name)         ALIGN_TEXT; .globl CNAME(name); \
  64                                 .type CNAME(name),@function; CNAME(name):
  65 #define NON_GPROF_ENTRY(name)   GEN_ENTRY(name)
  66 #define NON_GPROF_RET           .byte 0xc3      /* opcode for `ret' */
  67
  68 #define END(name)               .size name, . - name
  69
  70 #ifdef GPROF
  71 /*
  72  * __mcount is like [.]mcount except that doesn't require its caller to set
  73  * up a frame pointer.  It must be called before pushing anything onto the
  74  * stack.  gcc should eventually generate code to call __mcount in most
  75  * cases.  This would make -pg in combination with -fomit-frame-pointer
  76  * useful.  gcc has a configuration variable PROFILE_BEFORE_PROLOGUE to
  77  * allow profiling before setting up the frame pointer, but this is
  78  * inadequate for good handling of special cases, e.g., -fpic works best
  79  * with profiling after the prologue.
  80  *
  81  * [.]mexitcount is a new function to support non-statistical profiling if an
  82  * accurate clock is available.  For C sources, calls to it are generated
  83  * by the FreeBSD extension `-mprofiler-epilogue' to gcc.  It is best to
  84  * call [.]mexitcount at the end of a function like the MEXITCOUNT macro does,
  85  * but gcc currently generates calls to it at the start of the epilogue to
  86  * avoid problems with -fpic.
  87  *
  88  * [.]mcount and __mcount may clobber the call-used registers and %ef.
  89  * [.]mexitcount may clobber %ecx and %ef.
  90  *
  91  * Cross-jumping makes non-statistical profiling timing more complicated.
  92  * It is handled in many cases by calling [.]mexitcount before jumping.  It
  93  * is handled for conditional jumps using CROSSJUMP() and CROSSJUMP_LABEL().
  94  * It is handled for some fault-handling jumps by not sharing the exit
  95  * routine.
  96  *
  97  * ALTENTRY() must be before a corresponding ENTRY() so that it can jump to
  98  * the main entry point.  Note that alt entries are counted twice.  They
  99  * have to be counted as ordinary entries for gprof to get the call times
 100  * right for the ordinary entries.
 101  *
 102  * High local labels are used in macros to avoid clashes with local labels
 103  * in functions.
 104  *
 105  * Ordinary `ret' is used instead of a macro `RET' because there are a lot
 106  * of `ret's.  0xc3 is the opcode for `ret' (`#define ret ... ret' can't
 107  * be used because this file is sometimes preprocessed in traditional mode).
 108  * `ret' clobbers eflags but this doesn't matter.
 109  */
 110 #define ALTENTRY(name)          GEN_ENTRY(name) ; MCOUNT ; MEXITCOUNT ; jmp 9f
 111 #define CROSSJUMP(jtrue, label, jfalse) \
 112         jfalse 8f; MEXITCOUNT; jmp __CONCAT(to,label); 8:
 113 #define CROSSJUMPTARGET(label) \
 114         ALIGN_TEXT; __CONCAT(to,label): ; MCOUNT; jmp label
 115 #define ENTRY(name)             GEN_ENTRY(name) ; 9: ; MCOUNT
 116 #define FAKE_MCOUNT(caller)     pushq caller ; call __mcount ; popq %rcx
 117 #define MCOUNT                  call __mcount
 118 #define MCOUNT_LABEL(name)      GEN_ENTRY(name) ; nop ; ALIGN_TEXT
 119 #ifdef GUPROF
 120 #define MEXITCOUNT              call .mexitcount
 121 #define ret                     MEXITCOUNT ; NON_GPROF_RET
 122 #else
 123 #define MEXITCOUNT
 124 #endif
 125
 126 #else /* !GPROF */
 127 /*
 128  * ALTENTRY() has to align because it is before a corresponding ENTRY().
 129  * ENTRY() has to align to because there may be no ALTENTRY() before it.
 130  * If there is a previous ALTENTRY() then the alignment code for ENTRY()
 131  * is empty.
 132  */
 133 #define ALTENTRY(name)          GEN_ENTRY(name)
 134 #define CROSSJUMP(jtrue, label, jfalse) jtrue label
 135 #define CROSSJUMPTARGET(label)
 136 #define ENTRY(name)             GEN_ENTRY(name)
 137 #define FAKE_MCOUNT(caller)
 138 #define MCOUNT
 139 #define MCOUNT_LABEL(name)
 140 #define MEXITCOUNT
 141 #endif /* GPROF */
 142
 143 /*
 144  * Convenience for adding frame pointers to hand-coded ASM.  Useful for
 145  * DTrace, HWPMC, and KDB.
 146  */
 147 #define PUSH_FRAME_POINTER      \
 148         pushq   %rbp ;          \
 149         movq    %rsp, %rbp ;
 150 #define POP_FRAME_POINTER       \
 151         popq    %rbp
 152
 153 #ifdef LOCORE
 154 /*
 155  * Access per-CPU data.
 156  */
 157 #define PCPU(member)    %gs:PC_ ## member
 158 #define PCPU_ADDR(member, reg)                                  \
 159         movq %gs:PC_PRVSPACE, reg ;                             \
 160         addq $PC_ ## member, reg
 161
 162 /*
 163  * Convenience macro for declaring interrupt entry points.
 164  */
 165 #define IDTVEC(name)    ALIGN_TEXT; .globl __CONCAT(X,name); \
 166                         .type __CONCAT(X,name),@function; __CONCAT(X,name):
 167
 168         .macro  SAVE_SEGS
 169         movw    %fs,TF_FS(%rsp)
 170         movw    %gs,TF_GS(%rsp)
 171         movw    %es,TF_ES(%rsp)
 172         movw    %ds,TF_DS(%rsp)
 173         .endm
 174
 175         .macro  MOVE_STACKS qw
 176         .L.offset=0
 177         .rept   \qw
 178         movq    .L.offset(%rsp),%rdx
 179         movq    %rdx,.L.offset(%rax)
 180         .L.offset=.L.offset+8
 181         .endr
 182         .endm
 183
 184         .macro  PTI_UUENTRY has_err
 185         movq    PCPU(KCR3),%rax
 186         movq    %rax,%cr3
 187         movq    PCPU(RSP0),%rax
 188         subq    $PTI_SIZE,%rax
 189         MOVE_STACKS     ((PTI_SIZE / 8) - 1 + \has_err)
 190         movq    %rax,%rsp
 191         popq    %rdx
 192         popq    %rax
 193         .endm
 194
 195         .macro  PTI_UENTRY has_err
 196         swapgs
 197         pushq   %rax
 198         pushq   %rdx
 199         PTI_UUENTRY \has_err
 200         .endm
 201
 202         .macro  PTI_ENTRY name, cont, has_err=0
 203         ALIGN_TEXT
 204         .globl  X\name\()_pti
 205         .type   X\name\()_pti,@function
 206 X\name\()_pti:
 207         /* %rax, %rdx and possibly err not yet pushed */
 208         testb   $SEL_RPL_MASK,PTI_CS-(2+1-\has_err)*8(%rsp)
 209         jz      \cont
 210         PTI_UENTRY \has_err
 211         swapgs
 212         jmp     \cont
 213         .endm
 214
 215         .macro  PTI_INTRENTRY vec_name
 216         SUPERALIGN_TEXT
 217         .globl  X\vec_name\()_pti
 218         .type   X\vec_name\()_pti,@function
 219 X\vec_name\()_pti:
 220         testb   $SEL_RPL_MASK,PTI_CS-3*8(%rsp) /* err, %rax, %rdx not pushed */
 221         jz      \vec_name\()_u
 222         PTI_UENTRY has_err=0
 223         jmp     \vec_name\()_u
 224         .endm
 225
 226         .macro  INTR_PUSH_FRAME vec_name
 227         SUPERALIGN_TEXT
 228         .globl  X\vec_name
 229         .type   X\vec_name,@function
 230 X\vec_name:
 231         testb   $SEL_RPL_MASK,PTI_CS-3*8(%rsp) /* come from kernel? */
 232         jz      \vec_name\()_u          /* Yes, dont swapgs again */
 233         swapgs
 234 \vec_name\()_u:
 235         subq    $TF_RIP,%rsp    /* skip dummy tf_err and tf_trapno */
 236         movq    %rdi,TF_RDI(%rsp)
 237         movq    %rsi,TF_RSI(%rsp)
 238         movq    %rdx,TF_RDX(%rsp)
 239         movq    %rcx,TF_RCX(%rsp)
 240         movq    %r8,TF_R8(%rsp)
 241         movq    %r9,TF_R9(%rsp)
 242         movq    %rax,TF_RAX(%rsp)
 243         movq    %rbx,TF_RBX(%rsp)
 244         movq    %rbp,TF_RBP(%rsp)
 245         movq    %r10,TF_R10(%rsp)
 246         movq    %r11,TF_R11(%rsp)
 247         movq    %r12,TF_R12(%rsp)
 248         movq    %r13,TF_R13(%rsp)
 249         movq    %r14,TF_R14(%rsp)
 250         movq    %r15,TF_R15(%rsp)
 251         SAVE_SEGS
 252         movl    $TF_HASSEGS,TF_FLAGS(%rsp)
 253         cld
 254         testb   $SEL_RPL_MASK,TF_CS(%rsp)  /* come from kernel ? */
 255         jz      1f              /* yes, leave PCB_FULL_IRET alone */
 256         movq    PCPU(CURPCB),%r8
 257         andl    $~PCB_FULL_IRET,PCB_FLAGS(%r8)
 258 1:
 259         .endm
 260
 261         .macro  INTR_HANDLER vec_name
 262         .text
 263         PTI_INTRENTRY   \vec_name
 264         INTR_PUSH_FRAME \vec_name
 265         .endm
 266
 267         .macro  RESTORE_REGS
 268         movq    TF_RDI(%rsp),%rdi
 269         movq    TF_RSI(%rsp),%rsi
 270         movq    TF_RDX(%rsp),%rdx
 271         movq    TF_RCX(%rsp),%rcx
 272         movq    TF_R8(%rsp),%r8
 273         movq    TF_R9(%rsp),%r9
 274         movq    TF_RAX(%rsp),%rax
 275         movq    TF_RBX(%rsp),%rbx
 276         movq    TF_RBP(%rsp),%rbp
 277         movq    TF_R10(%rsp),%r10
 278         movq    TF_R11(%rsp),%r11
 279         movq    TF_R12(%rsp),%r12
 280         movq    TF_R13(%rsp),%r13
 281         movq    TF_R14(%rsp),%r14
 282         movq    TF_R15(%rsp),%r15
 283         .endm
 284
 285 #endif /* LOCORE */
 286
 287 #ifdef __STDC__
 288 #define ELFNOTE(name, type, desctype, descdata...) \
 289 .pushsection .note.name                 ;       \
 290   .align 4                              ;       \
 291   .long 2f - 1f         /* namesz */    ;       \
 292   .long 4f - 3f         /* descsz */    ;       \
 293   .long type                            ;       \
 294 1:.asciz #name                          ;       \
 295 2:.align 4                              ;       \
 296 3:desctype descdata                     ;       \
 297 4:.align 4                              ;       \
 298 .popsection
 299 #else /* !__STDC__, i.e. -traditional */
 300 #define ELFNOTE(name, type, desctype, descdata) \
 301 .pushsection .note.name                 ;       \
 302   .align 4                              ;       \
 303   .long 2f - 1f         /* namesz */    ;       \
 304   .long 4f - 3f         /* descsz */    ;       \
 305   .long type                            ;       \
 306 1:.asciz "name"                         ;       \
 307 2:.align 4                              ;       \
 308 3:desctype descdata                     ;       \
 309 4:.align 4                              ;       \
 310 .popsection
 311 #endif /* __STDC__ */
 312
 313 #endif /* !_MACHINE_ASMACROS_H_ */