sys/conf/ldscript.arm64

   1 OUTPUT_ARCH(aarch64)
   2 ENTRY(_start)
   3
   4 SEARCH_DIR(/usr/lib);
   5 SECTIONS
   6 {
   7   /* Read-only sections, merged into text segment: */
   8   . = text_start; /* This is set using --defsym= on the command line. */
   9   .text      :
  10   {
  11     *(.text)
  12     *(.stub)
  13     /* .gnu.warning sections are handled specially by elf32.em.  */
  14     *(.gnu.warning)
  15     *(.gnu.linkonce.t*)
  16   } =0x9090
  17   _etext = .;
  18   PROVIDE (etext = .);
  19   .fini      : { *(.fini)    } =0x9090
  20   .rodata    : { *(.rodata*) *(.gnu.linkonce.r*) }
  21   .rodata1   : { *(.rodata1) }
  22    .interp     : { *(.interp)   }
  23   .hash          : { *(.hash)           }
  24   .dynsym        : { *(.dynsym)         }
  25   .dynstr        : { *(.dynstr)         }
  26   .gnu.version   : { *(.gnu.version)    }
  27   .gnu.version_d   : { *(.gnu.version_d)        }
  28   .gnu.version_r   : { *(.gnu.version_r)        }
  29   .note.gnu.build-id : {
  30     PROVIDE (__build_id_start = .);
  31     *(.note.gnu.build-id)
  32     PROVIDE (__build_id_end = .);
  33   }
  34   .rel.text      :
  35     { *(.rel.text) *(.rel.gnu.linkonce.t*) }
  36   .rela.text     :
  37     { *(.rela.text) *(.rela.gnu.linkonce.t*) }
  38   .rel.data      :
  39     { *(.rel.data) *(.rel.gnu.linkonce.d*) }
  40   .rela.data     :
  41     { *(.rela.data) *(.rela.gnu.linkonce.d*) }
  42   .rel.rodata    :
  43     { *(.rel.rodata) *(.rel.gnu.linkonce.r*) }
  44   .rela.rodata   :
  45     { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
  46   .rel.got       : { *(.rel.got)                }
  47   .rela.got      : { *(.rela.got)               }
  48   .rel.ctors     : { *(.rel.ctors)      }
  49   .rela.ctors    : { *(.rela.ctors)     }
  50   .rel.dtors     : { *(.rel.dtors)      }
  51   .rela.dtors    : { *(.rela.dtors)     }
  52   .rel.init      : { *(.rel.init)       }
  53   .rela.init     : { *(.rela.init)      }
  54   .rel.fini      : { *(.rel.fini)       }
  55   .rela.fini     : { *(.rela.fini)      }
  56   .rel.bss       : { *(.rel.bss)                }
  57   .rela.bss      : { *(.rela.bss)               }
  58   .rel.plt       : { *(.rel.plt)                }
  59   .rela.plt      : { *(.rela.plt)               }
  60   .init          : { *(.init)   } =0x9090
  61   .plt      : { *(.plt) }
  62
  63   . = ALIGN(4);
  64   _extab_start = .;
  65   PROVIDE(extab_start = .);
  66   .ARM.extab : { *(.ARM.extab) }
  67   _extab.end = .;
  68   PROVIDE(extab_end = .);
  69
  70   _exidx_start = .;
  71   PROVIDE(exidx_start = .);
  72   .ARM.exidx : { *(.ARM.exidx) }
  73   _exidx_end = .;
  74   PROVIDE(exidx_end = .);
  75
  76   /* Adjust the address for the data segment.  We want to adjust up to
  77      the same address within the page on the next page up.  */
  78   . = ALIGN(0x1000) + (. & (0x1000 - 1)) ;
  79   .data    :
  80   {
  81     *(.data)
  82     *(.gnu.linkonce.d*)
  83   }
  84   . = ALIGN(128);
  85   .data.read_frequently :
  86   {
  87     *(SORT_BY_ALIGNMENT(.data.read_frequently))
  88   }
  89   .data.read_mostly :
  90   {
  91     *(.data.read_mostly)
  92   }
  93   . = ALIGN(128);
  94   .data.exclusive_cache_line :
  95   {
  96     *(.data.exclusive_cache_line)
  97   }
  98   . = ALIGN(128);
  99   .data1   : { *(.data1) }
 100   . = ALIGN(32 / 8);
 101   _start_ctors = .;
 102   PROVIDE (start_ctors = .);
 103   .ctors         :
 104   {
 105     *(.ctors)
 106   }
 107   _stop_ctors = .;
 108   PROVIDE (stop_ctors = .);
 109   .dtors         :
 110   {
 111     *(.dtors)
 112   }
 113   .got           : { *(.got.plt) *(.got) }
 114   .dynamic       : { *(.dynamic) }
 115   /* We want the small data sections together, so single-instruction offsets
 116      can access them all, and initialized data all before uninitialized, so
 117      we can shorten the on-disk segment size.  */
 118   . = ALIGN(8);
 119   .sdata     : { *(.sdata) }
 120   _edata  =  .;
 121   PROVIDE (edata = .);
 122   __bss_start = .;
 123   .sbss      : { *(.sbss) *(.scommon) }
 124   .bss       :
 125   {
 126    *(.dynbss)
 127    *(.bss)
 128    *(COMMON)
 129    . = ALIGN(8);
 130    __bss_end = .;
 131    /* A section for the initial page table, it doesn't need to be in the
 132       kernel file, however unlike normal .bss entries should not be zeroed
 133       out as we use it before the .bss section is cleared. */
 134    *(.init_pagetable)
 135   }
 136   _end = . ;
 137   PROVIDE (end = .);
 138   /* Stabs debugging sections.  */
 139   .stab 0 : { *(.stab) }
 140   .stabstr 0 : { *(.stabstr) }
 141   .stab.excl 0 : { *(.stab.excl) }
 142   .stab.exclstr 0 : { *(.stab.exclstr) }
 143   .stab.index 0 : { *(.stab.index) }
 144   .stab.indexstr 0 : { *(.stab.indexstr) }
 145   .comment 0 : { *(.comment) }
 146   /* DWARF debug sections.
 147      Symbols in the DWARF debugging sections are relative to the beginning
 148      of the section so we begin them at 0.  */
 149   /* DWARF 1 */
 150   .debug          0 : { *(.debug) }
 151   .line           0 : { *(.line) }
 152   /* GNU DWARF 1 extensions */
 153   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 154   .debug_sfnames  0 : { *(.debug_sfnames) }
 155   /* DWARF 1.1 and DWARF 2 */
 156   .debug_aranges  0 : { *(.debug_aranges) }
 157   .debug_pubnames 0 : { *(.debug_pubnames) }
 158   /* DWARF 2 */
 159   .debug_info     0 : { *(.debug_info) }
 160   .debug_abbrev   0 : { *(.debug_abbrev) }
 161   .debug_line     0 : { *(.debug_line) }
 162   .debug_frame    0 : { *(.debug_frame) }
 163   .debug_str      0 : { *(.debug_str) }
 164   .debug_loc      0 : { *(.debug_loc) }
 165   .debug_macinfo  0 : { *(.debug_macinfo) }
 166   /* SGI/MIPS DWARF 2 extensions */
 167   .debug_weaknames 0 : { *(.debug_weaknames) }
 168   .debug_funcnames 0 : { *(.debug_funcnames) }
 169   .debug_typenames 0 : { *(.debug_typenames) }
 170   .debug_varnames  0 : { *(.debug_varnames) }
 171   /* These must appear regardless of  .  */
 172 }