sys/arm64/arm64/copyinout.S

   1 /*-
   2  * Copyright (c) 2015 The FreeBSD Foundation
   3  * All rights reserved.
   4  *
   5  * This software was developed by Andrew Turner under
   6  * sponsorship from the FreeBSD Foundation.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  *
  29  */
  30
  31 #include <machine/asm.h>
  32 __FBSDID("$FreeBSD$");
  33
  34 #include <sys/errno.h>
  35
  36 #include "assym.s"
  37
  38 /*
  39  * Fault handler for the copy{in,out} functions below.
  40  */
  41 ENTRY(copyio_fault)
  42         SET_FAULT_HANDLER(xzr, x1) /* Clear the handler */
  43         mov     x0, #EFAULT
  44         ret
  45 END(copyio_fault)
  46
  47 /*
  48  * Copies from a kernel to user address
  49  *
  50  * int copyout(const void *kaddr, void *udaddr, size_t len)
  51  */
  52 ENTRY(copyout)
  53         cbz     x2, 2f          /* If len == 0 then skip loop */
  54
  55         adr     x6, copyio_fault /* Get the handler address */
  56         SET_FAULT_HANDLER(x6, x7) /* Set the handler */
  57
  58 1:      ldrb    w4, [x0], #1    /* Load from kaddr */
  59         strb    w4, [x1], #1    /* Store in uaddr */
  60         sub     x2, x2, #1      /* len-- */
  61         cbnz    x2, 1b
  62
  63         SET_FAULT_HANDLER(xzr, x7) /* Clear the handler */
  64
  65 2:      mov     x0, xzr         /* return 0 */
  66         ret
  67 END(copyout)
  68
  69 /*
  70  * Copies from a user to kernel address
  71  *
  72  * int copyin(const void *uaddr, void *kdaddr, size_t len)
  73  */
  74 ENTRY(copyin)
  75         cbz     x2, 2f          /* If len == 0 then skip loop */
  76
  77         adr     x6, copyio_fault /* Get the handler address */
  78         SET_FAULT_HANDLER(x6, x7) /* Set the handler */
  79
  80 1:      ldrb    w4, [x0], #1    /* Load from uaddr */
  81         strb    w4, [x1], #1    /* Store in kaddr */
  82         sub     x2, x2, #1      /* len-- */
  83         cbnz    x2, 1b
  84
  85         SET_FAULT_HANDLER(xzr, x7) /* Clear the handler */
  86
  87 2:      mov     x0, xzr         /* return 0 */
  88         ret
  89 END(copyin)
  90
  91 /*
  92  * Copies a string from a user to kernel address
  93  *
  94  * int copyinstr(const void *udaddr, void *kaddr, size_t len, size_t *done)
  95  */
  96 ENTRY(copyinstr)
  97         mov     x5, xzr         /* count = 0 */
  98         cbz     x2, 3f          /* If len == 0 then skip loop */
  99
 100         adr     x6, copyio_fault /* Get the handler address */
 101         SET_FAULT_HANDLER(x6, x7) /* Set the handler */
 102
 103 1:      ldrb    w4, [x0], #1    /* Load from uaddr */
 104         strb    w4, [x1], #1    /* Store in kaddr */
 105         cbz     w4, 2f          /* If == 0 then break */
 106         sub     x2, x2, #1      /* len-- */
 107         add     x5, x5, #1      /* count++ */
 108         cbnz    x2, 1b
 109
 110 2:      SET_FAULT_HANDLER(xzr, x7) /* Clear the handler */
 111
 112 3:      cbz     x3, 4f          /* Check if done != NULL */
 113         add     x5, x5, #1      /* count++ */
 114         str     x5, [x3]        /* done = count */
 115
 116 4:      mov     x0, xzr         /* return 0 */
 117         ret
 118 END(copyinstr)