sys/conf/ldscript.powerpcspe

   1 /* $FreeBSD$ */
   2
   3 OUTPUT_FORMAT("elf32-powerpc-freebsd", "elf32-powerpc-freebsd",
   4               "elf32-powerpc-freebsd")
   5 OUTPUT_ARCH(powerpc)
   6 ENTRY(__start)
   7 SEARCH_DIR(/usr/lib);
   8 PROVIDE (__stack = 0);
   9 PHDRS
  10 {
  11         kernel PT_LOAD;
  12         dynamic PT_DYNAMIC;
  13 }
  14 SECTIONS
  15 {
  16   /* Read-only sections, merged into text segment: */
  17
  18   . = kernbase + SIZEOF_HEADERS;
  19   PROVIDE (begin = . - SIZEOF_HEADERS);
  20
  21   .text      :
  22   {
  23     *(.glink)
  24     *(.text)
  25     *(.stub)
  26     /* .gnu.warning sections are handled specially by elf32.em.  */
  27     *(.gnu.warning)
  28     *(.gnu.linkonce.t*)
  29   } :kernel =0
  30   _etext = .;
  31   PROVIDE (etext = .);
  32
  33   .interp     : { *(.interp)    }
  34   .hash          : { *(.hash)           }
  35   .dynsym        : { *(.dynsym)         }
  36   .dynstr        : { *(.dynstr)         }
  37   .gnu.version   : { *(.gnu.version)    }
  38   .gnu.version_d   : { *(.gnu.version_d)        }
  39   .gnu.version_r   : { *(.gnu.version_r)        }
  40   .rela.text     :
  41     { *(.rela.text) *(.rela.gnu.linkonce.t*) }
  42   .rela.data     :
  43     { *(.rela.data) *(.rela.gnu.linkonce.d*) }
  44   .rela.rodata   :
  45     { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
  46   .rela.got      : { *(.rela.got)               }
  47   .rela.got1     : { *(.rela.got1)              }
  48   .rela.got2     : { *(.rela.got2)              }
  49   .rela.ctors    : { *(.rela.ctors)     }
  50   .rela.dtors    : { *(.rela.dtors)     }
  51   .rela.init     : { *(.rela.init)      }
  52   .rela.fini     : { *(.rela.fini)      }
  53   .rela.bss      : { *(.rela.bss)               }
  54   .rela.plt      : { *(.rela.plt)               }
  55   .rela.sdata    : { *(.rela.sdata)             }
  56   .rela.sbss     : { *(.rela.sbss)              }
  57   .rela.sdata2   : { *(.rela.sdata2)            }
  58   .rela.sbss2    : { *(.rela.sbss2)             }
  59
  60   .init      : { *(.init)    } =0
  61   .fini      : { *(.fini)    } =0
  62   .rodata    : { *(.rodata) *(.gnu.linkonce.r*) }
  63   .rodata1   : { *(.rodata1) }
  64   .note.gnu.build-id : {
  65     PROVIDE (__build_id_start = .);
  66     *(.note.gnu.build-id)
  67     PROVIDE (__build_id_end = .);
  68   }
  69   .sdata2    : { *(.sdata2)  }
  70   .sbss2     : { *(.sbss2)   }
  71   /* Adjust the address for the data segment to the next page up. */
  72   . = ((. + 0x1000) & ~(0x1000 - 1));
  73   .data    :
  74   {
  75     *(.data)
  76     *(.gnu.linkonce.d*)
  77     CONSTRUCTORS
  78   }
  79   .data1   : { *(.data1) }
  80   .got1           : { *(.got1) }
  81   . = ALIGN(4096);
  82   .got            : { *(.got) }
  83   .got.plt        : { *(.got.plt) }
  84
  85
  86   .dynamic        : { *(.dynamic) } :kernel :dynamic
  87   /* Put .ctors and .dtors next to the .got2 section, so that the pointers
  88      get relocated with -mrelocatable. Also put in the .fixup pointers.
  89      The current compiler no longer needs this, but keep it around for 2.7.2  */
  90                 PROVIDE (_GOT2_START_ = .);
  91   .got2           :  { *(.got2) }
  92                 PROVIDE (__CTOR_LIST__ = .);
  93   .ctors          : { *(.ctors) }
  94                 PROVIDE (__CTOR_END__ = .);
  95                 PROVIDE (__DTOR_LIST__ = .);
  96   .dtors          : { *(.dtors) }
  97                 PROVIDE (__DTOR_END__ = .);
  98                 PROVIDE (_FIXUP_START_ = .);
  99   .fixup          : { *(.fixup) }
 100                 PROVIDE (_FIXUP_END_ = .);
 101                 PROVIDE (_GOT2_END_ = .);
 102   /* We want the small data sections together, so single-instruction offsets
 103      can access them all, and initialized data all before uninitialized, so
 104      we can shorten the on-disk segment size.  */
 105   .sdata     : { *(.sdata) } :kernel
 106   _edata  =  .;
 107   PROVIDE (edata = .);
 108   .sbss      :
 109   {
 110     PROVIDE (__sbss_start = .);
 111     *(.sbss)
 112     *(.scommon)
 113     *(.dynsbss)
 114     PROVIDE (__sbss_end = .);
 115   }
 116   .plt   : { *(.plt) }
 117   .bss       :
 118   {
 119    PROVIDE (__bss_start = .);
 120    *(.dynbss)
 121    *(.bss)
 122    *(COMMON)
 123   }
 124   _end = . ;
 125   PROVIDE (end = .);
 126   /* Stabs debugging sections.  */
 127   .stab 0 : { *(.stab) }
 128   .stabstr 0 : { *(.stabstr) }
 129   /* DWARF debug sections.
 130      Symbols in the DWARF debugging sections are relative to the beginning
 131      of the section so we begin them at 0.  */
 132   /* DWARF 1 */
 133   .debug          0 : { *(.debug) }
 134   .line           0 : { *(.line) }
 135   /* GNU DWARF 1 extensions */
 136   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 137   .debug_sfnames  0 : { *(.debug_sfnames) }
 138   /* DWARF 1.1 and DWARF 2 */
 139   .debug_aranges  0 : { *(.debug_aranges) }
 140   .debug_pubnames 0 : { *(.debug_pubnames) }
 141   /* DWARF 2 */
 142   .debug_info     0 : { *(.debug_info) }
 143   .debug_abbrev   0 : { *(.debug_abbrev) }
 144   .debug_line     0 : { *(.debug_line) }
 145   .debug_frame    0 : { *(.debug_frame) }
 146   .debug_str      0 : { *(.debug_str) }
 147   .debug_loc      0 : { *(.debug_loc) }
 148   .debug_macinfo  0 : { *(.debug_macinfo) }
 149   /* SGI/MIPS DWARF 2 extensions */
 150   .debug_weaknames 0 : { *(.debug_weaknames) }
 151   .debug_funcnames 0 : { *(.debug_funcnames) }
 152   .debug_typenames 0 : { *(.debug_typenames) }
 153   .debug_varnames  0 : { *(.debug_varnames) }
 154   /* These must appear regardless of  .  */
 155 }
 156