sys/powerpc/aim/swtch.S

   1 /* $FreeBSD$ */
   2 /* $NetBSD: locore.S,v 1.24 2000/05/31 05:09:17 thorpej Exp $ */
   3
   4 /*-
   5  * Copyright (C) 2001 Benno Rice
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY Benno Rice ``AS IS'' AND ANY EXPRESS OR
  18  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  19  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  21  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  22  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  23  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  24  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  25  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  26  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27 */
  28 /*-
  29  * Copyright (C) 1995, 1996 Wolfgang Solfrank.
  30  * Copyright (C) 1995, 1996 TooLs GmbH.
  31  * All rights reserved.
  32  *
  33  * Redistribution and use in source and binary forms, with or without
  34  * modification, are permitted provided that the following conditions
  35  * are met:
  36  * 1. Redistributions of source code must retain the above copyright
  37  *    notice, this list of conditions and the following disclaimer.
  38  * 2. Redistributions in binary form must reproduce the above copyright
  39  *    notice, this list of conditions and the following disclaimer in the
  40  *    documentation and/or other materials provided with the distribution.
  41  * 3. All advertising materials mentioning features or use of this software
  42  *    must display the following acknowledgement:
  43  *      This product includes software developed by TooLs GmbH.
  44  * 4. The name of TooLs GmbH may not be used to endorse or promote products
  45  *    derived from this software without specific prior written permission.
  46  *
  47  * THIS SOFTWARE IS PROVIDED BY TOOLS GMBH ``AS IS'' AND ANY EXPRESS OR
  48  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  49  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  50  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  51  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  52  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  53  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  54  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  55  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  56  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  57  */
  58
  59 #include "assym.s"
  60
  61 #include <sys/syscall.h>
  62
  63 #include <machine/trap.h>
  64 #include <machine/param.h>
  65 #include <machine/sr.h>
  66 #include <machine/psl.h>
  67 #include <machine/asm.h>
  68
  69 /*
  70  * void cpu_switch(struct thread *old,
  71  *                 struct thread *new,
  72  *                 struct mutex *mtx);
  73  *
  74  * Switch to a new thread saving the current state in the old thread.
  75  */
  76 ENTRY(cpu_switch)
  77         stw     %r5,TD_LOCK(%r3)        /* ULE: update old thread's lock */
  78                                         /* XXX needs to change for MP */
  79
  80         lwz     %r5,TD_PCB(%r3)         /* Get the old thread's PCB ptr */
  81         mr      %r12,%r2
  82         stmw    %r12,PCB_CONTEXT(%r5)   /* Save the non-volatile GP regs.
  83                                            These can now be used for scratch */
  84
  85         mfcr    %r16                    /* Save the condition register */
  86         stw     %r16,PCB_CR(%r5)
  87         mflr    %r16                    /* Save the link register */
  88         stw     %r16,PCB_LR(%r5)
  89         mfsr    %r16,USER_SR            /* Save USER_SR for copyin/out */
  90         isync
  91         stw     %r16,PCB_AIM_USR(%r5)
  92         stw     %r1,PCB_SP(%r5)         /* Save the stack pointer */
  93
  94         mr      %r14,%r3                /* Copy the old thread ptr... */
  95         mr      %r15,%r4                /* and the new thread ptr in scratch */
  96
  97         lwz     %r6,PCB_FLAGS(%r5)      /* Save FPU context if needed */
  98         andi.   %r6, %r6, PCB_FPU
  99         beq     .L1
 100         bl      save_fpu
 101         mr      %r3,%r14                /* restore old thread ptr */
 102 .L1:
 103         bl      pmap_deactivate         /* Deactivate the current pmap */
 104
 105         mr      %r3,%r15                /* Get new thread ptr */
 106         bl      pmap_activate           /* Activate the new address space */
 107
 108         mfsprg  %r7,0                   /* Get the pcpu pointer */
 109         stw     %r15,PC_CURTHREAD(%r7)  /* Store new current thread */
 110         lwz     %r17,TD_PCB(%r15)       /* Store new current PCB */
 111         stw     %r17,PC_CURPCB(%r7)
 112
 113         lwz     %r6, PCB_FLAGS(%r17)    /* Restore FPU context if needed */
 114         andi.   %r6, %r6, PCB_FPU
 115         beq     .L2
 116         mr      %r3,%r15                /* Pass curthread to enable_fpu */
 117         bl      enable_fpu
 118
 119         /* thread to restore is in r3 */
 120 .L2:
 121         mr      %r3,%r17                /* Recover PCB ptr */
 122         lmw     %r12,PCB_CONTEXT(%r3)   /* Load the non-volatile GP regs */
 123         mr      %r2,%r12
 124         lwz     %r5,PCB_CR(%r3)         /* Load the condition register */
 125         mtcr    %r5
 126         lwz     %r5,PCB_LR(%r3)         /* Load the link register */
 127         mtlr    %r5
 128         lwz     %r5,PCB_AIM_USR(%r3)    /* Load the USER_SR segment reg */
 129         mtsr    USER_SR,%r5
 130         isync
 131         lwz     %r1,PCB_SP(%r3)         /* Load the stack pointer */
 132         blr
 133
 134 /*
 135  * savectx(pcb)
 136  * Update pcb, saving current processor state
 137  */
 138 ENTRY(savectx)
 139         mr      %r12,%r2
 140         stmw    %r12,PCB_CONTEXT(%r3)   /* Save the non-volatile GP regs */
 141         mfcr    %r4                     /* Save the condition register */
 142         stw     %r4,PCB_CONTEXT(%r3)
 143         blr
 144
 145 /*
 146  * fork_trampoline()
 147  * Set up the return from cpu_fork()
 148  */
 149 ENTRY(fork_trampoline)
 150         lwz     %r3,CF_FUNC(%r1)
 151         lwz     %r4,CF_ARG0(%r1)
 152         lwz     %r5,CF_ARG1(%r1)
 153         bl      fork_exit
 154         addi    %r1,%r1,CF_SIZE-FSP     /* Allow 8 bytes in front of
 155                                            trapframe to simulate FRAME_SETUP
 156                                            does when allocating space for
 157                                            a frame pointer/saved LR */
 158         b       trapexit