sys/i386/i386/swtch.s

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 4. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  *
  32  * $FreeBSD$
  33  */
  34
  35 #include "opt_npx.h"
  36
  37 #include <machine/asmacros.h>
  38
  39 #include "assym.s"
  40
  41 /*****************************************************************************/
  42 /* Scheduling                                                                */
  43 /*****************************************************************************/
  44
  45         .text
  46
  47 /*
  48  * cpu_throw()
  49  *
  50  * This is the second half of cpu_switch(). It is used when the current
  51  * thread is either a dummy or slated to die, and we no longer care
  52  * about its state.  This is only a slight optimization and is probably
  53  * not worth it anymore.  Note that we need to clear the pm_active bits so
  54  * we do need the old proc if it still exists.
  55  * 0(%esp) = ret
  56  * 4(%esp) = oldtd
  57  * 8(%esp) = newtd
  58  */
  59 ENTRY(cpu_throw)
  60         movl    PCPU(CPUID), %esi
  61         movl    4(%esp),%ecx                    /* Old thread */
  62         testl   %ecx,%ecx                       /* no thread? */
  63         jz      1f
  64         /* release bit from old pm_active */
  65         movl    PCPU(CURPMAP), %ebx
  66 #ifdef SMP
  67         lock
  68 #endif
  69         btrl    %esi, PM_ACTIVE(%ebx)           /* clear old */
  70 1:
  71         movl    8(%esp),%ecx                    /* New thread */
  72         movl    TD_PCB(%ecx),%edx
  73         movl    PCB_CR3(%edx),%eax
  74         movl    %eax,%cr3                       /* new address space */
  75         /* set bit in new pm_active */
  76         movl    TD_PROC(%ecx),%eax
  77         movl    P_VMSPACE(%eax), %ebx
  78         addl    $VM_PMAP, %ebx
  79         movl    %ebx, PCPU(CURPMAP)
  80 #ifdef SMP
  81         lock
  82 #endif
  83         btsl    %esi, PM_ACTIVE(%ebx)           /* set new */
  84         jmp     sw1
  85
  86 /*
  87  * cpu_switch(old, new)
  88  *
  89  * Save the current thread state, then select the next thread to run
  90  * and load its state.
  91  * 0(%esp) = ret
  92  * 4(%esp) = oldtd
  93  * 8(%esp) = newtd
  94  */
  95 ENTRY(cpu_switch)
  96
  97         /* Switch to new thread.  First, save context. */
  98         movl    4(%esp),%ecx
  99
 100 #ifdef INVARIANTS
 101         testl   %ecx,%ecx                       /* no thread? */
 102         jz      badsw2                          /* no, panic */
 103 #endif
 104
 105         movl    TD_PCB(%ecx),%edx
 106
 107         movl    (%esp),%eax                     /* Hardware registers */
 108         movl    %eax,PCB_EIP(%edx)
 109         movl    %ebx,PCB_EBX(%edx)
 110         movl    %esp,PCB_ESP(%edx)
 111         movl    %ebp,PCB_EBP(%edx)
 112         movl    %esi,PCB_ESI(%edx)
 113         movl    %edi,PCB_EDI(%edx)
 114         movl    %gs,PCB_GS(%edx)
 115         pushfl                                  /* PSL */
 116         popl    PCB_PSL(%edx)
 117         /* Test if debug registers should be saved. */
 118         testl   $PCB_DBREGS,PCB_FLAGS(%edx)
 119         jz      1f                              /* no, skip over */
 120         movl    %dr7,%eax                       /* yes, do the save */
 121         movl    %eax,PCB_DR7(%edx)
 122         andl    $0x0000fc00, %eax               /* disable all watchpoints */
 123         movl    %eax,%dr7
 124         movl    %dr6,%eax
 125         movl    %eax,PCB_DR6(%edx)
 126         movl    %dr3,%eax
 127         movl    %eax,PCB_DR3(%edx)
 128         movl    %dr2,%eax
 129         movl    %eax,PCB_DR2(%edx)
 130         movl    %dr1,%eax
 131         movl    %eax,PCB_DR1(%edx)
 132         movl    %dr0,%eax
 133         movl    %eax,PCB_DR0(%edx)
 134 1:
 135
 136 #ifdef DEV_NPX
 137         /* have we used fp, and need a save? */
 138         cmpl    %ecx,PCPU(FPCURTHREAD)
 139         jne     1f
 140         addl    $PCB_SAVEFPU,%edx               /* h/w bugs make saving complicated */
 141         pushl   %edx
 142         call    npxsave                         /* do it in a big C function */
 143         popl    %eax
 144 1:
 145 #endif
 146
 147         /* Save is done.  Now fire up new thread. Leave old vmspace. */
 148         movl    %ecx,%edi
 149         movl    8(%esp),%ecx                    /* New thread */
 150 #ifdef INVARIANTS
 151         testl   %ecx,%ecx                       /* no thread? */
 152         jz      badsw3                          /* no, panic */
 153 #endif
 154         movl    TD_PCB(%ecx),%edx
 155         movl    PCPU(CPUID), %esi
 156
 157         /* switch address space */
 158         movl    PCB_CR3(%edx),%eax
 159 #ifdef PAE
 160         cmpl    %eax,IdlePDPT                   /* Kernel address space? */
 161 #else
 162         cmpl    %eax,IdlePTD                    /* Kernel address space? */
 163 #endif
 164         je      sw1
 165         movl    %cr3,%ebx                       /* The same address space? */
 166         cmpl    %ebx,%eax
 167         je      sw1
 168         movl    %eax,%cr3                       /* new address space */
 169
 170         /* Release bit from old pmap->pm_active */
 171         movl    PCPU(CURPMAP), %ebx
 172 #ifdef SMP
 173         lock
 174 #endif
 175         btrl    %esi, PM_ACTIVE(%ebx)           /* clear old */
 176
 177         /* Set bit in new pmap->pm_active */
 178         movl    TD_PROC(%ecx),%eax              /* newproc */
 179         movl    P_VMSPACE(%eax), %ebx
 180         addl    $VM_PMAP, %ebx
 181         movl    %ebx, PCPU(CURPMAP)
 182 #ifdef SMP
 183         lock
 184 #endif
 185         btsl    %esi, PM_ACTIVE(%ebx)           /* set new */
 186
 187 sw1:
 188         /*
 189          * At this point, we've switched address spaces and are ready
 190          * to load up the rest of the next context.
 191          */
 192         cmpl    $0, PCB_EXT(%edx)               /* has pcb extension? */
 193         je      1f                              /* If not, use the default */
 194         movl    $1, PCPU(PRIVATE_TSS)           /* mark use of private tss */
 195         movl    PCB_EXT(%edx), %edi             /* new tss descriptor */
 196         jmp     2f                              /* Load it up */
 197
 198 1:      /*
 199          * Use the common default TSS instead of our own.
 200          * Set our stack pointer into the TSS, it's set to just
 201          * below the PCB.  In C, common_tss.tss_esp0 = &pcb - 16;
 202          */
 203         leal    -16(%edx), %ebx                 /* leave space for vm86 */
 204         movl    %ebx, PCPU(COMMON_TSS) + TSS_ESP0
 205
 206         /*
 207          * Test this CPU's  bit in the bitmap to see if this
 208          * CPU was using a private TSS.
 209          */
 210         cmpl    $0, PCPU(PRIVATE_TSS)           /* Already using the common? */
 211         je      3f                              /* if so, skip reloading */
 212         movl    $0, PCPU(PRIVATE_TSS)
 213         PCPU_ADDR(COMMON_TSSD, %edi)
 214 2:
 215         /* Move correct tss descriptor into GDT slot, then reload tr. */
 216         movl    PCPU(TSS_GDT), %ebx             /* entry in GDT */
 217         movl    0(%edi), %eax
 218         movl    4(%edi), %esi
 219         movl    %eax, 0(%ebx)
 220         movl    %esi, 4(%ebx)
 221         movl    $GPROC0_SEL*8, %esi             /* GSEL(GPROC0_SEL, SEL_KPL) */
 222         ltr     %si
 223 3:
 224
 225         /* Copy the %fs and %gs selectors into this pcpu gdt */
 226         leal    PCB_FSD(%edx), %esi
 227         movl    PCPU(FSGS_GDT), %edi
 228         movl    0(%esi), %eax           /* %fs selector */
 229         movl    4(%esi), %ebx
 230         movl    %eax, 0(%edi)
 231         movl    %ebx, 4(%edi)
 232         movl    8(%esi), %eax           /* %gs selector, comes straight after */
 233         movl    12(%esi), %ebx
 234         movl    %eax, 8(%edi)
 235         movl    %ebx, 12(%edi)
 236
 237         /* Restore context. */
 238         movl    PCB_EBX(%edx),%ebx
 239         movl    PCB_ESP(%edx),%esp
 240         movl    PCB_EBP(%edx),%ebp
 241         movl    PCB_ESI(%edx),%esi
 242         movl    PCB_EDI(%edx),%edi
 243         movl    PCB_EIP(%edx),%eax
 244         movl    %eax,(%esp)
 245         pushl   PCB_PSL(%edx)
 246         popfl
 247
 248         movl    %edx, PCPU(CURPCB)
 249         movl    %ecx, PCPU(CURTHREAD)           /* into next thread */
 250
 251         /*
 252          * Determine the LDT to use and load it if is the default one and
 253          * that is not the current one.
 254          */
 255         movl    TD_PROC(%ecx),%eax
 256         cmpl    $0,P_MD+MD_LDT(%eax)
 257         jnz     1f
 258         movl    _default_ldt,%eax
 259         cmpl    PCPU(CURRENTLDT),%eax
 260         je      2f
 261         lldt    _default_ldt
 262         movl    %eax,PCPU(CURRENTLDT)
 263         jmp     2f
 264 1:
 265         /* Load the LDT when it is not the default one. */
 266         pushl   %edx                            /* Preserve pointer to pcb. */
 267         addl    $P_MD,%eax                      /* Pointer to mdproc is arg. */
 268         pushl   %eax
 269         call    set_user_ldt
 270         addl    $4,%esp
 271         popl    %edx
 272 2:
 273
 274         /* This must be done after loading the user LDT. */
 275         .globl  cpu_switch_load_gs
 276 cpu_switch_load_gs:
 277         movl    PCB_GS(%edx),%gs
 278
 279         /* Test if debug registers should be restored. */
 280         testl   $PCB_DBREGS,PCB_FLAGS(%edx)
 281         jz      1f
 282
 283         /*
 284          * Restore debug registers.  The special code for dr7 is to
 285          * preserve the current values of its reserved bits.
 286          */
 287         movl    PCB_DR6(%edx),%eax
 288         movl    %eax,%dr6
 289         movl    PCB_DR3(%edx),%eax
 290         movl    %eax,%dr3
 291         movl    PCB_DR2(%edx),%eax
 292         movl    %eax,%dr2
 293         movl    PCB_DR1(%edx),%eax
 294         movl    %eax,%dr1
 295         movl    PCB_DR0(%edx),%eax
 296         movl    %eax,%dr0
 297         movl    %dr7,%eax
 298         andl    $0x0000fc00,%eax
 299         movl    PCB_DR7(%edx),%ecx
 300         andl    $~0x0000fc00,%ecx
 301         orl     %ecx,%eax
 302         movl    %eax,%dr7
 303 1:
 304         ret
 305
 306 #ifdef INVARIANTS
 307 badsw1:
 308         pushal
 309         pushl   $sw0_1
 310         call    panic
 311 sw0_1:  .asciz  "cpu_throw: no newthread supplied"
 312
 313 badsw2:
 314         pushal
 315         pushl   $sw0_2
 316         call    panic
 317 sw0_2:  .asciz  "cpu_switch: no curthread supplied"
 318
 319 badsw3:
 320         pushal
 321         pushl   $sw0_3
 322         call    panic
 323 sw0_3:  .asciz  "cpu_switch: no newthread supplied"
 324 #endif
 325
 326 /*
 327  * savectx(pcb)
 328  * Update pcb, saving current processor state.
 329  */
 330 ENTRY(savectx)
 331         /* Fetch PCB. */
 332         movl    4(%esp),%ecx
 333
 334         /* Save caller's return address.  Child won't execute this routine. */
 335         movl    (%esp),%eax
 336         movl    %eax,PCB_EIP(%ecx)
 337
 338         movl    %cr3,%eax
 339         movl    %eax,PCB_CR3(%ecx)
 340
 341         movl    %ebx,PCB_EBX(%ecx)
 342         movl    %esp,PCB_ESP(%ecx)
 343         movl    %ebp,PCB_EBP(%ecx)
 344         movl    %esi,PCB_ESI(%ecx)
 345         movl    %edi,PCB_EDI(%ecx)
 346         movl    %gs,PCB_GS(%ecx)
 347         pushfl
 348         popl    PCB_PSL(%ecx)
 349
 350 #ifdef DEV_NPX
 351         /*
 352          * If fpcurthread == NULL, then the npx h/w state is irrelevant and the
 353          * state had better already be in the pcb.  This is true for forks
 354          * but not for dumps (the old book-keeping with FP flags in the pcb
 355          * always lost for dumps because the dump pcb has 0 flags).
 356          *
 357          * If fpcurthread != NULL, then we have to save the npx h/w state to
 358          * fpcurthread's pcb and copy it to the requested pcb, or save to the
 359          * requested pcb and reload.  Copying is easier because we would
 360          * have to handle h/w bugs for reloading.  We used to lose the
 361          * parent's npx state for forks by forgetting to reload.
 362          */
 363         pushfl
 364         cli
 365         movl    PCPU(FPCURTHREAD),%eax
 366         testl   %eax,%eax
 367         je      1f
 368
 369         pushl   %ecx
 370         movl    TD_PCB(%eax),%eax
 371         leal    PCB_SAVEFPU(%eax),%eax
 372         pushl   %eax
 373         pushl   %eax
 374         call    npxsave
 375         addl    $4,%esp
 376         popl    %eax
 377         popl    %ecx
 378
 379         pushl   $PCB_SAVEFPU_SIZE
 380         leal    PCB_SAVEFPU(%ecx),%ecx
 381         pushl   %ecx
 382         pushl   %eax
 383         call    bcopy
 384         addl    $12,%esp
 385 1:
 386         popfl
 387 #endif  /* DEV_NPX */
 388
 389         ret