sys/arm64/arm64/exception.S

   1 /*-
   2  * Copyright (c) 2014 Andrew Turner
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  */
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 #include "assym.s"
  32
  33         .text
  34
  35 .macro  save_registers el
  36 .if \el == 1
  37         mov     x18, sp
  38         sub     sp, sp, #128
  39 .endif
  40         sub     sp, sp, #(TF_SIZE + 16)
  41         stp     x29, x30, [sp, #(TF_SIZE)]
  42         stp     x28, x29, [sp, #(TF_X + 28 * 8)]
  43         stp     x26, x27, [sp, #(TF_X + 26 * 8)]
  44         stp     x24, x25, [sp, #(TF_X + 24 * 8)]
  45         stp     x22, x23, [sp, #(TF_X + 22 * 8)]
  46         stp     x20, x21, [sp, #(TF_X + 20 * 8)]
  47         stp     x18, x19, [sp, #(TF_X + 18 * 8)]
  48         stp     x16, x17, [sp, #(TF_X + 16 * 8)]
  49         stp     x14, x15, [sp, #(TF_X + 14 * 8)]
  50         stp     x12, x13, [sp, #(TF_X + 12 * 8)]
  51         stp     x10, x11, [sp, #(TF_X + 10 * 8)]
  52         stp     x8,  x9,  [sp, #(TF_X + 8  * 8)]
  53         stp     x6,  x7,  [sp, #(TF_X + 6  * 8)]
  54         stp     x4,  x5,  [sp, #(TF_X + 4  * 8)]
  55         stp     x2,  x3,  [sp, #(TF_X + 2  * 8)]
  56         stp     x0,  x1,  [sp, #(TF_X + 0  * 8)]
  57         mrs     x10, elr_el1
  58         mrs     x11, spsr_el1
  59 .if \el == 0
  60         mrs     x18, sp_el0
  61 .endif
  62         stp     x10, x11, [sp, #(TF_ELR)]
  63         stp     x18,  lr, [sp, #(TF_SP)]
  64         mrs     x18, tpidr_el1
  65         add     x29, sp, #(TF_SIZE)
  66 .endm
  67
  68 .macro  restore_registers el
  69 .if \el == 1
  70         msr     daifset, #2
  71         /*
  72          * Disable interrupts, x18 may change in the interrupt exception
  73          * handler.  For EL0 exceptions, do_ast already did this.
  74          */
  75 .endif
  76         ldp     x18,  lr, [sp, #(TF_SP)]
  77         ldp     x10, x11, [sp, #(TF_ELR)]
  78 .if \el == 0
  79         msr     sp_el0, x18
  80 .endif
  81         msr     spsr_el1, x11
  82         msr     elr_el1, x10
  83         ldp     x0,  x1,  [sp, #(TF_X + 0  * 8)]
  84         ldp     x2,  x3,  [sp, #(TF_X + 2  * 8)]
  85         ldp     x4,  x5,  [sp, #(TF_X + 4  * 8)]
  86         ldp     x6,  x7,  [sp, #(TF_X + 6  * 8)]
  87         ldp     x8,  x9,  [sp, #(TF_X + 8  * 8)]
  88         ldp     x10, x11, [sp, #(TF_X + 10 * 8)]
  89         ldp     x12, x13, [sp, #(TF_X + 12 * 8)]
  90         ldp     x14, x15, [sp, #(TF_X + 14 * 8)]
  91         ldp     x16, x17, [sp, #(TF_X + 16 * 8)]
  92 .if \el == 0
  93         ldp     x18, x19, [sp, #(TF_X + 18 * 8)]
  94 .else
  95         ldr          x19, [sp, #(TF_X + 19 * 8)]
  96 .endif
  97         ldp     x20, x21, [sp, #(TF_X + 20 * 8)]
  98         ldp     x22, x23, [sp, #(TF_X + 22 * 8)]
  99         ldp     x24, x25, [sp, #(TF_X + 24 * 8)]
 100         ldp     x26, x27, [sp, #(TF_X + 26 * 8)]
 101         ldp     x28, x29, [sp, #(TF_X + 28 * 8)]
 102 .if \el == 0
 103         add     sp, sp, #(TF_SIZE + 16)
 104 .else
 105         mov     sp, x18
 106         mrs     x18, tpidr_el1
 107 .endif
 108 .endm
 109
 110 .macro  do_ast
 111         /* Disable interrupts */
 112         mrs     x19, daif
 113 1:
 114         msr     daifset, #2
 115
 116         /* Read the current thread flags */
 117         ldr     x1, [x18, #PC_CURTHREAD]        /* Load curthread */
 118         ldr     x2, [x1, #TD_FLAGS]
 119
 120         /* Check if we have either bits set */
 121         mov     x3, #((TDF_ASTPENDING|TDF_NEEDRESCHED) >> 8)
 122         lsl     x3, x3, #8
 123         and     x2, x2, x3
 124         cbz     x2, 2f
 125
 126         /* Restore interrupts */
 127         msr     daif, x19
 128
 129         /* handle the ast */
 130         mov     x0, sp
 131         bl      _C_LABEL(ast)
 132
 133         /* Re-check for new ast scheduled */
 134         b       1b
 135 2:
 136 .endm
 137
 138 ENTRY(handle_el1h_sync)
 139         save_registers 1
 140         mov     x0, sp
 141         bl      do_el1h_sync
 142         restore_registers 1
 143         eret
 144 END(handle_el1h_sync)
 145
 146 ENTRY(handle_el1h_irq)
 147         save_registers 1
 148         mov     x0, sp
 149         bl      arm_cpu_intr
 150         restore_registers 1
 151         eret
 152 END(handle_el1h_irq)
 153
 154 ENTRY(handle_el1h_error)
 155         brk     0xf13
 156 END(handle_el1h_error)
 157
 158 ENTRY(handle_el0_sync)
 159         save_registers 0
 160         mov     x0, sp
 161         bl      do_el0_sync
 162         do_ast
 163         restore_registers 0
 164         eret
 165 END(handle_el0_sync)
 166
 167 ENTRY(handle_el0_irq)
 168         save_registers 0
 169         mov     x0, sp
 170         bl      arm_cpu_intr
 171         do_ast
 172         restore_registers 0
 173         eret
 174 END(handle_el0_irq)
 175
 176 ENTRY(handle_el0_error)
 177         save_registers 0
 178         mov     x0, sp
 179         bl      do_el0_error
 180         brk     0xf23
 181         1: b 1b
 182 END(handle_el0_error)
 183
 184 .macro  vempty
 185         .align 7
 186         brk     0xfff
 187         1: b    1b
 188 .endm
 189
 190 .macro  vector  name
 191         .align 7
 192         b       handle_\name
 193 .endm
 194
 195         .align 11
 196         .globl exception_vectors
 197 exception_vectors:
 198         vempty                  /* Synchronous EL1t */
 199         vempty                  /* IRQ EL1t */
 200         vempty                  /* FIQ EL1t */
 201         vempty                  /* Error EL1t */
 202
 203         vector el1h_sync        /* Synchronous EL1h */
 204         vector el1h_irq         /* IRQ EL1h */
 205         vempty                  /* FIQ EL1h */
 206         vector el1h_error       /* Error EL1h */
 207
 208         vector el0_sync         /* Synchronous 64-bit EL0 */
 209         vector el0_irq          /* IRQ 64-bit EL0 */
 210         vempty                  /* FIQ 64-bit EL0 */
 211         vector el0_error        /* Error 64-bit EL0 */
 212
 213         vempty                  /* Synchronous 32-bit EL0 */
 214         vempty                  /* IRQ 32-bit EL0 */
 215         vempty                  /* FIQ 32-bit EL0 */
 216         vempty                  /* Error 32-bit EL0 */
 217