sys/i386/i386/swtch.s

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  *
  32  * $FreeBSD$
  33  */
  34
  35 #include "opt_sched.h"
  36
  37 #include <machine/asmacros.h>
  38
  39 #include "assym.s"
  40
  41 #if defined(SMP) && defined(SCHED_ULE)
  42 #define SETOP           xchgl
  43 #define BLOCK_SPIN(reg)                                                 \
  44                 movl            $blocked_lock,%eax ;                    \
  45         100: ;                                                          \
  46                 lock ;                                                  \
  47                 cmpxchgl        %eax,TD_LOCK(reg) ;                     \
  48                 jne             101f ;                                  \
  49                 pause ;                                                 \
  50                 jmp             100b ;                                  \
  51         101:
  52 #else
  53 #define SETOP           movl
  54 #define BLOCK_SPIN(reg)
  55 #endif
  56
  57 /*****************************************************************************/
  58 /* Scheduling                                                                */
  59 /*****************************************************************************/
  60
  61         .text
  62
  63 /*
  64  * cpu_throw()
  65  *
  66  * This is the second half of cpu_switch(). It is used when the current
  67  * thread is either a dummy or slated to die, and we no longer care
  68  * about its state.  This is only a slight optimization and is probably
  69  * not worth it anymore.  Note that we need to clear the pm_active bits so
  70  * we do need the old proc if it still exists.
  71  * 0(%esp) = ret
  72  * 4(%esp) = oldtd
  73  * 8(%esp) = newtd
  74  */
  75 ENTRY(cpu_throw)
  76         movl    PCPU(CPUID), %esi
  77         movl    4(%esp),%ecx                    /* Old thread */
  78         testl   %ecx,%ecx                       /* no thread? */
  79         jz      1f
  80         /* release bit from old pm_active */
  81         movl    PCPU(CURPMAP), %ebx
  82 #ifdef SMP
  83         lock
  84 #endif
  85         btrl    %esi, PM_ACTIVE(%ebx)           /* clear old */
  86 1:
  87         movl    8(%esp),%ecx                    /* New thread */
  88         movl    TD_PCB(%ecx),%edx
  89         movl    PCB_CR3(%edx),%eax
  90         movl    %eax,%cr3
  91         /* set bit in new pm_active */
  92         movl    TD_PROC(%ecx),%eax
  93         movl    P_VMSPACE(%eax), %ebx
  94         addl    $VM_PMAP, %ebx
  95         movl    %ebx, PCPU(CURPMAP)
  96 #ifdef SMP
  97         lock
  98 #endif
  99         btsl    %esi, PM_ACTIVE(%ebx)           /* set new */
 100         jmp     sw1
 101 END(cpu_throw)
 102
 103 /*
 104  * cpu_switch(old, new)
 105  *
 106  * Save the current thread state, then select the next thread to run
 107  * and load its state.
 108  * 0(%esp) = ret
 109  * 4(%esp) = oldtd
 110  * 8(%esp) = newtd
 111  * 12(%esp) = newlock
 112  */
 113 ENTRY(cpu_switch)
 114
 115         /* Switch to new thread.  First, save context. */
 116         movl    4(%esp),%ecx
 117
 118 #ifdef INVARIANTS
 119         testl   %ecx,%ecx                       /* no thread? */
 120         jz      badsw2                          /* no, panic */
 121 #endif
 122
 123         movl    TD_PCB(%ecx),%edx
 124
 125         movl    (%esp),%eax                     /* Hardware registers */
 126         movl    %eax,PCB_EIP(%edx)
 127         movl    %ebx,PCB_EBX(%edx)
 128         movl    %esp,PCB_ESP(%edx)
 129         movl    %ebp,PCB_EBP(%edx)
 130         movl    %esi,PCB_ESI(%edx)
 131         movl    %edi,PCB_EDI(%edx)
 132         mov     %gs,PCB_GS(%edx)
 133         /* Test if debug registers should be saved. */
 134         testl   $PCB_DBREGS,PCB_FLAGS(%edx)
 135         jz      1f                              /* no, skip over */
 136         movl    %dr7,%eax                       /* yes, do the save */
 137         movl    %eax,PCB_DR7(%edx)
 138         andl    $0x0000fc00, %eax               /* disable all watchpoints */
 139         movl    %eax,%dr7
 140         movl    %dr6,%eax
 141         movl    %eax,PCB_DR6(%edx)
 142         movl    %dr3,%eax
 143         movl    %eax,PCB_DR3(%edx)
 144         movl    %dr2,%eax
 145         movl    %eax,PCB_DR2(%edx)
 146         movl    %dr1,%eax
 147         movl    %eax,PCB_DR1(%edx)
 148         movl    %dr0,%eax
 149         movl    %eax,PCB_DR0(%edx)
 150 1:
 151
 152         /* have we used fp, and need a save? */
 153         cmpl    %ecx,PCPU(FPCURTHREAD)
 154         jne     1f
 155         pushl   PCB_SAVEFPU(%edx)               /* h/w bugs make saving complicated */
 156         call    npxsave                         /* do it in a big C function */
 157         popl    %eax
 158 1:
 159
 160         /* Save is done.  Now fire up new thread. Leave old vmspace. */
 161         movl    4(%esp),%edi
 162         movl    8(%esp),%ecx                    /* New thread */
 163         movl    12(%esp),%esi                   /* New lock */
 164 #ifdef INVARIANTS
 165         testl   %ecx,%ecx                       /* no thread? */
 166         jz      badsw3                          /* no, panic */
 167 #endif
 168         movl    TD_PCB(%ecx),%edx
 169
 170         /* switch address space */
 171         movl    PCB_CR3(%edx),%eax
 172         movl    %cr3,%ebx                       /* The same address space? */
 173         cmpl    %ebx,%eax
 174         je      sw0
 175         movl    %eax,%cr3                       /* new address space */
 176         movl    %esi,%eax
 177         movl    PCPU(CPUID),%esi
 178         SETOP   %eax,TD_LOCK(%edi)              /* Switchout td_lock */
 179
 180         /* Release bit from old pmap->pm_active */
 181         movl    PCPU(CURPMAP), %ebx
 182 #ifdef SMP
 183         lock
 184 #endif
 185         btrl    %esi, PM_ACTIVE(%ebx)           /* clear old */
 186
 187         /* Set bit in new pmap->pm_active */
 188         movl    TD_PROC(%ecx),%eax              /* newproc */
 189         movl    P_VMSPACE(%eax), %ebx
 190         addl    $VM_PMAP, %ebx
 191         movl    %ebx, PCPU(CURPMAP)
 192 #ifdef SMP
 193         lock
 194 #endif
 195         btsl    %esi, PM_ACTIVE(%ebx)           /* set new */
 196         jmp     sw1
 197
 198 sw0:
 199         SETOP   %esi,TD_LOCK(%edi)              /* Switchout td_lock */
 200 sw1:
 201         BLOCK_SPIN(%ecx)
 202         /*
 203          * At this point, we've switched address spaces and are ready
 204          * to load up the rest of the next context.
 205          */
 206         cmpl    $0, PCB_EXT(%edx)               /* has pcb extension? */
 207         je      1f                              /* If not, use the default */
 208         movl    $1, PCPU(PRIVATE_TSS)           /* mark use of private tss */
 209         movl    PCB_EXT(%edx), %edi             /* new tss descriptor */
 210         jmp     2f                              /* Load it up */
 211
 212 1:      /*
 213          * Use the common default TSS instead of our own.
 214          * Set our stack pointer into the TSS, it's set to just
 215          * below the PCB.  In C, common_tss.tss_esp0 = &pcb - 16;
 216          */
 217         leal    -16(%edx), %ebx                 /* leave space for vm86 */
 218         movl    %ebx, PCPU(COMMON_TSS) + TSS_ESP0
 219
 220         /*
 221          * Test this CPU's  bit in the bitmap to see if this
 222          * CPU was using a private TSS.
 223          */
 224         cmpl    $0, PCPU(PRIVATE_TSS)           /* Already using the common? */
 225         je      3f                              /* if so, skip reloading */
 226         movl    $0, PCPU(PRIVATE_TSS)
 227         PCPU_ADDR(COMMON_TSSD, %edi)
 228 2:
 229         /* Move correct tss descriptor into GDT slot, then reload tr. */
 230         movl    PCPU(TSS_GDT), %ebx             /* entry in GDT */
 231         movl    0(%edi), %eax
 232         movl    4(%edi), %esi
 233         movl    %eax, 0(%ebx)
 234         movl    %esi, 4(%ebx)
 235         movl    $GPROC0_SEL*8, %esi             /* GSEL(GPROC0_SEL, SEL_KPL) */
 236         ltr     %si
 237 3:
 238
 239         /* Copy the %fs and %gs selectors into this pcpu gdt */
 240         leal    PCB_FSD(%edx), %esi
 241         movl    PCPU(FSGS_GDT), %edi
 242         movl    0(%esi), %eax           /* %fs selector */
 243         movl    4(%esi), %ebx
 244         movl    %eax, 0(%edi)
 245         movl    %ebx, 4(%edi)
 246         movl    8(%esi), %eax           /* %gs selector, comes straight after */
 247         movl    12(%esi), %ebx
 248         movl    %eax, 8(%edi)
 249         movl    %ebx, 12(%edi)
 250
 251         /* Restore context. */
 252         movl    PCB_EBX(%edx),%ebx
 253         movl    PCB_ESP(%edx),%esp
 254         movl    PCB_EBP(%edx),%ebp
 255         movl    PCB_ESI(%edx),%esi
 256         movl    PCB_EDI(%edx),%edi
 257         movl    PCB_EIP(%edx),%eax
 258         movl    %eax,(%esp)
 259
 260         movl    %edx, PCPU(CURPCB)
 261         movl    TD_TID(%ecx),%eax
 262         movl    %ecx, PCPU(CURTHREAD)           /* into next thread */
 263
 264         /*
 265          * Determine the LDT to use and load it if is the default one and
 266          * that is not the current one.
 267          */
 268         movl    TD_PROC(%ecx),%eax
 269         cmpl    $0,P_MD+MD_LDT(%eax)
 270         jnz     1f
 271         movl    _default_ldt,%eax
 272         cmpl    PCPU(CURRENTLDT),%eax
 273         je      2f
 274         lldt    _default_ldt
 275         movl    %eax,PCPU(CURRENTLDT)
 276         jmp     2f
 277 1:
 278         /* Load the LDT when it is not the default one. */
 279         pushl   %edx                            /* Preserve pointer to pcb. */
 280         addl    $P_MD,%eax                      /* Pointer to mdproc is arg. */
 281         pushl   %eax
 282         call    set_user_ldt
 283         addl    $4,%esp
 284         popl    %edx
 285 2:
 286
 287         /* This must be done after loading the user LDT. */
 288         .globl  cpu_switch_load_gs
 289 cpu_switch_load_gs:
 290         mov     PCB_GS(%edx),%gs
 291
 292         /* Test if debug registers should be restored. */
 293         testl   $PCB_DBREGS,PCB_FLAGS(%edx)
 294         jz      1f
 295
 296         /*
 297          * Restore debug registers.  The special code for dr7 is to
 298          * preserve the current values of its reserved bits.
 299          */
 300         movl    PCB_DR6(%edx),%eax
 301         movl    %eax,%dr6
 302         movl    PCB_DR3(%edx),%eax
 303         movl    %eax,%dr3
 304         movl    PCB_DR2(%edx),%eax
 305         movl    %eax,%dr2
 306         movl    PCB_DR1(%edx),%eax
 307         movl    %eax,%dr1
 308         movl    PCB_DR0(%edx),%eax
 309         movl    %eax,%dr0
 310         movl    %dr7,%eax
 311         andl    $0x0000fc00,%eax
 312         movl    PCB_DR7(%edx),%ecx
 313         andl    $~0x0000fc00,%ecx
 314         orl     %ecx,%eax
 315         movl    %eax,%dr7
 316 1:
 317         ret
 318
 319 #ifdef INVARIANTS
 320 badsw1:
 321         pushal
 322         pushl   $sw0_1
 323         call    panic
 324 sw0_1:  .asciz  "cpu_throw: no newthread supplied"
 325
 326 badsw2:
 327         pushal
 328         pushl   $sw0_2
 329         call    panic
 330 sw0_2:  .asciz  "cpu_switch: no curthread supplied"
 331
 332 badsw3:
 333         pushal
 334         pushl   $sw0_3
 335         call    panic
 336 sw0_3:  .asciz  "cpu_switch: no newthread supplied"
 337 #endif
 338 END(cpu_switch)
 339
 340 /*
 341  * savectx(pcb)
 342  * Update pcb, saving current processor state.
 343  */
 344 ENTRY(savectx)
 345         /* Fetch PCB. */
 346         movl    4(%esp),%ecx
 347
 348         /* Save caller's return address.  Child won't execute this routine. */
 349         movl    (%esp),%eax
 350         movl    %eax,PCB_EIP(%ecx)
 351
 352         movl    %cr3,%eax
 353         movl    %eax,PCB_CR3(%ecx)
 354
 355         movl    %ebx,PCB_EBX(%ecx)
 356         movl    %esp,PCB_ESP(%ecx)
 357         movl    %ebp,PCB_EBP(%ecx)
 358         movl    %esi,PCB_ESI(%ecx)
 359         movl    %edi,PCB_EDI(%ecx)
 360         mov     %gs,PCB_GS(%ecx)
 361
 362         movl    %cr0,%eax
 363         movl    %eax,PCB_CR0(%ecx)
 364         movl    %cr2,%eax
 365         movl    %eax,PCB_CR2(%ecx)
 366         movl    %cr4,%eax
 367         movl    %eax,PCB_CR4(%ecx)
 368
 369         movl    %dr0,%eax
 370         movl    %eax,PCB_DR0(%ecx)
 371         movl    %dr1,%eax
 372         movl    %eax,PCB_DR1(%ecx)
 373         movl    %dr2,%eax
 374         movl    %eax,PCB_DR2(%ecx)
 375         movl    %dr3,%eax
 376         movl    %eax,PCB_DR3(%ecx)
 377         movl    %dr6,%eax
 378         movl    %eax,PCB_DR6(%ecx)
 379         movl    %dr7,%eax
 380         movl    %eax,PCB_DR7(%ecx)
 381
 382         mov     %ds,PCB_DS(%ecx)
 383         mov     %es,PCB_ES(%ecx)
 384         mov     %fs,PCB_FS(%ecx)
 385         mov     %ss,PCB_SS(%ecx)
 386
 387         sgdt    PCB_GDT(%ecx)
 388         sidt    PCB_IDT(%ecx)
 389         sldt    PCB_LDT(%ecx)
 390         str     PCB_TR(%ecx)
 391
 392         movl    $1,%eax
 393         ret
 394 END(savectx)
 395
 396 /*
 397  * resumectx(pcb) __fastcall
 398  * Resuming processor state from pcb.
 399  */
 400 ENTRY(resumectx)
 401         /* Restore GDT. */
 402         lgdt    PCB_GDT(%ecx)
 403
 404         /* Restore segment registers */
 405         movzwl  PCB_DS(%ecx),%eax
 406         mov     %ax,%ds
 407         movzwl  PCB_ES(%ecx),%eax
 408         mov     %ax,%es
 409         movzwl  PCB_FS(%ecx),%eax
 410         mov     %ax,%fs
 411         movzwl  PCB_GS(%ecx),%eax
 412         movw    %ax,%gs
 413         movzwl  PCB_SS(%ecx),%eax
 414         mov     %ax,%ss
 415
 416         /* Restore CR2, CR4, CR3 and CR0 */
 417         movl    PCB_CR2(%ecx),%eax
 418         movl    %eax,%cr2
 419         movl    PCB_CR4(%ecx),%eax
 420         movl    %eax,%cr4
 421         movl    PCB_CR3(%ecx),%eax
 422         movl    %eax,%cr3
 423         movl    PCB_CR0(%ecx),%eax
 424         movl    %eax,%cr0
 425         jmp     1f
 426 1:
 427
 428         /* Restore descriptor tables */
 429         lidt    PCB_IDT(%ecx)
 430         lldt    PCB_LDT(%ecx)
 431
 432 #define SDT_SYS386TSS   9
 433 #define SDT_SYS386BSY   11
 434         /* Clear "task busy" bit and reload TR */
 435         movl    PCPU(TSS_GDT),%eax
 436         andb    $(~SDT_SYS386BSY | SDT_SYS386TSS),5(%eax)
 437         movzwl  PCB_TR(%ecx),%eax
 438         ltr     %ax
 439 #undef SDT_SYS386TSS
 440 #undef SDT_SYS386BSY
 441
 442         /* Restore debug registers */
 443         movl    PCB_DR0(%ecx),%eax
 444         movl    %eax,%dr0
 445         movl    PCB_DR1(%ecx),%eax
 446         movl    %eax,%dr1
 447         movl    PCB_DR2(%ecx),%eax
 448         movl    %eax,%dr2
 449         movl    PCB_DR3(%ecx),%eax
 450         movl    %eax,%dr3
 451         movl    PCB_DR6(%ecx),%eax
 452         movl    %eax,%dr6
 453         movl    PCB_DR7(%ecx),%eax
 454         movl    %eax,%dr7
 455
 456         /* Restore other registers */
 457         movl    PCB_EDI(%ecx),%edi
 458         movl    PCB_ESI(%ecx),%esi
 459         movl    PCB_EBP(%ecx),%ebp
 460         movl    PCB_ESP(%ecx),%esp
 461         movl    PCB_EBX(%ecx),%ebx
 462
 463         /* reload code selector by turning return into intersegmental return */
 464         pushl   PCB_EIP(%ecx)
 465         movl    $KCSEL,4(%esp)
 466         xorl    %eax,%eax
 467         lret
 468 END(resumectx)