sys/arm/arm/copystr.S

   1 /*      $NetBSD: copystr.S,v 1.8 2002/10/13 14:54:48 bjh21 Exp $        */
   2
   3 /*-
   4  * Copyright (c) 1995 Mark Brinicombe.
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. All advertising materials mentioning features or use of this software
  16  *    must display the following acknowledgement:
  17  *      This product includes software developed by Mark Brinicombe.
  18  * 4. The name of the company nor the name of the author may be used to
  19  *    endorse or promote products derived from this software without specific
  20  *    prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR IMPLIED
  23  * WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  24  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  25  * IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
  26  * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  27  * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  28  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  * copystr.S
  35  *
  36  * optimised and fault protected copystr functions
  37  *
  38  * Created      : 16/05/95
  39  */
  40
  41 #include "assym.inc"
  42 #include <machine/asm.h>
  43 #include <machine/armreg.h>
  44 __FBSDID("$FreeBSD$");
  45
  46 #include <sys/errno.h>
  47
  48         .text
  49         .align  2
  50
  51 #if __ARM_ARCH >= 6
  52 #define GET_PCB(tmp) \
  53         mrc p15, 0, tmp, c13, c0, 4; \
  54         add     tmp, tmp, #(TD_PCB)
  55 #else
  56 .Lpcb:
  57         .word   _C_LABEL(__pcpu) + PC_CURPCB
  58
  59 #define GET_PCB(tmp) \
  60         ldr     tmp, .Lpcb
  61 #endif
  62
  63 #define SAVE_REGS       stmfd   sp!, {r4-r6}
  64 #define RESTORE_REGS    ldmfd   sp!, {r4-r6}
  65
  66 /*
  67  * r0 - user space address
  68  * r1 - kernel space address
  69  * r2 - maxlens
  70  * r3 - lencopied
  71  *
  72  * Copy string from user space to kernel space
  73  */
  74 ENTRY(copyinstr)
  75         SAVE_REGS
  76
  77         teq     r2, #0x00000000
  78         mov     r6, #0x00000000
  79         moveq   r0, #ENAMETOOLONG
  80         beq     2f
  81
  82         ldr     r12, =VM_MAXUSER_ADDRESS
  83
  84         GET_PCB(r4)
  85         ldr     r4, [r4]
  86
  87 #ifdef DIAGNOSTIC
  88         teq     r4, #0x00000000
  89         beq     .Lcopystrpcbfault
  90 #endif
  91
  92         adr     r5, .Lcopystrfault
  93         str     r5, [r4, #PCB_ONFAULT]
  94
  95 1:
  96         cmp     r0, r12
  97         bcs     .Lcopystrfault
  98         ldrbt   r5, [r0], #0x0001
  99         add     r6, r6, #0x00000001
 100         teq     r5, #0x00000000
 101         strb    r5, [r1], #0x0001
 102         teqne   r6, r2
 103         bne     1b
 104
 105         mov     r0, #0x00000000
 106         str     r0, [r4, #PCB_ONFAULT]
 107
 108         teq     r5, #0x00000000
 109         moveq   r0, #0x00000000
 110         movne   r0, #ENAMETOOLONG
 111
 112 2:      teq     r3, #0x00000000
 113         strne   r6, [r3]
 114
 115         RESTORE_REGS
 116         RET
 117 END(copyinstr)
 118
 119 /* A fault occurred during the copy */
 120 .Lcopystrfault:
 121         mov     r1, #0x00000000
 122         str     r1, [r4, #PCB_ONFAULT]
 123         mov     r0, #EFAULT
 124         RESTORE_REGS
 125         RET
 126
 127 #ifdef DIAGNOSTIC
 128 .Lcopystrpcbfault:
 129         mov     r2, r1
 130         mov     r1, r0
 131         adr     r0, Lcopystrpcbfaulttext
 132         bic     sp, sp, #7                      /* align stack to 8 bytes */
 133         b       _C_LABEL(panic)
 134
 135 Lcopystrpcbfaulttext:
 136         .asciz  "No valid PCB during copyinoutstr() addr1=%08x addr2=%08x\n"
 137         .align  2
 138 #endif