sys/arm64/arm64/exception.S

   1 /*-
   2  * Copyright (c) 2014 Andrew Turner
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  */
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 #include "assym.s"
  32
  33         .text
  34
  35 .macro  save_registers el
  36 .if \el == 1
  37         mov     x18, sp
  38         sub     sp, sp, #128
  39 .endif
  40         sub     sp, sp, #(TF_SIZE + 16)
  41         stp     x29, x30, [sp, #(TF_SIZE)]
  42         stp     x28, x29, [sp, #(TF_X + 28 * 8)]
  43         stp     x26, x27, [sp, #(TF_X + 26 * 8)]
  44         stp     x24, x25, [sp, #(TF_X + 24 * 8)]
  45         stp     x22, x23, [sp, #(TF_X + 22 * 8)]
  46         stp     x20, x21, [sp, #(TF_X + 20 * 8)]
  47         stp     x18, x19, [sp, #(TF_X + 18 * 8)]
  48         stp     x16, x17, [sp, #(TF_X + 16 * 8)]
  49         stp     x14, x15, [sp, #(TF_X + 14 * 8)]
  50         stp     x12, x13, [sp, #(TF_X + 12 * 8)]
  51         stp     x10, x11, [sp, #(TF_X + 10 * 8)]
  52         stp     x8,  x9,  [sp, #(TF_X + 8  * 8)]
  53         stp     x6,  x7,  [sp, #(TF_X + 6  * 8)]
  54         stp     x4,  x5,  [sp, #(TF_X + 4  * 8)]
  55         stp     x2,  x3,  [sp, #(TF_X + 2  * 8)]
  56         stp     x0,  x1,  [sp, #(TF_X + 0  * 8)]
  57         mrs     x10, elr_el1
  58         mrs     x11, spsr_el1
  59 .if \el == 0
  60         mrs     x18, sp_el0
  61 .endif
  62         stp     x10, x11, [sp, #(TF_ELR)]
  63         stp     x18,  lr, [sp, #(TF_SP)]
  64         mrs     x18, tpidr_el1
  65         add     x29, sp, #(TF_SIZE)
  66 .endm
  67
  68 .macro  restore_registers el
  69 .if \el == 1
  70         msr     daifset, #2
  71         /*
  72          * Disable interrupts, x18 may change in the interrupt exception
  73          * handler.  For EL0 exceptions, do_ast already did this.
  74          */
  75 .endif
  76         ldp     x18,  lr, [sp, #(TF_SP)]
  77         ldp     x10, x11, [sp, #(TF_ELR)]
  78 .if \el == 0
  79         msr     sp_el0, x18
  80 .endif
  81         msr     spsr_el1, x11
  82         msr     elr_el1, x10
  83         ldp     x0,  x1,  [sp, #(TF_X + 0  * 8)]
  84         ldp     x2,  x3,  [sp, #(TF_X + 2  * 8)]
  85         ldp     x4,  x5,  [sp, #(TF_X + 4  * 8)]
  86         ldp     x6,  x7,  [sp, #(TF_X + 6  * 8)]
  87         ldp     x8,  x9,  [sp, #(TF_X + 8  * 8)]
  88         ldp     x10, x11, [sp, #(TF_X + 10 * 8)]
  89         ldp     x12, x13, [sp, #(TF_X + 12 * 8)]
  90         ldp     x14, x15, [sp, #(TF_X + 14 * 8)]
  91         ldp     x16, x17, [sp, #(TF_X + 16 * 8)]
  92 .if \el == 0
  93         /*
  94          * We only restore the callee saved registers when returning to
  95          * userland as they may have been updated by a system call or signal.
  96          */
  97         ldp     x18, x19, [sp, #(TF_X + 18 * 8)]
  98         ldp     x20, x21, [sp, #(TF_X + 20 * 8)]
  99         ldp     x22, x23, [sp, #(TF_X + 22 * 8)]
 100         ldp     x24, x25, [sp, #(TF_X + 24 * 8)]
 101         ldp     x26, x27, [sp, #(TF_X + 26 * 8)]
 102         ldp     x28, x29, [sp, #(TF_X + 28 * 8)]
 103 .else
 104         ldr          x29, [sp, #(TF_X + 29 * 8)]
 105 .endif
 106 .if \el == 0
 107         add     sp, sp, #(TF_SIZE + 16)
 108 .else
 109         mov     sp, x18
 110         mrs     x18, tpidr_el1
 111 .endif
 112 .endm
 113
 114 .macro  do_ast
 115         /* Disable interrupts */
 116         mrs     x19, daif
 117 1:
 118         msr     daifset, #2
 119
 120         /* Read the current thread flags */
 121         ldr     x1, [x18, #PC_CURTHREAD]        /* Load curthread */
 122         ldr     x2, [x1, #TD_FLAGS]
 123
 124         /* Check if we have either bits set */
 125         mov     x3, #((TDF_ASTPENDING|TDF_NEEDRESCHED) >> 8)
 126         lsl     x3, x3, #8
 127         and     x2, x2, x3
 128         cbz     x2, 2f
 129
 130         /* Restore interrupts */
 131         msr     daif, x19
 132
 133         /* handle the ast */
 134         mov     x0, sp
 135         bl      _C_LABEL(ast)
 136
 137         /* Re-check for new ast scheduled */
 138         b       1b
 139 2:
 140 .endm
 141
 142 ENTRY(handle_el1h_sync)
 143         save_registers 1
 144         mov     x0, sp
 145         bl      do_el1h_sync
 146         restore_registers 1
 147         eret
 148 END(handle_el1h_sync)
 149
 150 ENTRY(handle_el1h_irq)
 151         save_registers 1
 152         mov     x0, sp
 153         bl      intr_irq_handler
 154         restore_registers 1
 155         eret
 156 END(handle_el1h_irq)
 157
 158 ENTRY(handle_el1h_error)
 159         brk     0xf13
 160 END(handle_el1h_error)
 161
 162 ENTRY(handle_el0_sync)
 163         save_registers 0
 164         mov     x0, sp
 165         bl      do_el0_sync
 166         do_ast
 167         restore_registers 0
 168         eret
 169 END(handle_el0_sync)
 170
 171 ENTRY(handle_el0_irq)
 172         save_registers 0
 173         mov     x0, sp
 174         bl      intr_irq_handler
 175         do_ast
 176         restore_registers 0
 177         eret
 178 END(handle_el0_irq)
 179
 180 ENTRY(handle_el0_error)
 181         save_registers 0
 182         mov     x0, sp
 183         bl      do_el0_error
 184         brk     0xf23
 185         1: b 1b
 186 END(handle_el0_error)
 187
 188 .macro  vempty
 189         .align 7
 190         brk     0xfff
 191         1: b    1b
 192 .endm
 193
 194 .macro  vector  name
 195         .align 7
 196         b       handle_\name
 197 .endm
 198
 199         .align 11
 200         .globl exception_vectors
 201 exception_vectors:
 202         vempty                  /* Synchronous EL1t */
 203         vempty                  /* IRQ EL1t */
 204         vempty                  /* FIQ EL1t */
 205         vempty                  /* Error EL1t */
 206
 207         vector el1h_sync        /* Synchronous EL1h */
 208         vector el1h_irq         /* IRQ EL1h */
 209         vempty                  /* FIQ EL1h */
 210         vector el1h_error       /* Error EL1h */
 211
 212         vector el0_sync         /* Synchronous 64-bit EL0 */
 213         vector el0_irq          /* IRQ 64-bit EL0 */
 214         vempty                  /* FIQ 64-bit EL0 */
 215         vector el0_error        /* Error 64-bit EL0 */
 216
 217         vempty                  /* Synchronous 32-bit EL0 */
 218         vempty                  /* IRQ 32-bit EL0 */
 219         vempty                  /* FIQ 32-bit EL0 */
 220         vempty                  /* Error 32-bit EL0 */
 221