sys/boot/powerpc/ps3/ldscript.powerpc

   1 /* $FreeBSD$ */
   2
   3 OUTPUT_FORMAT("elf32-powerpc-freebsd", "elf32-powerpc-freebsd",
   4               "elf32-powerpc-freebsd")
   5 OUTPUT_ARCH(powerpc:common)
   6 ENTRY(_start)
   7 SEARCH_DIR(/usr/lib);
   8 PROVIDE (__stack = 0);
   9 SECTIONS
  10 {
  11   /* Read-only sections, merged into text segment: */
  12   . = 0x0;
  13   .text      :
  14   {
  15     *(.text)
  16     /* .gnu.warning sections are handled specially by elf32.em.  */
  17     *(.gnu.warning)
  18     *(.gnu.linkonce.t*)
  19   } =0
  20   _etext = .;
  21   .interp     : { *(.interp)    }
  22   .hash          : { *(.hash)           }
  23   .dynsym        : { *(.dynsym)         }
  24   .dynstr        : { *(.dynstr)         }
  25   .gnu.version   : { *(.gnu.version)    }
  26   .gnu.version_d   : { *(.gnu.version_d)        }
  27   .gnu.version_r   : { *(.gnu.version_r)        }
  28   .rela.text     :
  29     { *(.rela.text) *(.rela.gnu.linkonce.t*) }
  30   .rela.data     :
  31     { *(.rela.data) *(.rela.gnu.linkonce.d*) }
  32   .rela.rodata   :
  33     { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
  34   .rela.got      : { *(.rela.got)               }
  35   .rela.got1     : { *(.rela.got1)              }
  36   .rela.got2     : { *(.rela.got2)              }
  37   .rela.ctors    : { *(.rela.ctors)     }
  38   .rela.dtors    : { *(.rela.dtors)     }
  39   .rela.init     : { *(.rela.init)      }
  40   .rela.fini     : { *(.rela.fini)      }
  41   .rela.bss      : { *(.rela.bss)               }
  42   .rela.plt      : { *(.rela.plt)               }
  43   .rela.sbss     : { *(.rela.sbss)              }
  44   .rela.sbss2    : { *(.rela.sbss2)             }
  45   .text      :
  46   {
  47     *(.text)
  48     /* .gnu.warning sections are handled specially by elf32.em.  */
  49     *(.gnu.warning)
  50     *(.gnu.linkonce.t*)
  51   } =0
  52   _etext = .;
  53   PROVIDE (etext = .);
  54   .init      : { *(.init)    } =0
  55   .fini      : { *(.fini)    } =0
  56   .rodata    : { *(.rodata) *(.gnu.linkonce.r*) }
  57   .rodata1   : { *(.rodata1) }
  58   .sbss2     : { *(.sbss2)   }
  59   /* Adjust the address for the data segment to the next page up. */
  60   . = ((. + 0x1000) & ~(0x1000 - 1));
  61   .data    :
  62   {
  63     *(.data)
  64     *(.gnu.linkonce.d*)
  65     CONSTRUCTORS
  66   }
  67   .data1   : { *(.data1) }
  68   .got1           : { *(.got1) }
  69   .dynamic        : { *(.dynamic) }
  70   /* Put .ctors and .dtors next to the .got2 section, so that the pointers
  71      get relocated with -mrelocatable. Also put in the .fixup pointers.
  72      The current compiler no longer needs this, but keep it around for 2.7.2  */
  73                 PROVIDE (_GOT2_START_ = .);
  74   .got2           :  { *(.got2) }
  75                 PROVIDE (__CTOR_LIST__ = .);
  76   .ctors          : { *(.ctors) }
  77                 PROVIDE (__CTOR_END__ = .);
  78                 PROVIDE (__DTOR_LIST__ = .);
  79   .dtors          : { *(.dtors) }
  80                 PROVIDE (__DTOR_END__ = .);
  81                 PROVIDE (_FIXUP_START_ = .);
  82   .fixup          : { *(.fixup) }
  83                 PROVIDE (_FIXUP_END_ = .);
  84                 PROVIDE (_GOT2_END_ = .);
  85                 PROVIDE (_GOT_START_ = .);
  86   .got            : { *(.got) }
  87   .got.plt        : { *(.got.plt) }
  88                 PROVIDE (_GOT_END_ = .);
  89   _edata  =  .;
  90   PROVIDE (edata = .);
  91   .sbss      :
  92   {
  93     PROVIDE (__sbss_start = .);
  94     *(.sbss)
  95     *(.scommon)
  96     *(.dynsbss)
  97     PROVIDE (__sbss_end = .);
  98   }
  99   .plt   : { *(.plt) }
 100   .bss       :
 101   {
 102    PROVIDE (__bss_start = .);
 103    *(.dynbss)
 104    *(.bss)
 105    *(COMMON)
 106   }
 107   . = ALIGN(4096);
 108   _end = . ;
 109   PROVIDE (end = .);
 110 }
 111