sys/powerpc/aim/locore64.S

   1 /* $FreeBSD$ */
   2
   3 /*-
   4  * Copyright (C) 2010-2016 Nathan Whitehorn
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  17  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  18  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  19  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  20  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  21  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  22  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  23  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  24  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  25  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  26  *
  27  * $FreeBSD$
  28  */
  29
  30 #include "assym.inc"
  31
  32 #include <sys/syscall.h>
  33
  34 #include <machine/trap.h>
  35 #include <machine/param.h>
  36 #include <machine/spr.h>
  37 #include <machine/asm.h>
  38 #include <machine/vmparam.h>
  39
  40 #ifdef _CALL_ELF
  41 .abiversion _CALL_ELF
  42 #endif
  43
  44 /* Glue for linker script */
  45 .globl  kernbase
  46 .set    kernbase, KERNBASE
  47
  48 /*
  49  * Globals
  50  */
  51         .data
  52         .align 3
  53 GLOBAL(__startkernel)
  54         .llong  begin
  55 GLOBAL(__endkernel)
  56         .llong  end
  57 GLOBAL(can_wakeup)
  58         .llong  0x0
  59
  60         .align  4
  61 #define TMPSTKSZ        16384           /* 16K temporary stack */
  62 GLOBAL(tmpstk)
  63         .space  TMPSTKSZ
  64
  65 TOC_ENTRY(tmpstk)
  66 TOC_ENTRY(can_wakeup)
  67
  68 /*
  69  * Entry point for bootloaders that do not fully implement ELF and start
  70  * at the beginning of the image (kexec, notably). In its own section so
  71  * that it ends up before any linker-generated call stubs and actually at
  72  * the beginning of the image. kexec on some systems also enters at
  73  * (start of image) + 0x60, so put a spin loop there.
  74  */
  75         .section ".text.kboot", "x", @progbits
  76 kbootentry:
  77         b __start
  78 . = kbootentry + 0x40   /* Magic address used in platform layer */
  79         .global smp_spin_sem
  80 ap_kexec_spin_sem:
  81         .long   -1
  82 . = kbootentry + 0x60   /* Entry point for kexec APs */
  83 ap_kexec_start:         /* At 0x60 past start, copied to 0x60 by kexec */
  84         /* r3 set to CPU ID by kexec */
  85
  86         /* Invalidate icache for low-memory copy and jump there */
  87         li      %r0,0x80
  88         dcbst   0,%r0
  89         sync
  90         icbi    0,%r0
  91         isync
  92         ba      0x80                    /* Absolute branch to next inst */
  93
  94 . = kbootentry + 0x80                   /* Aligned to cache line */
  95 1:      or      31,31,31                /* yield */
  96         sync
  97         lwz     %r1,0x40(0)             /* Spin on ap_kexec_spin_sem */
  98         cmpw    %r1,%r3                 /* Until it equals our CPU ID */
  99         bne     1b
 100
 101         /* Released */
 102         or      2,2,2                   /* unyield */
 103
 104         /* Make sure that it will be software reset. Clear SRR1 */
 105         li      %r1,0
 106         mtsrr1  %r1
 107         ba      EXC_RST
 108
 109 /*
 110  * Now start the real text section
 111  */
 112
 113         .text
 114         .globl  btext
 115 btext:
 116
 117 /*
 118  * Main kernel entry point.
 119  *
 120  * Calling convention:
 121  * r3: Flattened Device Tree pointer (or zero)
 122  * r4: ignored
 123  * r5: OF client interface pointer (or zero)
 124  * r6: Loader metadata pointer (or zero)
 125  * r7: Magic cookie (0xfb5d104d) to indicate that r6 has loader metadata
 126  */
 127         .text
 128 ASENTRY_NOPROF(__start)
 129         /* Set 64-bit mode if not yet set before branching to C */
 130         mfmsr   %r20
 131         li      %r21,1
 132         insrdi  %r20,%r21,1,0
 133         mtmsrd  %r20
 134         isync
 135         nop     /* Make this block a multiple of 8 bytes */
 136
 137         /* Set up the TOC pointer */
 138         b       0f
 139         .align 3
 140 0:      nop
 141         bl      1f
 142         .llong  __tocbase + 0x8000 - .
 143 1:      mflr    %r2
 144         ld      %r1,0(%r2)
 145         add     %r2,%r1,%r2
 146
 147         /* Get load offset */
 148         ld      %r31,-0x8000(%r2) /* First TOC entry is TOC base */
 149         subf    %r31,%r31,%r2   /* Subtract from real TOC base to get base */
 150
 151         /* Set up the stack pointer */
 152         bl      1f
 153         .llong  tmpstk + TMPSTKSZ - 96 - .
 154 1:      mflr    %r30
 155         ld      %r1,0(%r30)
 156         add     %r1,%r1,%r30
 157         nop
 158
 159         /* Relocate kernel */
 160         std     %r3,48(%r1)
 161         std     %r4,56(%r1)
 162         std     %r5,64(%r1)
 163         std     %r6,72(%r1)
 164         std     %r7,80(%r1)
 165
 166         bl      1f
 167         .llong _DYNAMIC-.
 168 1:      mflr    %r3
 169         ld      %r4,0(%r3)
 170         add     %r3,%r4,%r3
 171         mr      %r4,%r31
 172         bl      elf_reloc_self
 173         nop
 174         ld      %r3,48(%r1)
 175         ld      %r4,56(%r1)
 176         ld      %r5,64(%r1)
 177         ld      %r6,72(%r1)
 178         ld      %r7,80(%r1)
 179
 180         /* Begin CPU init */
 181         mr      %r4,%r2 /* Replace ignored r4 with tocbase for trap handlers */
 182         bl      powerpc_init
 183         nop
 184
 185         /* Set stack pointer to new value and branch to mi_startup */
 186         mr      %r1, %r3
 187         li      %r3, 0
 188         std     %r3, 0(%r1)
 189         bl      mi_startup
 190         nop
 191
 192         /* Unreachable */
 193         b       .
 194
 195 ASENTRY_NOPROF(__restartkernel)
 196         /*
 197          * r3-r7: arguments to go to __start
 198          * r8: offset from current kernel address to apply
 199          * r9: MSR to set when (atomically) jumping to __start + r8
 200          */
 201         mtsrr1  %r9
 202         bl      1f
 203 1:      mflr    %r25
 204         add     %r25,%r8,%r25
 205         addi    %r25,%r25,2f-1b
 206         mtsrr0  %r25
 207         rfid
 208 2:      bl      __start
 209         nop
 210
 211 #include <powerpc/aim/trap_subr64.S>