sys/powerpc/ofw/ofwcall32.S

   1 /*-
   2  * Copyright (C) 2009-2011 Nathan Whitehorn
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  15  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  16  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  17  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  18  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  19  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  20  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  21  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  22  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  23  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  24  *
  25  * $FreeBSD$
  26  */
  27
  28 #include <sys/syscall.h>
  29
  30 #include <machine/trap.h>
  31 #include <machine/param.h>
  32 #include <machine/spr.h>
  33 #include <machine/asm.h>
  34
  35 #define OFWSTKSZ        4096            /* 4K Open Firmware stack */
  36
  37 /*
  38  * Globals
  39  */
  40         .data
  41 GLOBAL(ofmsr)
  42         .long   0, 0, 0, 0, 0           /* msr/sprg0-3 used in Open Firmware */
  43 GLOBAL(rtasmsr)
  44         .long   0
  45 GLOBAL(openfirmware_entry)
  46         .long   0                       /* Open Firmware entry point */
  47 GLOBAL(rtas_entry)
  48         .long   0                       /* RTAS entry point */
  49
  50         .align  4
  51 ofwstk:
  52         .space  OFWSTKSZ
  53 rtas_regsave:
  54         .space  4
  55
  56 /*
  57  * Open Firmware Entry Point. May need to enter real mode.
  58  *
  59  * C prototype: int ofwcall(void *callbuffer);
  60  */
  61
  62 ASENTRY(ofwcall)
  63         mflr    %r0
  64         stw     %r0,4(%r1)
  65
  66         /* Record the old MSR */
  67         mfmsr   %r6
  68
  69         /* GOT pointer in r7 */
  70         bl      1f
  71 1:
  72         mflr    %r7
  73         addis   %r7,%r7,(_GLOBAL_OFFSET_TABLE_-1b)@ha
  74         addi    %r7,%r7,(_GLOBAL_OFFSET_TABLE_-1b)@l
  75
  76         /* read client interface handler */
  77         lwz     %r4,openfirmware_entry@got(%r7)
  78         lwz     %r4,0(%r4)
  79
  80         /*
  81          * Set the MSR to the OF value. This has the side effect of disabling
  82          * exceptions, which prevents preemption later.
  83          */
  84
  85         lwz     %r5,ofmsr@got(%r7)
  86         lwz     %r5,0(%r5)
  87         mtmsr   %r5
  88         isync
  89
  90         /*
  91          * Set up OF stack. This needs to be potentially accessible in real mode
  92          * The pointer to the current kernel stack is placed at the very
  93          * top of the stack along with the old MSR so we can get them back
  94          * later.
  95          */
  96         mr      %r5,%r1
  97         lwz     %r1,ofwstk@got(%r7)
  98         addi    %r1,%r1,(OFWSTKSZ-32)
  99         stw     %r5,20(%r1)     /* Save real stack pointer */
 100         stw     %r2,24(%r1)     /* Save curthread */
 101         stw     %r6,28(%r1)     /* Save old MSR */
 102         li      %r5,0
 103         stw     %r5,4(%r1)
 104         stw     %r5,0(%r1)
 105
 106         /* Finally, branch to OF */
 107         mtctr   %r4
 108         bctrl
 109
 110         /* Reload stack pointer and MSR from the OFW stack */
 111         lwz     %r6,28(%r1)
 112         lwz     %r2,24(%r1)
 113         lwz     %r1,20(%r1)
 114
 115         /* Now set the real MSR */
 116         mtmsr   %r6
 117         isync
 118
 119         /* Return */
 120         lwz     %r0,4(%r1)
 121         mtlr    %r0
 122         blr
 123
 124 /*
 125  * RTAS Entry Point. Similar to the OF one, but simpler (no separate stack)
 126  *
 127  * C prototype: int rtascall(void *callbuffer, void *rtas_privdat);
 128  */
 129
 130 ASENTRY(rtascall)
 131         mflr    %r0
 132         stw     %r0,4(%r1)
 133
 134         /* GOT pointer in r7 */
 135         bl      1f
 136 1:
 137         mflr    %r7
 138         addis   %r7,%r7,(_GLOBAL_OFFSET_TABLE_-1b)@ha
 139         addi    %r7,%r7,(_GLOBAL_OFFSET_TABLE_-1b)@l
 140
 141         /* Record the old MSR to real-mode-accessible area */
 142         mfmsr   %r0
 143         lwz     %r5,rtas_regsave@got(%r7)
 144         stw     %r0,0(%r5)
 145
 146         /* read client interface handler */
 147         lwz     %r5,rtas_entry@got(%r7)
 148         lwz     %r5,0(%r5)
 149
 150         /* Set the MSR to the RTAS value */
 151         lwz     %r6,rtasmsr@got(%r7)
 152         lwz     %r6,0(%r6)
 153         mtmsr   %r6
 154         isync
 155
 156         /* Branch to RTAS */
 157         mtctr   %r5
 158         bctrl
 159
 160         /* GOT pointer in r7 */
 161         bl      1f
 162 1:
 163         mflr    %r7
 164         addis   %r7,%r7,(_GLOBAL_OFFSET_TABLE_-1b)@ha
 165         addi    %r7,%r7,(_GLOBAL_OFFSET_TABLE_-1b)@l
 166
 167         /* Now set the MSR back */
 168         lwz     %r6,rtas_regsave@got(%r7)
 169         lwz     %r6,0(%r6)
 170         mtmsr   %r6
 171         isync
 172
 173         /* And return */
 174         lwz     %r0,4(%r1)
 175         mtlr    %r0
 176         blr
 177