sys/i386/i386/swtch.s

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 4. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  *
  32  * $FreeBSD$
  33  */
  34
  35 #include "opt_npx.h"
  36
  37 #include <machine/asmacros.h>
  38
  39 #include "assym.s"
  40
  41 /*****************************************************************************/
  42 /* Scheduling                                                                */
  43 /*****************************************************************************/
  44
  45         .text
  46
  47 /*
  48  * cpu_throw()
  49  *
  50  * This is the second half of cpu_switch(). It is used when the current
  51  * thread is either a dummy or slated to die, and we no longer care
  52  * about its state.  This is only a slight optimization and is probably
  53  * not worth it anymore.  Note that we need to clear the pm_active bits so
  54  * we do need the old proc if it still exists.
  55  * 0(%esp) = ret
  56  * 4(%esp) = oldtd
  57  * 8(%esp) = newtd
  58  */
  59 ENTRY(cpu_throw)
  60         movl    PCPU(CPUID), %esi
  61         movl    4(%esp),%ecx                    /* Old thread */
  62         testl   %ecx,%ecx                       /* no thread? */
  63         jz      1f
  64         /* release bit from old pm_active */
  65         movl    PCPU(CURPMAP), %ebx
  66 #ifdef SMP
  67         lock
  68 #endif
  69         btrl    %esi, PM_ACTIVE(%ebx)           /* clear old */
  70 1:
  71         movl    8(%esp),%ecx                    /* New thread */
  72         movl    TD_PCB(%ecx),%edx
  73         movl    PCB_CR3(%edx),%eax
  74         movl    %eax,%cr3                       /* new address space */
  75         /* set bit in new pm_active */
  76         movl    TD_PROC(%ecx),%eax
  77         movl    P_VMSPACE(%eax), %ebx
  78         addl    $VM_PMAP, %ebx
  79         movl    %ebx, PCPU(CURPMAP)
  80 #ifdef SMP
  81         lock
  82 #endif
  83         btsl    %esi, PM_ACTIVE(%ebx)           /* set new */
  84         jmp     sw1
  85
  86 /*
  87  * cpu_switch(old, new)
  88  *
  89  * Save the current thread state, then select the next thread to run
  90  * and load its state.
  91  * 0(%esp) = ret
  92  * 4(%esp) = oldtd
  93  * 8(%esp) = newtd
  94  */
  95 ENTRY(cpu_switch)
  96
  97         /* Switch to new thread.  First, save context. */
  98         movl    4(%esp),%ecx
  99
 100 #ifdef INVARIANTS
 101         testl   %ecx,%ecx                       /* no thread? */
 102         jz      badsw2                          /* no, panic */
 103 #endif
 104
 105         movl    TD_PCB(%ecx),%edx
 106
 107         movl    (%esp),%eax                     /* Hardware registers */
 108         movl    %eax,PCB_EIP(%edx)
 109         movl    %ebx,PCB_EBX(%edx)
 110         movl    %esp,PCB_ESP(%edx)
 111         movl    %ebp,PCB_EBP(%edx)
 112         movl    %esi,PCB_ESI(%edx)
 113         movl    %edi,PCB_EDI(%edx)
 114         movl    %gs,PCB_GS(%edx)
 115         pushfl                                  /* PSL */
 116         popl    PCB_PSL(%edx)
 117         /* Test if debug registers should be saved. */
 118         testl   $PCB_DBREGS,PCB_FLAGS(%edx)
 119         jz      1f                              /* no, skip over */
 120         movl    %dr7,%eax                       /* yes, do the save */
 121         movl    %eax,PCB_DR7(%edx)
 122         andl    $0x0000fc00, %eax               /* disable all watchpoints */
 123         movl    %eax,%dr7
 124         movl    %dr6,%eax
 125         movl    %eax,PCB_DR6(%edx)
 126         movl    %dr3,%eax
 127         movl    %eax,PCB_DR3(%edx)
 128         movl    %dr2,%eax
 129         movl    %eax,PCB_DR2(%edx)
 130         movl    %dr1,%eax
 131         movl    %eax,PCB_DR1(%edx)
 132         movl    %dr0,%eax
 133         movl    %eax,PCB_DR0(%edx)
 134 1:
 135
 136 #ifdef DEV_NPX
 137         /* have we used fp, and need a save? */
 138         cmpl    %ecx,PCPU(FPCURTHREAD)
 139         jne     1f
 140         addl    $PCB_SAVEFPU,%edx               /* h/w bugs make saving complicated */
 141         pushl   %edx
 142         call    npxsave                         /* do it in a big C function */
 143         popl    %eax
 144 1:
 145 #endif
 146
 147         /* Save is done.  Now fire up new thread. Leave old vmspace. */
 148         movl    8(%esp),%ecx                    /* New thread */
 149 #ifdef INVARIANTS
 150         testl   %ecx,%ecx                       /* no thread? */
 151         jz      badsw3                          /* no, panic */
 152 #endif
 153         movl    TD_PCB(%ecx),%edx
 154         movl    PCPU(CPUID), %esi
 155
 156         /* switch address space */
 157         movl    PCB_CR3(%edx),%eax
 158 #ifdef PAE
 159         cmpl    %eax,IdlePDPT                   /* Kernel address space? */
 160 #else
 161         cmpl    %eax,IdlePTD                    /* Kernel address space? */
 162 #endif
 163         je      sw1
 164         movl    %cr3,%ebx                       /* The same address space? */
 165         cmpl    %ebx,%eax
 166         je      sw1
 167         movl    %eax,%cr3                       /* new address space */
 168
 169         /* Release bit from old pmap->pm_active */
 170         movl    PCPU(CURPMAP), %ebx
 171 #ifdef SMP
 172         lock
 173 #endif
 174         btrl    %esi, PM_ACTIVE(%ebx)           /* clear old */
 175
 176         /* Set bit in new pmap->pm_active */
 177         movl    TD_PROC(%ecx),%eax              /* newproc */
 178         movl    P_VMSPACE(%eax), %ebx
 179         addl    $VM_PMAP, %ebx
 180         movl    %ebx, PCPU(CURPMAP)
 181 #ifdef SMP
 182         lock
 183 #endif
 184         btsl    %esi, PM_ACTIVE(%ebx)           /* set new */
 185
 186 sw1:
 187         /*
 188          * At this point, we've switched address spaces and are ready
 189          * to load up the rest of the next context.
 190          */
 191         cmpl    $0, PCB_EXT(%edx)               /* has pcb extension? */
 192         je      1f                              /* If not, use the default */
 193         movl    $1, PCPU(PRIVATE_TSS)           /* mark use of private tss */
 194         movl    PCB_EXT(%edx), %edi             /* new tss descriptor */
 195         jmp     2f                              /* Load it up */
 196
 197 1:      /*
 198          * Use the common default TSS instead of our own.
 199          * Set our stack pointer into the TSS, it's set to just
 200          * below the PCB.  In C, common_tss.tss_esp0 = &pcb - 16;
 201          */
 202         leal    -16(%edx), %ebx                 /* leave space for vm86 */
 203         movl    %ebx, PCPU(COMMON_TSS) + TSS_ESP0
 204
 205         /*
 206          * Test this CPU's  bit in the bitmap to see if this
 207          * CPU was using a private TSS.
 208          */
 209         cmpl    $0, PCPU(PRIVATE_TSS)           /* Already using the common? */
 210         je      3f                              /* if so, skip reloading */
 211         movl    $0, PCPU(PRIVATE_TSS)
 212         PCPU_ADDR(COMMON_TSSD, %edi)
 213 2:
 214         /* Move correct tss descriptor into GDT slot, then reload tr. */
 215         movl    PCPU(TSS_GDT), %ebx             /* entry in GDT */
 216         movl    0(%edi), %eax
 217         movl    4(%edi), %esi
 218         movl    %eax, 0(%ebx)
 219         movl    %esi, 4(%ebx)
 220         movl    $GPROC0_SEL*8, %esi             /* GSEL(GPROC0_SEL, SEL_KPL) */
 221         ltr     %si
 222 3:
 223
 224         /* Copy the %fs and %gs selectors into this pcpu gdt */
 225         leal    PCB_FSD(%edx), %esi
 226         movl    PCPU(FSGS_GDT), %edi
 227         movl    0(%esi), %eax           /* %fs selector */
 228         movl    4(%esi), %ebx
 229         movl    %eax, 0(%edi)
 230         movl    %ebx, 4(%edi)
 231         movl    8(%esi), %eax           /* %gs selector, comes straight after */
 232         movl    12(%esi), %ebx
 233         movl    %eax, 8(%edi)
 234         movl    %ebx, 12(%edi)
 235
 236         /* Restore context. */
 237         movl    PCB_EBX(%edx),%ebx
 238         movl    PCB_ESP(%edx),%esp
 239         movl    PCB_EBP(%edx),%ebp
 240         movl    PCB_ESI(%edx),%esi
 241         movl    PCB_EDI(%edx),%edi
 242         movl    PCB_EIP(%edx),%eax
 243         movl    %eax,(%esp)
 244         pushl   PCB_PSL(%edx)
 245         popfl
 246
 247         movl    %edx, PCPU(CURPCB)
 248         movl    TD_TID(%ecx),%eax
 249         movl    %ecx, PCPU(CURTHREAD)           /* into next thread */
 250         movl    %eax, PCPU(CURTID)
 251
 252         /*
 253          * Determine the LDT to use and load it if is the default one and
 254          * that is not the current one.
 255          */
 256         movl    TD_PROC(%ecx),%eax
 257         cmpl    $0,P_MD+MD_LDT(%eax)
 258         jnz     1f
 259         movl    _default_ldt,%eax
 260         cmpl    PCPU(CURRENTLDT),%eax
 261         je      2f
 262         lldt    _default_ldt
 263         movl    %eax,PCPU(CURRENTLDT)
 264         jmp     2f
 265 1:
 266         /* Load the LDT when it is not the default one. */
 267         pushl   %edx                            /* Preserve pointer to pcb. */
 268         addl    $P_MD,%eax                      /* Pointer to mdproc is arg. */
 269         pushl   %eax
 270         call    set_user_ldt
 271         addl    $4,%esp
 272         popl    %edx
 273 2:
 274
 275         /* This must be done after loading the user LDT. */
 276         .globl  cpu_switch_load_gs
 277 cpu_switch_load_gs:
 278         movl    PCB_GS(%edx),%gs
 279
 280         /* Test if debug registers should be restored. */
 281         testl   $PCB_DBREGS,PCB_FLAGS(%edx)
 282         jz      1f
 283
 284         /*
 285          * Restore debug registers.  The special code for dr7 is to
 286          * preserve the current values of its reserved bits.
 287          */
 288         movl    PCB_DR6(%edx),%eax
 289         movl    %eax,%dr6
 290         movl    PCB_DR3(%edx),%eax
 291         movl    %eax,%dr3
 292         movl    PCB_DR2(%edx),%eax
 293         movl    %eax,%dr2
 294         movl    PCB_DR1(%edx),%eax
 295         movl    %eax,%dr1
 296         movl    PCB_DR0(%edx),%eax
 297         movl    %eax,%dr0
 298         movl    %dr7,%eax
 299         andl    $0x0000fc00,%eax
 300         movl    PCB_DR7(%edx),%ecx
 301         andl    $~0x0000fc00,%ecx
 302         orl     %ecx,%eax
 303         movl    %eax,%dr7
 304 1:
 305         ret
 306
 307 #ifdef INVARIANTS
 308 badsw1:
 309         pushal
 310         pushl   $sw0_1
 311         call    panic
 312 sw0_1:  .asciz  "cpu_throw: no newthread supplied"
 313
 314 badsw2:
 315         pushal
 316         pushl   $sw0_2
 317         call    panic
 318 sw0_2:  .asciz  "cpu_switch: no curthread supplied"
 319
 320 badsw3:
 321         pushal
 322         pushl   $sw0_3
 323         call    panic
 324 sw0_3:  .asciz  "cpu_switch: no newthread supplied"
 325 #endif
 326
 327 /*
 328  * savectx(pcb)
 329  * Update pcb, saving current processor state.
 330  */
 331 ENTRY(savectx)
 332         /* Fetch PCB. */
 333         movl    4(%esp),%ecx
 334
 335         /* Save caller's return address.  Child won't execute this routine. */
 336         movl    (%esp),%eax
 337         movl    %eax,PCB_EIP(%ecx)
 338
 339         movl    %cr3,%eax
 340         movl    %eax,PCB_CR3(%ecx)
 341
 342         movl    %ebx,PCB_EBX(%ecx)
 343         movl    %esp,PCB_ESP(%ecx)
 344         movl    %ebp,PCB_EBP(%ecx)
 345         movl    %esi,PCB_ESI(%ecx)
 346         movl    %edi,PCB_EDI(%ecx)
 347         movl    %gs,PCB_GS(%ecx)
 348         pushfl
 349         popl    PCB_PSL(%ecx)
 350
 351 #ifdef DEV_NPX
 352         /*
 353          * If fpcurthread == NULL, then the npx h/w state is irrelevant and the
 354          * state had better already be in the pcb.  This is true for forks
 355          * but not for dumps (the old book-keeping with FP flags in the pcb
 356          * always lost for dumps because the dump pcb has 0 flags).
 357          *
 358          * If fpcurthread != NULL, then we have to save the npx h/w state to
 359          * fpcurthread's pcb and copy it to the requested pcb, or save to the
 360          * requested pcb and reload.  Copying is easier because we would
 361          * have to handle h/w bugs for reloading.  We used to lose the
 362          * parent's npx state for forks by forgetting to reload.
 363          */
 364         pushfl
 365         cli
 366         movl    PCPU(FPCURTHREAD),%eax
 367         testl   %eax,%eax
 368         je      1f
 369
 370         pushl   %ecx
 371         movl    TD_PCB(%eax),%eax
 372         leal    PCB_SAVEFPU(%eax),%eax
 373         pushl   %eax
 374         pushl   %eax
 375         call    npxsave
 376         addl    $4,%esp
 377         popl    %eax
 378         popl    %ecx
 379
 380         pushl   $PCB_SAVEFPU_SIZE
 381         leal    PCB_SAVEFPU(%ecx),%ecx
 382         pushl   %ecx
 383         pushl   %eax
 384         call    bcopy
 385         addl    $12,%esp
 386 1:
 387         popfl
 388 #endif  /* DEV_NPX */
 389
 390         ret