sys/riscv/riscv/copyinout.S

   1 /*-
   2  * Copyright (c) 2015-2018 Ruslan Bukin <br@bsdpad.com>
   3  * All rights reserved.
   4  *
   5  * Portions of this software were developed by SRI International and the
   6  * University of Cambridge Computer Laboratory under DARPA/AFRL contract
   7  * FA8750-10-C-0237 ("CTSRD"), as part of the DARPA CRASH research programme.
   8  *
   9  * Portions of this software were developed by the University of Cambridge
  10  * Computer Laboratory as part of the CTSRD Project, with support from the
  11  * UK Higher Education Innovation Fund (HEIF).
  12  *
  13  * Redistribution and use in source and binary forms, with or without
  14  * modification, are permitted provided that the following conditions
  15  * are met:
  16  * 1. Redistributions of source code must retain the above copyright
  17  *    notice, this list of conditions and the following disclaimer.
  18  * 2. Redistributions in binary form must reproduce the above copyright
  19  *    notice, this list of conditions and the following disclaimer in the
  20  *    documentation and/or other materials provided with the distribution.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/asm.h>
  36 __FBSDID("$FreeBSD$");
  37
  38 #include <machine/riscvreg.h>
  39 #include <sys/errno.h>
  40
  41 #include "assym.inc"
  42
  43 /*
  44  * Fault handler for the copy{in,out} functions below.
  45  */
  46 ENTRY(copyio_fault)
  47         SET_FAULT_HANDLER(x0, a1) /* Clear the handler */
  48         EXIT_USER_ACCESS(a1)
  49 copyio_fault_nopcb:
  50         li      a0, EFAULT
  51         ret
  52 END(copyio_fault)
  53
  54 /*
  55  * copycommon - common copy routine
  56  *
  57  * a0 - Source address
  58  * a1 - Destination address
  59  * a2 - Size of copy
  60  */
  61         .macro copycommon
  62         la      a6, copyio_fault /* Get the handler address */
  63         SET_FAULT_HANDLER(a6, a7) /* Set the handler */
  64         ENTER_USER_ACCESS(a7)
  65
  66 1:      lb      a4, 0(a0)       /* Load from src */
  67         addi    a0, a0, 1
  68         sb      a4, 0(a1)       /* Store in dest */
  69         addi    a1, a1, 1
  70         addi    a2, a2, -1      /* len-- */
  71         bnez    a2, 1b
  72
  73         EXIT_USER_ACCESS(a7)
  74         SET_FAULT_HANDLER(x0, a7) /* Clear the handler */
  75         .endm
  76
  77 /*
  78  * Copies from a kernel to user address
  79  *
  80  * int copyout(const void *kaddr, void *udaddr, size_t len)
  81  */
  82 ENTRY(copyout)
  83         beqz    a2, copyout_end /* If len == 0 then skip loop */
  84         add     a3, a1, a2
  85         li      a4, VM_MAXUSER_ADDRESS
  86         bgt     a3, a4, copyio_fault_nopcb
  87
  88         copycommon
  89
  90 copyout_end:
  91         li      a0, 0           /* return 0 */
  92         ret
  93 END(copyout)
  94
  95 /*
  96  * Copies from a user to kernel address
  97  *
  98  * int copyin(const void *uaddr, void *kaddr, size_t len)
  99  */
 100 ENTRY(copyin)
 101         beqz    a2, copyin_end  /* If len == 0 then skip loop */
 102         add     a3, a0, a2
 103         li      a4, VM_MAXUSER_ADDRESS
 104         bgt     a3, a4, copyio_fault_nopcb
 105
 106         copycommon
 107
 108 copyin_end:
 109         li      a0, 0           /* return 0 */
 110         ret
 111 END(copyin)
 112
 113 /*
 114  * Copies a string from a user to kernel address
 115  *
 116  * int copyinstr(const void *udaddr, void *kaddr, size_t len, size_t *done)
 117  */
 118 ENTRY(copyinstr)
 119         mv      a5, x0          /* count = 0 */
 120         beqz    a2, 3f          /* If len == 0 then skip loop */
 121
 122         la      a6, copyio_fault /* Get the handler address */
 123         SET_FAULT_HANDLER(a6, a7) /* Set the handler */
 124         ENTER_USER_ACCESS(a7)
 125
 126         li      a7, VM_MAXUSER_ADDRESS
 127 1:      bgt     a0, a7, copyio_fault
 128         lb      a4, 0(a0)       /* Load from uaddr */
 129         addi    a0, a0, 1
 130         sb      a4, 0(a1)       /* Store in kaddr */
 131         addi    a1, a1, 1
 132         beqz    a4, 2f
 133         addi    a2, a2, -1      /* len-- */
 134         addi    a5, a5, 1       /* count++ */
 135         bnez    a2, 1b
 136
 137 2:      EXIT_USER_ACCESS(a7)
 138         SET_FAULT_HANDLER(x0, a7) /* Clear the handler */
 139
 140 3:      beqz    a3, 4f          /* Check if done != NULL */
 141         addi    a5, a5, 1       /* count++ */
 142         sd      a5, 0(a3)       /* done = count */
 143
 144 4:      mv      a0, x0          /* return 0 */
 145         beqz    a4, 5f
 146         li      a0, ENAMETOOLONG
 147 5:
 148         ret
 149 END(copyinstr)