sys/arm64/arm64/exception.S

   1 /*-
   2  * Copyright (c) 2014 Andrew Turner
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  */
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 #include "assym.s"
  32
  33         .text
  34
  35 .macro  save_registers el
  36 .if \el == 1
  37         mov     x18, sp
  38         sub     sp, sp, #128
  39 .endif
  40         stp     x28, x29, [sp, #-16]!
  41         stp     x26, x27, [sp, #-16]!
  42         stp     x24, x25, [sp, #-16]!
  43         stp     x22, x23, [sp, #-16]!
  44         stp     x20, x21, [sp, #-16]!
  45         stp     x18, x19, [sp, #-16]!
  46         stp     x16, x17, [sp, #-16]!
  47         stp     x14, x15, [sp, #-16]!
  48         stp     x12, x13, [sp, #-16]!
  49         stp     x10, x11, [sp, #-16]!
  50         stp     x8, x9, [sp, #-16]!
  51         stp     x6, x7, [sp, #-16]!
  52         stp     x4, x5, [sp, #-16]!
  53         stp     x2, x3, [sp, #-16]!
  54         stp     x0, x1, [sp, #-16]!
  55         mrs     x10, elr_el1
  56         mrs     x11, spsr_el1
  57 .if \el == 0
  58         mrs     x18, sp_el0
  59 .endif
  60         stp     x10, x11, [sp, #-16]!
  61         stp     x18, lr, [sp, #-16]!
  62         mrs     x18, tpidr_el1
  63 .endm
  64
  65 .macro  restore_registers el
  66         msr     daifset, #2             /* Disable interrupts, x18 may change
  67                                          * in the interrupt exception handler */
  68         ldp     x18, lr, [sp], #16
  69         ldp     x10, x11, [sp], #16
  70 .if \el == 0
  71         msr     sp_el0, x18
  72 .endif
  73         msr     spsr_el1, x11
  74         msr     elr_el1, x10
  75         ldp     x0, x1, [sp], #16
  76         ldp     x2, x3, [sp], #16
  77         ldp     x4, x5, [sp], #16
  78         ldp     x6, x7, [sp], #16
  79         ldp     x8, x9, [sp], #16
  80         ldp     x10, x11, [sp], #16
  81         ldp     x12, x13, [sp], #16
  82         ldp     x14, x15, [sp], #16
  83         ldp     x16, x17, [sp], #16
  84 .if \el == 0
  85         ldp     x18, x19, [sp], #16
  86 .else
  87         ldp     xzr, x19, [sp], #16
  88 .endif
  89         ldp     x20, x21, [sp], #16
  90         ldp     x22, x23, [sp], #16
  91         ldp     x24, x25, [sp], #16
  92         ldp     x26, x27, [sp], #16
  93         ldp     x28, x29, [sp], #16
  94 .if \el == 1
  95         mov     sp, x18
  96         mrs     x18, tpidr_el1
  97 .endif
  98 .endm
  99
 100 .macro  do_ast
 101         /* Disable interrupts */
 102         mrs     x19, daif
 103         msr     daifset, #2
 104
 105         /* Read the current thread flags */
 106 1:      ldr     x1, [x18, #PC_CURTHREAD]        /* Load curthread */
 107         ldr     x2, [x1, #TD_FLAGS]
 108
 109         /* Check if we have either bits set */
 110         mov     x3, #((TDF_ASTPENDING|TDF_NEEDRESCHED) >> 8)
 111         lsl     x3, x3, #8
 112         and     x2, x2, x3
 113         cmp     x2, #0
 114         b.eq    2f
 115
 116         /* Restore interrupts */
 117         msr     daif, x19
 118
 119         /* handle the ast */
 120         mov     x0, sp
 121         bl      _C_LABEL(ast)
 122
 123         /* Disable interrupts */
 124         mrs     x19, daif
 125         msr     daifset, #2
 126
 127 2:
 128         /* Restore interrupts */
 129         msr     daif, x19
 130 .endm
 131
 132 handle_el1h_sync:
 133         save_registers 1
 134         mov     x0, sp
 135         bl      do_el1h_sync
 136         restore_registers 1
 137         eret
 138
 139 handle_el1h_irq:
 140         save_registers 1
 141         mov     x0, sp
 142         bl      arm_cpu_intr
 143         restore_registers 1
 144         eret
 145
 146 handle_el1h_error:
 147         brk     0xf13
 148
 149 handle_el0_sync:
 150         save_registers 0
 151         mov     x0, sp
 152         bl      do_el0_sync
 153         do_ast
 154         restore_registers 0
 155         eret
 156
 157 handle_el0_irq:
 158         save_registers 0
 159         mov     x0, sp
 160         bl      arm_cpu_intr
 161         restore_registers 0
 162         eret
 163
 164 handle_el0_error:
 165         save_registers 0
 166         mov     x0, sp
 167         bl      do_el0_error
 168         brk     0xf23
 169         1: b 1b
 170
 171 .macro  vempty
 172         .align 7
 173         brk     0xfff
 174         1: b    1b
 175 .endm
 176
 177 .macro  vector  name
 178         .align 7
 179         b       handle_\name
 180 .endm
 181
 182         .align 11
 183         .globl exception_vectors
 184 exception_vectors:
 185         vempty                  /* Synchronous EL1t */
 186         vempty                  /* IRQ EL1t */
 187         vempty                  /* FIQ EL1t */
 188         vempty                  /* Error EL1t */
 189
 190         vector el1h_sync        /* Synchronous EL1h */
 191         vector el1h_irq         /* IRQ EL1h */
 192         vempty                  /* FIQ EL1h */
 193         vector el1h_error       /* Error EL1h */
 194
 195         vector el0_sync         /* Synchronous 64-bit EL0 */
 196         vector el0_irq          /* IRQ 64-bit EL0 */
 197         vempty                  /* FIQ 64-bit EL0 */
 198         vector el0_error        /* Error 64-bit EL0 */
 199
 200         vempty                  /* Synchronous 32-bit EL0 */
 201         vempty                  /* IRQ 32-bit EL0 */
 202         vempty                  /* FIQ 32-bit EL0 */
 203         vempty                  /* Error 32-bit EL0 */
 204