sys/mips/mips/swtch.S

   1 /*      $OpenBSD: locore.S,v 1.18 1998/09/15 10:58:53 pefo Exp $        */
   2 /*-
   3  * Copyright (c) 1992, 1993
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * This code is derived from software contributed to Berkeley by
   7  * Digital Equipment Corporation and Ralph Campbell.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 4. Neither the name of the University nor the names of its contributors
  18  *    may be used to endorse or promote products derived from this software
  19  *    without specific prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  31  * SUCH DAMAGE.
  32  *
  33  * Copyright (C) 1989 Digital Equipment Corporation.
  34  * Permission to use, copy, modify, and distribute this software and
  35  * its documentation for any purpose and without fee is hereby granted,
  36  * provided that the above copyright notice appears in all copies.
  37  * Digital Equipment Corporation makes no representations about the
  38  * suitability of this software for any purpose.  It is provided "as is"
  39  * without express or implied warranty.
  40  *
  41  * from: Header: /sprite/src/kernel/mach/ds3100.md/RCS/loMem.s,
  42  *      v 1.1 89/07/11 17:55:04 nelson Exp  SPRITE (DECWRL)
  43  * from: Header: /sprite/src/kernel/mach/ds3100.md/RCS/machAsm.s,
  44  *      v 9.2 90/01/29 18:00:39 shirriff Exp  SPRITE (DECWRL)
  45  * from: Header: /sprite/src/kernel/vm/ds3100.md/vmPmaxAsm.s,
  46  *      v 1.1 89/07/10 14:27:41 nelson Exp  SPRITE (DECWRL)
  47  *
  48  *      from: @(#)locore.s      8.5 (Berkeley) 1/4/94
  49  *      JNPR: swtch.S,v 1.6.2.1 2007/09/10 10:36:50 girish
  50  * $FreeBSD$
  51  */
  52
  53 /*
  54  *      Contains code that is the first executed at boot time plus
  55  *      assembly language support routines.
  56  */
  57
  58 #include "opt_cputype.h"
  59 #include <sys/syscall.h>
  60 #include <machine/asm.h>
  61 #include <machine/cpu.h>
  62 #include <machine/cpuregs.h>
  63 #include <machine/regnum.h>
  64 #include <machine/pte.h>
  65
  66 #include "assym.s"
  67
  68         .set    noreorder                       # Noreorder is default style!
  69
  70 #define SAVE_U_PCB_REG(reg, offs, base) \
  71         REG_S   reg, U_PCB_REGS + (SZREG * offs) (base)
  72
  73 #define RESTORE_U_PCB_REG(reg, offs, base) \
  74         REG_L   reg, U_PCB_REGS + (SZREG * offs) (base)
  75
  76 #define SAVE_U_PCB_FPREG(reg, offs, base) \
  77         FP_S    reg, U_PCB_FPREGS + (SZFPREG * offs) (base)
  78
  79 #define RESTORE_U_PCB_FPREG(reg, offs, base) \
  80         FP_L    reg, U_PCB_FPREGS + (SZFPREG * offs) (base)
  81
  82 #define SAVE_U_PCB_FPSR(reg, offs, base) \
  83         REG_S   reg, U_PCB_FPREGS + (SZFPREG * offs) (base)
  84
  85 #define RESTORE_U_PCB_FPSR(reg, offs, base) \
  86         REG_L   reg, U_PCB_FPREGS + (SZFPREG * offs) (base)
  87
  88 #define SAVE_U_PCB_CONTEXT(reg, offs, base) \
  89         REG_S   reg, U_PCB_CONTEXT + (SZREG * offs) (base)
  90
  91 #define RESTORE_U_PCB_CONTEXT(reg, offs, base) \
  92         REG_L   reg, U_PCB_CONTEXT + (SZREG * offs) (base)
  93
  94
  95 /*
  96  * Setup for and return to user.
  97  */
  98 LEAF(fork_trampoline)
  99         move    a0,s0
 100         move    a1,s1
 101         jal     _C_LABEL(fork_exit)
 102         move    a2,s2                     #BDSlot
 103
 104         DO_AST
 105
 106         mfc0    v0, MIPS_COP_0_STATUS
 107         and     v0, ~(MIPS_SR_INT_IE)
 108         mtc0    v0, MIPS_COP_0_STATUS   # disable interrupts
 109         COP0_SYNC
 110 /*
 111  * The use of k1 for storing the PCB pointer must be done only
 112  * after interrupts are disabled.  Otherwise it will get overwritten
 113  * by the interrupt code.
 114  */
 115         .set    noat
 116         GET_CPU_PCPU(k1)
 117         PTR_L   k1, PC_CURPCB(k1)
 118
 119         RESTORE_U_PCB_REG(t0, MULLO, k1)
 120         RESTORE_U_PCB_REG(t1, MULHI, k1)
 121         mtlo    t0
 122         mthi    t1
 123         RESTORE_U_PCB_REG(a0, PC, k1)
 124         RESTORE_U_PCB_REG(AT, AST, k1)
 125         RESTORE_U_PCB_REG(v0, V0, k1)
 126         MTC0    a0, MIPS_COP_0_EXC_PC   # set return address
 127
 128         RESTORE_U_PCB_REG(v1, V1, k1)
 129         RESTORE_U_PCB_REG(a0, A0, k1)
 130         RESTORE_U_PCB_REG(a1, A1, k1)
 131         RESTORE_U_PCB_REG(a2, A2, k1)
 132         RESTORE_U_PCB_REG(a3, A3, k1)
 133         RESTORE_U_PCB_REG(t0, T0, k1)
 134         RESTORE_U_PCB_REG(t1, T1, k1)
 135         RESTORE_U_PCB_REG(t2, T2, k1)
 136         RESTORE_U_PCB_REG(t3, T3, k1)
 137         RESTORE_U_PCB_REG(ta0, TA0, k1)
 138         RESTORE_U_PCB_REG(ta1, TA1, k1)
 139         RESTORE_U_PCB_REG(ta2, TA2, k1)
 140         RESTORE_U_PCB_REG(ta3, TA3, k1)
 141         RESTORE_U_PCB_REG(s0, S0, k1)
 142         RESTORE_U_PCB_REG(s1, S1, k1)
 143         RESTORE_U_PCB_REG(s2, S2, k1)
 144         RESTORE_U_PCB_REG(s3, S3, k1)
 145         RESTORE_U_PCB_REG(s4, S4, k1)
 146         RESTORE_U_PCB_REG(s5, S5, k1)
 147         RESTORE_U_PCB_REG(s6, S6, k1)
 148         RESTORE_U_PCB_REG(s7, S7, k1)
 149         RESTORE_U_PCB_REG(t8, T8, k1)
 150         RESTORE_U_PCB_REG(t9, T9, k1)
 151         RESTORE_U_PCB_REG(k0, SR, k1)
 152         RESTORE_U_PCB_REG(gp, GP, k1)
 153         RESTORE_U_PCB_REG(s8, S8, k1)
 154         RESTORE_U_PCB_REG(ra, RA, k1)
 155         RESTORE_U_PCB_REG(sp, SP, k1)
 156         li      k1, ~MIPS_SR_INT_MASK
 157         and     k0, k0, k1
 158         mfc0    k1, MIPS_COP_0_STATUS
 159         and     k1, k1, MIPS_SR_INT_MASK
 160         or      k0, k0, k1
 161         mtc0    k0, MIPS_COP_0_STATUS   # switch to user mode (when eret...)
 162         HAZARD_DELAY
 163         sync
 164         eret
 165         .set    at
 166 END(fork_trampoline)
 167
 168 /*
 169  * Update pcb, saving current processor state.
 170  * Note: this only works if pcbp != curproc's pcb since
 171  * cpu_switch() will copy over pcb_context.
 172  *
 173  *      savectx(struct pcb *pcbp);
 174  */
 175 LEAF(savectx)
 176         SAVE_U_PCB_CONTEXT(s0, PREG_S0, a0)
 177         SAVE_U_PCB_CONTEXT(s1, PREG_S1, a0)
 178         SAVE_U_PCB_CONTEXT(s2, PREG_S2, a0)
 179         SAVE_U_PCB_CONTEXT(s3, PREG_S3, a0)
 180         mfc0    v0, MIPS_COP_0_STATUS
 181         SAVE_U_PCB_CONTEXT(s4, PREG_S4, a0)
 182         SAVE_U_PCB_CONTEXT(s5, PREG_S5, a0)
 183         SAVE_U_PCB_CONTEXT(s6, PREG_S6, a0)
 184         SAVE_U_PCB_CONTEXT(s7, PREG_S7, a0)
 185         SAVE_U_PCB_CONTEXT(sp, PREG_SP, a0)
 186         SAVE_U_PCB_CONTEXT(s8, PREG_S8, a0)
 187         SAVE_U_PCB_CONTEXT(ra, PREG_RA, a0)
 188         SAVE_U_PCB_CONTEXT(v0, PREG_SR, a0)
 189         SAVE_U_PCB_CONTEXT(gp, PREG_GP, a0)
 190
 191         move    v0, ra                  /* save 'ra' before we trash it */
 192         jal     1f
 193         nop
 194 1:
 195         SAVE_U_PCB_CONTEXT(ra, PREG_PC, a0)
 196         move    ra, v0                  /* restore 'ra' before returning */
 197
 198         j       ra
 199         move    v0, zero
 200 END(savectx)
 201
 202 NON_LEAF(cpu_throw, CALLFRAME_SIZ, ra)
 203         mfc0    t0, MIPS_COP_0_STATUS           # t0 = saved status register
 204         nop
 205         nop
 206         and     a3, t0, ~(MIPS_SR_INT_IE)
 207         mtc0    a3, MIPS_COP_0_STATUS           # Disable all interrupts
 208         ITLBNOPFIX
 209         j       mips_sw1                        # We're not interested in old
 210                                                 # thread's context, so jump
 211                                                 # right to action
 212         nop                                     # BDSLOT
 213 END(cpu_throw)
 214
 215 /*
 216  * cpu_switch(struct thread *old, struct thread *new, struct mutex *mtx);
 217  *      a0 - old
 218  *      a1 - new
 219  *      a2 - mtx
 220  * Find the highest priority process and resume it.
 221  */
 222 NON_LEAF(cpu_switch, CALLFRAME_SIZ, ra)
 223         mfc0    t0, MIPS_COP_0_STATUS           # t0 = saved status register
 224         nop
 225         nop
 226         and     a3, t0, ~(MIPS_SR_INT_IE)
 227         mtc0    a3, MIPS_COP_0_STATUS           # Disable all interrupts
 228         ITLBNOPFIX
 229         beqz    a0, mips_sw1
 230         move    a3, a0
 231         PTR_L   a0, TD_PCB(a0)          # load PCB addr of curproc
 232         SAVE_U_PCB_CONTEXT(sp, PREG_SP, a0)             # save old sp
 233         PTR_SUBU        sp, sp, CALLFRAME_SIZ
 234         REG_S   ra, CALLFRAME_RA(sp)
 235         .mask   0x80000000, (CALLFRAME_RA - CALLFRAME_SIZ)
 236         SAVE_U_PCB_CONTEXT(s0, PREG_S0, a0)             # do a 'savectx()'
 237         SAVE_U_PCB_CONTEXT(s1, PREG_S1, a0)
 238         SAVE_U_PCB_CONTEXT(s2, PREG_S2, a0)
 239         SAVE_U_PCB_CONTEXT(s3, PREG_S3, a0)
 240         SAVE_U_PCB_CONTEXT(s4, PREG_S4, a0)
 241         SAVE_U_PCB_CONTEXT(s5, PREG_S5, a0)
 242         SAVE_U_PCB_CONTEXT(s6, PREG_S6, a0)
 243         SAVE_U_PCB_CONTEXT(s7, PREG_S7, a0)
 244         SAVE_U_PCB_CONTEXT(s8, PREG_S8, a0)
 245         SAVE_U_PCB_CONTEXT(ra, PREG_RA, a0)             # save return address
 246         SAVE_U_PCB_CONTEXT(t0, PREG_SR, a0)             # save status register
 247         SAVE_U_PCB_CONTEXT(gp, PREG_GP, a0)
 248         jal     getpc
 249         nop
 250 getpc:
 251         SAVE_U_PCB_CONTEXT(ra, PREG_PC, a0)             # save return address
 252
 253 #ifdef CPU_CNMIPS
 254
 255         lw      t2, TD_MDFLAGS(a3)              # get md_flags
 256         and     t1, t2, MDTD_COP2USED
 257         beqz    t1, cop2_untouched
 258         nop
 259
 260         /* Clear cop2used flag */
 261         and     t2, t2, ~MDTD_COP2USED
 262         sw      t2, TD_MDFLAGS(a3)
 263
 264         and     t2, t0, ~MIPS_SR_COP_2_BIT      # clear COP_2 enable bit
 265         SAVE_U_PCB_CONTEXT(t2, PREG_SR, a0)     # save status register
 266
 267         RESTORE_U_PCB_REG(t0, PS, a0)           # get CPU status register
 268         and     t2, t0, ~MIPS_SR_COP_2_BIT      # clear COP_2 enable bit
 269         SAVE_U_PCB_REG(t2, PS, a0)              # save stratus register
 270
 271         /* preserve a0..a3 */
 272         move    s0, a0
 273         move    s1, a1
 274         move    s2, a2
 275         move    s3, a3
 276
 277         /* does kernel own COP2 context? */
 278         lw      t1, TD_COP2OWNER(a3)            # get md_cop2owner
 279         beqz    t1, userland_cop2               # 0 - it's userland context
 280         nop
 281
 282         PTR_L   a0, TD_COP2(a3)
 283         beqz    a0, no_cop2_context
 284         nop
 285
 286         j       do_cop2_save
 287         nop
 288
 289 userland_cop2:
 290
 291         PTR_L   a0, TD_UCOP2(a3)
 292         beqz    a0, no_cop2_context
 293         nop
 294
 295 do_cop2_save:
 296         jal     octeon_cop2_save
 297         nop
 298
 299 no_cop2_context:
 300         move    a3, s3
 301         move    a2, s2
 302         move    a1, s1
 303         move    a0, s0
 304
 305 cop2_untouched:
 306 #endif
 307
 308         PTR_S   a2, TD_LOCK(a3)                 # Switchout td_lock
 309
 310 mips_sw1:
 311 #if defined(SMP) && defined(SCHED_ULE)
 312         PTR_LA  t0, _C_LABEL(blocked_lock)
 313 blocked_loop:
 314         PTR_L   t1, TD_LOCK(a1)
 315         beq     t0, t1, blocked_loop
 316         nop
 317 #endif
 318         move    s7, a1  # Store newthread
 319 /*
 320  * Switch to new context.
 321  */
 322         GET_CPU_PCPU(a3)
 323         PTR_S   a1, PC_CURTHREAD(a3)
 324         PTR_L   a2, TD_PCB(a1)
 325         PTR_S   a2, PC_CURPCB(a3)
 326         PTR_L   v0, TD_KSTACK(a1)
 327 #if defined(__mips_n64)
 328         PTR_LI  s0, MIPS_XKSEG_START
 329 #else
 330         PTR_LI  s0, MIPS_KSEG2_START            # If Uarea addr is below kseg2,
 331 #endif
 332         bltu    v0, s0, sw2                     # no need to insert in TLB.
 333         PTE_L   a1, TD_UPTE + 0(s7)             # a1 = u. pte #0
 334         PTE_L   a2, TD_UPTE + PTESIZE(s7)       # a2 = u. pte #1
 335 /*
 336  * Wiredown the USPACE of newproc in TLB entry#0.  Check whether target
 337  * USPACE is already in another place of TLB before that, and if so
 338  * invalidate that TLB entry.
 339  * NOTE: This is hard coded to UPAGES == 2.
 340  * Also, there should be no TLB faults at this point.
 341  */
 342         MTC0    v0, MIPS_COP_0_TLB_HI           # VPN = va
 343         HAZARD_DELAY
 344         tlbp                                    # probe VPN
 345         HAZARD_DELAY
 346         mfc0    s0, MIPS_COP_0_TLB_INDEX
 347         HAZARD_DELAY
 348
 349         PTR_LI  t1, MIPS_KSEG0_START            # invalidate tlb entry
 350         bltz    s0, entry0set
 351         nop
 352         sll     s0, PAGE_SHIFT + 1
 353         addu    t1, s0
 354         MTC0    t1, MIPS_COP_0_TLB_HI
 355         PTE_MTC0        zero, MIPS_COP_0_TLB_LO0
 356         PTE_MTC0        zero, MIPS_COP_0_TLB_LO1
 357         HAZARD_DELAY
 358         tlbwi
 359         HAZARD_DELAY
 360         MTC0    v0, MIPS_COP_0_TLB_HI           # set VPN again
 361
 362 entry0set:
 363 /* SMP!! - Works only for  unshared TLB case - i.e. no v-cpus */
 364         mtc0    zero, MIPS_COP_0_TLB_INDEX              # TLB entry #0
 365         HAZARD_DELAY
 366         PTE_MTC0        a1, MIPS_COP_0_TLB_LO0          # upte[0]
 367         HAZARD_DELAY
 368         PTE_MTC0        a2, MIPS_COP_0_TLB_LO1          # upte[1]
 369         HAZARD_DELAY
 370         tlbwi                                   # set TLB entry #0
 371         HAZARD_DELAY
 372 /*
 373  * Now running on new u struct.
 374  */
 375 sw2:
 376         PTR_L   s0, TD_PCB(s7)
 377         RESTORE_U_PCB_CONTEXT(sp, PREG_SP, s0)
 378         PTR_LA  t1, _C_LABEL(pmap_activate)     # s7 = new proc pointer
 379         jalr    t1                              # s7 = new proc pointer
 380         move    a0, s7                          # BDSLOT
 381 /*
 382  * Restore registers and return.
 383  */
 384         move    a0, s0
 385         RESTORE_U_PCB_CONTEXT(gp, PREG_GP, a0)
 386         RESTORE_U_PCB_CONTEXT(v0, PREG_SR, a0)  # restore kernel context
 387         RESTORE_U_PCB_CONTEXT(ra, PREG_RA, a0)
 388         RESTORE_U_PCB_CONTEXT(s0, PREG_S0, a0)
 389         RESTORE_U_PCB_CONTEXT(s1, PREG_S1, a0)
 390         RESTORE_U_PCB_CONTEXT(s2, PREG_S2, a0)
 391         RESTORE_U_PCB_CONTEXT(s3, PREG_S3, a0)
 392         RESTORE_U_PCB_CONTEXT(s4, PREG_S4, a0)
 393         RESTORE_U_PCB_CONTEXT(s5, PREG_S5, a0)
 394         RESTORE_U_PCB_CONTEXT(s6, PREG_S6, a0)
 395         RESTORE_U_PCB_CONTEXT(s7, PREG_S7, a0)
 396         RESTORE_U_PCB_CONTEXT(s8, PREG_S8, a0)
 397
 398         mfc0    t0, MIPS_COP_0_STATUS
 399         and     t0, t0, MIPS_SR_INT_MASK
 400         and     v0, v0, ~MIPS_SR_INT_MASK
 401         or      v0, v0, t0
 402         mtc0    v0, MIPS_COP_0_STATUS
 403         ITLBNOPFIX
 404
 405         j       ra
 406         nop
 407 END(cpu_switch)
 408
 409 /*----------------------------------------------------------------------------
 410  *
 411  * MipsSwitchFPState --
 412  *
 413  *      Save the current state into 'from' and restore it from 'to'.
 414  *
 415  *      MipsSwitchFPState(from, to)
 416  *              struct thread *from;
 417  *              struct trapframe *to;
 418  *
 419  * Results:
 420  *      None.
 421  *
 422  * Side effects:
 423  *      None.
 424  *
 425  *----------------------------------------------------------------------------
 426  */
 427 LEAF(MipsSwitchFPState)
 428         mfc0    t1, MIPS_COP_0_STATUS   # Save old SR
 429         li      t0, MIPS_SR_COP_1_BIT   # enable the coprocessor
 430         mtc0    t0, MIPS_COP_0_STATUS
 431         ITLBNOPFIX
 432
 433         beq     a0, zero, 1f            # skip save if NULL pointer
 434         nop
 435 /*
 436  * First read out the status register to make sure that all FP operations
 437  * have completed.
 438  */
 439         PTR_L   a0, TD_PCB(a0)                  # get pointer to pcb for proc
 440         cfc1    t0, MIPS_FPU_CSR                # stall til FP done
 441         cfc1    t0, MIPS_FPU_CSR                # now get status
 442         li      t3, ~MIPS_SR_COP_1_BIT
 443         RESTORE_U_PCB_REG(t2, PS, a0)           # get CPU status register
 444         SAVE_U_PCB_FPSR(t0, FSR_NUM, a0)        # save FP status
 445         and     t2, t2, t3                      # clear COP_1 enable bit
 446         SAVE_U_PCB_REG(t2, PS, a0)              # save new status register
 447 /*
 448  * Save the floating point registers.
 449  */
 450         SAVE_U_PCB_FPREG($f0, F0_NUM, a0)
 451         SAVE_U_PCB_FPREG($f1, F1_NUM, a0)
 452         SAVE_U_PCB_FPREG($f2, F2_NUM, a0)
 453         SAVE_U_PCB_FPREG($f3, F3_NUM, a0)
 454         SAVE_U_PCB_FPREG($f4, F4_NUM, a0)
 455         SAVE_U_PCB_FPREG($f5, F5_NUM, a0)
 456         SAVE_U_PCB_FPREG($f6, F6_NUM, a0)
 457         SAVE_U_PCB_FPREG($f7, F7_NUM, a0)
 458         SAVE_U_PCB_FPREG($f8, F8_NUM, a0)
 459         SAVE_U_PCB_FPREG($f9, F9_NUM, a0)
 460         SAVE_U_PCB_FPREG($f10, F10_NUM, a0)
 461         SAVE_U_PCB_FPREG($f11, F11_NUM, a0)
 462         SAVE_U_PCB_FPREG($f12, F12_NUM, a0)
 463         SAVE_U_PCB_FPREG($f13, F13_NUM, a0)
 464         SAVE_U_PCB_FPREG($f14, F14_NUM, a0)
 465         SAVE_U_PCB_FPREG($f15, F15_NUM, a0)
 466         SAVE_U_PCB_FPREG($f16, F16_NUM, a0)
 467         SAVE_U_PCB_FPREG($f17, F17_NUM, a0)
 468         SAVE_U_PCB_FPREG($f18, F18_NUM, a0)
 469         SAVE_U_PCB_FPREG($f19, F19_NUM, a0)
 470         SAVE_U_PCB_FPREG($f20, F20_NUM, a0)
 471         SAVE_U_PCB_FPREG($f21, F21_NUM, a0)
 472         SAVE_U_PCB_FPREG($f22, F22_NUM, a0)
 473         SAVE_U_PCB_FPREG($f23, F23_NUM, a0)
 474         SAVE_U_PCB_FPREG($f24, F24_NUM, a0)
 475         SAVE_U_PCB_FPREG($f25, F25_NUM, a0)
 476         SAVE_U_PCB_FPREG($f26, F26_NUM, a0)
 477         SAVE_U_PCB_FPREG($f27, F27_NUM, a0)
 478         SAVE_U_PCB_FPREG($f28, F28_NUM, a0)
 479         SAVE_U_PCB_FPREG($f29, F29_NUM, a0)
 480         SAVE_U_PCB_FPREG($f30, F30_NUM, a0)
 481         SAVE_U_PCB_FPREG($f31, F31_NUM, a0)
 482
 483 1:
 484 /*
 485  *  Restore the floating point registers.
 486  */
 487         RESTORE_U_PCB_FPSR(t0, FSR_NUM, a1)     # get status register
 488         RESTORE_U_PCB_FPREG($f0, F0_NUM, a1)
 489         RESTORE_U_PCB_FPREG($f1, F1_NUM, a1)
 490         RESTORE_U_PCB_FPREG($f2, F2_NUM, a1)
 491         RESTORE_U_PCB_FPREG($f3, F3_NUM, a1)
 492         RESTORE_U_PCB_FPREG($f4, F4_NUM, a1)
 493         RESTORE_U_PCB_FPREG($f5, F5_NUM, a1)
 494         RESTORE_U_PCB_FPREG($f6, F6_NUM, a1)
 495         RESTORE_U_PCB_FPREG($f7, F7_NUM, a1)
 496         RESTORE_U_PCB_FPREG($f8, F8_NUM, a1)
 497         RESTORE_U_PCB_FPREG($f9, F9_NUM, a1)
 498         RESTORE_U_PCB_FPREG($f10, F10_NUM, a1)
 499         RESTORE_U_PCB_FPREG($f11, F11_NUM, a1)
 500         RESTORE_U_PCB_FPREG($f12, F12_NUM, a1)
 501         RESTORE_U_PCB_FPREG($f13, F13_NUM, a1)
 502         RESTORE_U_PCB_FPREG($f14, F14_NUM, a1)
 503         RESTORE_U_PCB_FPREG($f15, F15_NUM, a1)
 504         RESTORE_U_PCB_FPREG($f16, F16_NUM, a1)
 505         RESTORE_U_PCB_FPREG($f17, F17_NUM, a1)
 506         RESTORE_U_PCB_FPREG($f18, F18_NUM, a1)
 507         RESTORE_U_PCB_FPREG($f19, F19_NUM, a1)
 508         RESTORE_U_PCB_FPREG($f20, F20_NUM, a1)
 509         RESTORE_U_PCB_FPREG($f21, F21_NUM, a1)
 510         RESTORE_U_PCB_FPREG($f22, F22_NUM, a1)
 511         RESTORE_U_PCB_FPREG($f23, F23_NUM, a1)
 512         RESTORE_U_PCB_FPREG($f24, F24_NUM, a1)
 513         RESTORE_U_PCB_FPREG($f25, F25_NUM, a1)
 514         RESTORE_U_PCB_FPREG($f26, F26_NUM, a1)
 515         RESTORE_U_PCB_FPREG($f27, F27_NUM, a1)
 516         RESTORE_U_PCB_FPREG($f28, F28_NUM, a1)
 517         RESTORE_U_PCB_FPREG($f29, F29_NUM, a1)
 518         RESTORE_U_PCB_FPREG($f30, F30_NUM, a1)
 519         RESTORE_U_PCB_FPREG($f31, F31_NUM, a1)
 520
 521         and     t0, t0, ~MIPS_FPU_EXCEPTION_BITS
 522         ctc1    t0, MIPS_FPU_CSR
 523         nop
 524
 525         mtc0    t1, MIPS_COP_0_STATUS           # Restore the status register.
 526         ITLBNOPFIX
 527         j       ra
 528         nop
 529 END(MipsSwitchFPState)
 530
 531 /*----------------------------------------------------------------------------
 532  *
 533  * MipsSaveCurFPState --
 534  *
 535  *      Save the current floating point coprocessor state.
 536  *
 537  *      MipsSaveCurFPState(td)
 538  *              struct thread *td;
 539  *
 540  * Results:
 541  *      None.
 542  *
 543  * Side effects:
 544  *      machFPCurProcPtr is cleared.
 545  *
 546  *----------------------------------------------------------------------------
 547  */
 548 LEAF(MipsSaveCurFPState)
 549         PTR_L   a0, TD_PCB(a0)                  # get pointer to pcb for thread
 550         mfc0    t1, MIPS_COP_0_STATUS           # Disable interrupts and
 551         li      t0, MIPS_SR_COP_1_BIT           #  enable the coprocessor
 552         mtc0    t0, MIPS_COP_0_STATUS
 553         ITLBNOPFIX
 554         GET_CPU_PCPU(a1)
 555         PTR_S   zero, PC_FPCURTHREAD(a1)        # indicate state has been saved
 556 /*
 557  * First read out the status register to make sure that all FP operations
 558  * have completed.
 559  */
 560         RESTORE_U_PCB_REG(t2, PS, a0)           # get CPU status register
 561         li      t3, ~MIPS_SR_COP_1_BIT
 562         and     t2, t2, t3                      # clear COP_1 enable bit
 563         cfc1    t0, MIPS_FPU_CSR                # stall til FP done
 564         cfc1    t0, MIPS_FPU_CSR                # now get status
 565         SAVE_U_PCB_REG(t2, PS, a0)              # save new status register
 566         SAVE_U_PCB_FPSR(t0, FSR_NUM, a0)        # save FP status
 567 /*
 568  * Save the floating point registers.
 569  */
 570         SAVE_U_PCB_FPREG($f0, F0_NUM, a0)
 571         SAVE_U_PCB_FPREG($f1, F1_NUM, a0)
 572         SAVE_U_PCB_FPREG($f2, F2_NUM, a0)
 573         SAVE_U_PCB_FPREG($f3, F3_NUM, a0)
 574         SAVE_U_PCB_FPREG($f4, F4_NUM, a0)
 575         SAVE_U_PCB_FPREG($f5, F5_NUM, a0)
 576         SAVE_U_PCB_FPREG($f6, F6_NUM, a0)
 577         SAVE_U_PCB_FPREG($f7, F7_NUM, a0)
 578         SAVE_U_PCB_FPREG($f8, F8_NUM, a0)
 579         SAVE_U_PCB_FPREG($f9, F9_NUM, a0)
 580         SAVE_U_PCB_FPREG($f10, F10_NUM, a0)
 581         SAVE_U_PCB_FPREG($f11, F11_NUM, a0)
 582         SAVE_U_PCB_FPREG($f12, F12_NUM, a0)
 583         SAVE_U_PCB_FPREG($f13, F13_NUM, a0)
 584         SAVE_U_PCB_FPREG($f14, F14_NUM, a0)
 585         SAVE_U_PCB_FPREG($f15, F15_NUM, a0)
 586         SAVE_U_PCB_FPREG($f16, F16_NUM, a0)
 587         SAVE_U_PCB_FPREG($f17, F17_NUM, a0)
 588         SAVE_U_PCB_FPREG($f18, F18_NUM, a0)
 589         SAVE_U_PCB_FPREG($f19, F19_NUM, a0)
 590         SAVE_U_PCB_FPREG($f20, F20_NUM, a0)
 591         SAVE_U_PCB_FPREG($f21, F21_NUM, a0)
 592         SAVE_U_PCB_FPREG($f22, F22_NUM, a0)
 593         SAVE_U_PCB_FPREG($f23, F23_NUM, a0)
 594         SAVE_U_PCB_FPREG($f24, F24_NUM, a0)
 595         SAVE_U_PCB_FPREG($f25, F25_NUM, a0)
 596         SAVE_U_PCB_FPREG($f26, F26_NUM, a0)
 597         SAVE_U_PCB_FPREG($f27, F27_NUM, a0)
 598         SAVE_U_PCB_FPREG($f28, F28_NUM, a0)
 599         SAVE_U_PCB_FPREG($f29, F29_NUM, a0)
 600         SAVE_U_PCB_FPREG($f30, F30_NUM, a0)
 601         SAVE_U_PCB_FPREG($f31, F31_NUM, a0)
 602
 603         mtc0    t1, MIPS_COP_0_STATUS           # Restore the status register.
 604         ITLBNOPFIX
 605         j       ra
 606         nop
 607 END(MipsSaveCurFPState)
 608
 609 /*
 610  * When starting init, call this to configure the process for user
 611  * mode.  This will be inherited by other processes.
 612  */
 613 LEAF_NOPROFILE(prepare_usermode)
 614         j       ra
 615         nop
 616 END(prepare_usermode)
 617
 618
 619 /*
 620  * This code is copied the user's stack for returning from signal handlers
 621  * (see sendsig() and sigreturn()). We have to compute the address
 622  * of the sigcontext struct for the sigreturn call.
 623  */
 624         .globl  _C_LABEL(sigcode)
 625 _C_LABEL(sigcode):
 626         PTR_ADDU        a0, sp, SIGF_UC         # address of ucontext
 627         li              v0, SYS_sigreturn
 628 # sigreturn (ucp)
 629         syscall
 630         break   0                               # just in case sigreturn fails
 631         .globl  _C_LABEL(esigcode)
 632 _C_LABEL(esigcode):
 633
 634         .data
 635         .globl  szsigcode
 636 szsigcode:
 637         .long   esigcode-sigcode
 638         .text