sys/conf/ldscript.mips.octeon1

   1 /* $FreeBSD$ */
   2
   3 ENTRY(_start)
   4
   5 PHDRS {
   6         text PT_LOAD FLAGS(0x7);
   7 }
   8
   9 SECTIONS {
  10         . = KERNLOADADDR + SIZEOF_HEADERS;
  11
  12         .text : {
  13                 *(.text)
  14                 *(.dynamic)
  15                 etext = .;
  16                 _etext = .;
  17                 . = ALIGN(0x2000);
  18         } : text
  19
  20         . = ALIGN(0x2000);
  21         .rodata : {
  22                 _fdata = .;
  23                 *(.rodata)
  24                 . = ALIGN(32);
  25         }
  26
  27         .note.gnu.build-id : {
  28                 PROVIDE (__build_id_start = .);
  29                 *(.note.gnu.build-id)
  30                 PROVIDE (__build_id_end = .);
  31         }
  32
  33         .data : {
  34                 _rwdata = .;
  35                 *(.data)
  36                 . = ALIGN(32);
  37         }
  38
  39         _gp = (. + 0x8000);
  40
  41         .sdata : {
  42                 _small_start = .;
  43                 *(.sdata)
  44                 . = ALIGN(32);
  45                 edata = .;
  46                 _edata = .;
  47         } : text
  48
  49         .sbss : {
  50                 __bss_start = .;
  51                 _fbss = .;
  52                 *(.sbss) *(.scommon)
  53                 _small_end = .;
  54                 . = ALIGN(32);
  55         }
  56
  57         .bss : {
  58                 *(.bss)
  59                 *(COMMON)
  60                 . = ALIGN(32);
  61                 _end = .;
  62                 end = .;
  63         }
  64
  65 }