sys/arm64/arm64/swtch.S

   1 /*-
   2  * Copyright (c) 2014 Andrew Turner
   3  * Copyright (c) 2014 The FreeBSD Foundation
   4  * All rights reserved.
   5  *
   6  * This software was developed by Andrew Turner under sponsorship from
   7  * the FreeBSD Foundation.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  *
  18  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  19  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  22  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  24  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  25  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  26  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  27  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  28  * SUCH DAMAGE.
  29  *
  30  */
  31
  32 #include "assym.s"
  33 #include "opt_kstack_pages.h"
  34 #include "opt_sched.h"
  35
  36 #include <machine/asm.h>
  37
  38 __FBSDID("$FreeBSD$");
  39
  40 /*
  41  * void cpu_throw(struct thread *old, struct thread *new)
  42  */
  43 ENTRY(cpu_throw)
  44 #ifdef VFP
  45         /* Backup the new thread pointer around a call to C code */
  46         mov     x19, x1
  47         bl      vfp_discard
  48         mov     x1, x19
  49 #endif
  50
  51         /* Store the new curthread */
  52         str     x1, [x18, #PC_CURTHREAD]
  53         /* And the new pcb */
  54         ldr     x4, [x1, #TD_PCB]
  55         str     x4, [x18, #PC_CURPCB]
  56
  57         /*
  58          * TODO: We may need to flush the cache here.
  59          */
  60
  61         /* Switch to the new pmap */
  62         ldr     x5, [x4, #PCB_L1ADDR]
  63         msr     ttbr0_el1, x5
  64         isb
  65
  66         /* Invalidate the TLB */
  67         dsb     sy
  68         tlbi    vmalle1is
  69         dsb     sy
  70         isb
  71
  72         /* Restore the registers */
  73         ldp     x5, x6, [x4, #PCB_SP]
  74         mov     sp, x5
  75         msr     tpidr_el0, x6
  76         ldp     x8, x9, [x4, #PCB_REGS + 8 * 8]
  77         ldp     x10, x11, [x4, #PCB_REGS + 10 * 8]
  78         ldp     x12, x13, [x4, #PCB_REGS + 12 * 8]
  79         ldp     x14, x15, [x4, #PCB_REGS + 14 * 8]
  80         ldp     x16, x17, [x4, #PCB_REGS + 16 * 8]
  81         ldr          x19, [x4, #PCB_REGS + 19 * 8]
  82         ldp     x20, x21, [x4, #PCB_REGS + 20 * 8]
  83         ldp     x22, x23, [x4, #PCB_REGS + 22 * 8]
  84         ldp     x24, x25, [x4, #PCB_REGS + 24 * 8]
  85         ldp     x26, x27, [x4, #PCB_REGS + 26 * 8]
  86         ldp     x28, x29, [x4, #PCB_REGS + 28 * 8]
  87         ldr     x30, [x4, #PCB_REGS + 30 * 8]
  88
  89         ret
  90 END(cpu_throw)
  91
  92 /*
  93  * void cpu_switch(struct thread *old, struct thread *new, struct mtx *mtx)
  94  *
  95  * x0 = old
  96  * x1 = new
  97  * x2 = mtx
  98  * x3 to x7, x16 and x17 are caller saved
  99  */
 100 ENTRY(cpu_switch)
 101         /* Store the new curthread */
 102         str     x1, [x18, #PC_CURTHREAD]
 103         /* And the new pcb */
 104         ldr     x4, [x1, #TD_PCB]
 105         str     x4, [x18, #PC_CURPCB]
 106
 107         /*
 108          * Save the old context.
 109          */
 110         ldr     x4, [x0, #TD_PCB]
 111
 112         /* Store the callee-saved registers */
 113         stp     x8, x9, [x4, #PCB_REGS + 8 * 8]
 114         stp     x10, x11, [x4, #PCB_REGS + 10 * 8]
 115         stp     x12, x13, [x4, #PCB_REGS + 12 * 8]
 116         stp     x14, x15, [x4, #PCB_REGS + 14 * 8]
 117         stp     x16, x17, [x4, #PCB_REGS + 16 * 8]
 118         stp     x18, x19, [x4, #PCB_REGS + 18 * 8]
 119         stp     x20, x21, [x4, #PCB_REGS + 20 * 8]
 120         stp     x22, x23, [x4, #PCB_REGS + 22 * 8]
 121         stp     x24, x25, [x4, #PCB_REGS + 24 * 8]
 122         stp     x26, x27, [x4, #PCB_REGS + 26 * 8]
 123         stp     x28, x29, [x4, #PCB_REGS + 28 * 8]
 124         str     x30, [x4, #PCB_REGS + 30 * 8]
 125         /* And the old stack pointer */
 126         mov     x5, sp
 127         mrs     x6, tpidr_el0
 128         stp     x5, x6, [x4, #PCB_SP]
 129
 130 #ifdef VFP
 131         mov     x19, x0
 132         mov     x20, x1
 133         mov     x21, x2
 134         bl      vfp_save_state
 135         mov     x2, x21
 136         mov     x1, x20
 137         mov     x0, x19
 138 #endif
 139
 140         /*
 141          * Restore the saved context.
 142          */
 143         ldr     x4, [x1, #TD_PCB]
 144
 145         /*
 146          * TODO: We may need to flush the cache here if switching
 147          * to a user process.
 148          */
 149
 150         /* Switch to the new pmap */
 151         ldr     x5, [x4, #PCB_L1ADDR]
 152         msr     ttbr0_el1, x5
 153         isb
 154
 155         /* Invalidate the TLB */
 156         dsb     sy
 157         tlbi    vmalle1is
 158         dsb     sy
 159         isb
 160
 161         /* Release the old thread */
 162         str     x2, [x0, #TD_LOCK]
 163 #if defined(SCHED_ULE) && defined(SMP)
 164         /* Read the value in blocked_lock */
 165         ldr     x0, =_C_LABEL(blocked_lock)
 166         ldr     x1, [x0]
 167         /* Load curthread */
 168         ldr     x2, [x18, #PC_CURTHREAD]
 169 1:
 170         ldr     x3, [x2, #TD_LOCK]
 171         cmp     x3, x1
 172         b.eq    1b
 173 #endif
 174
 175         /* Restore the registers */
 176         ldp     x5, x6, [x4, #PCB_SP]
 177         mov     sp, x5
 178         msr     tpidr_el0, x6
 179         ldp     x8, x9, [x4, #PCB_REGS + 8 * 8]
 180         ldp     x10, x11, [x4, #PCB_REGS + 10 * 8]
 181         ldp     x12, x13, [x4, #PCB_REGS + 12 * 8]
 182         ldp     x14, x15, [x4, #PCB_REGS + 14 * 8]
 183         ldp     x16, x17, [x4, #PCB_REGS + 16 * 8]
 184         ldr          x19, [x4, #PCB_REGS + 19 * 8]
 185         ldp     x20, x21, [x4, #PCB_REGS + 20 * 8]
 186         ldp     x22, x23, [x4, #PCB_REGS + 22 * 8]
 187         ldp     x24, x25, [x4, #PCB_REGS + 24 * 8]
 188         ldp     x26, x27, [x4, #PCB_REGS + 26 * 8]
 189         ldp     x28, x29, [x4, #PCB_REGS + 28 * 8]
 190         ldr     x30, [x4, #PCB_REGS + 30 * 8]
 191
 192         str     xzr, [x4, #PCB_REGS + 18 * 8]
 193         ret
 194 .Lcpu_switch_panic_str:
 195         .asciz "cpu_switch: %p\0"
 196 END(cpu_switch)
 197
 198 ENTRY(fork_trampoline)
 199         mov     x0, x8
 200         mov     x1, x9
 201         mov     x2, sp
 202         mov     fp, #0  /* Stack traceback stops here. */
 203         bl      _C_LABEL(fork_exit)
 204
 205         /* Restore sp and lr */
 206         ldp     x0, x1, [sp]
 207         msr     sp_el0, x0
 208         mov     lr, x1
 209
 210         /* Restore the registers other than x0 and x1 */
 211         ldp     x2, x3, [sp, #TF_X + 2 * 8]
 212         ldp     x4, x5, [sp, #TF_X + 4 * 8]
 213         ldp     x6, x7, [sp, #TF_X + 6 * 8]
 214         ldp     x8, x9, [sp, #TF_X + 8 * 8]
 215         ldp     x10, x11, [sp, #TF_X + 10 * 8]
 216         ldp     x12, x13, [sp, #TF_X + 12 * 8]
 217         ldp     x14, x15, [sp, #TF_X + 14 * 8]
 218         ldp     x16, x17, [sp, #TF_X + 16 * 8]
 219         ldr          x19, [sp, #TF_X + 19 * 8]
 220         ldp     x20, x21, [sp, #TF_X + 20 * 8]
 221         ldp     x22, x23, [sp, #TF_X + 22 * 8]
 222         ldp     x24, x25, [sp, #TF_X + 24 * 8]
 223         ldp     x26, x27, [sp, #TF_X + 26 * 8]
 224         ldp     x28, x29, [sp, #TF_X + 28 * 8]
 225         /* Skip x30 as it was restored above as lr */
 226
 227         /*
 228          * Disable interrupts to avoid
 229          * overwriting spsr_el1 by an IRQ exception.
 230          */
 231         msr     daifset, #2
 232
 233         /* Restore elr and spsr */
 234         ldp     x0, x1, [sp, #16]
 235         msr     elr_el1, x0
 236         msr     spsr_el1, x1
 237
 238         /* Finally x0 and x1 */
 239         ldp     x0, x1, [sp, #TF_X + 0 * 8]
 240         ldr     x18, [sp, #TF_X + 18 * 8]
 241
 242         /*
 243          * No need for interrupts reenabling since PSR
 244          * will be set to the desired value anyway.
 245          */
 246         eret
 247
 248 END(fork_trampoline)
 249
 250 ENTRY(savectx)
 251         /* Store the callee-saved registers */
 252         stp     x8,  x9,  [x0, #PCB_REGS + 8 * 8]
 253         stp     x10, x11, [x0, #PCB_REGS + 10 * 8]
 254         stp     x12, x13, [x0, #PCB_REGS + 12 * 8]
 255         stp     x14, x15, [x0, #PCB_REGS + 14 * 8]
 256         stp     x16, x17, [x0, #PCB_REGS + 16 * 8]
 257         stp     x18, x19, [x0, #PCB_REGS + 18 * 8]
 258         stp     x20, x21, [x0, #PCB_REGS + 20 * 8]
 259         stp     x22, x23, [x0, #PCB_REGS + 22 * 8]
 260         stp     x24, x25, [x0, #PCB_REGS + 24 * 8]
 261         stp     x26, x27, [x0, #PCB_REGS + 26 * 8]
 262         stp     x28, x29, [x0, #PCB_REGS + 28 * 8]
 263         str     x30, [x0, #PCB_REGS + 30 * 8]
 264         /* And the old stack pointer */
 265         mov     x5, sp
 266         mrs     x6, tpidr_el0
 267         stp     x5, x6, [x0, #PCB_SP]
 268
 269         /* Store the VFP registers */
 270 #ifdef VFP
 271         mov     x29, lr
 272         bl      vfp_save_state
 273         mov     lr, x29
 274 #endif
 275
 276         ret
 277 END(savectx)
 278