usr.sbin/config/lang.l

   1 %{
   2 /*-
   3  * Copyright (c) 1980, 1993
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  * 4. Neither the name of the University nor the names of its contributors
  15  *    may be used to endorse or promote products derived from this software
  16  *    without specific prior written permission.
  17  *
  18  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  19  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  22  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  24  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  25  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  26  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  27  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  28  * SUCH DAMAGE.
  29  *
  30  *      @(#)lang.l      8.1 (Berkeley) 6/6/93
  31  * $FreeBSD$
  32  */
  33
  34 #include <assert.h>
  35 #include <ctype.h>
  36 #include <err.h>
  37 #include <stdlib.h>
  38 #include <string.h>
  39 #include "y.tab.h"
  40 #include "config.h"
  41
  42 /*
  43  * Data for returning to previous files from include files.
  44  */
  45 struct incl {
  46         struct  incl *in_prev;  /* previous includes in effect, if any */
  47         YY_BUFFER_STATE in_buf; /* previous lex state */
  48         const   char *in_fname; /* previous file name */
  49         int     in_lineno;      /* previous line number */
  50         int     in_ateof;       /* token to insert at EOF */
  51 };
  52 static struct   incl *inclp;
  53 static const    char *lastfile;
  54
  55 /*
  56  * Key word table
  57  */
  58
  59 struct kt {
  60         const char *kt_name;
  61         int kt_val;
  62 } key_words[] = {
  63         { "config",     CONFIG },
  64         { "cpu",        CPU },
  65         { "nocpu",      NOCPU },
  66         { "device",     DEVICE },
  67         { "devices",    DEVICE },
  68         { "nodevice",   NODEVICE },
  69         { "nodevices",  NODEVICE },
  70         { "env",        ENV },
  71         { "envvar",     ENVVAR },
  72         { "hints",      HINTS },
  73         { "ident",      IDENT },
  74         { "machine",    ARCH }, /* MACHINE is defined in /sys/param.h */
  75         { "makeoption", MAKEOPTIONS },
  76         { "makeoptions", MAKEOPTIONS },
  77         { "nomakeoption", NOMAKEOPTION },
  78         { "nomakeoptions", NOMAKEOPTION },
  79         { "maxusers",   MAXUSERS },
  80         { "profile",    PROFILE },
  81         { "option",     OPTIONS },
  82         { "options",    OPTIONS },
  83         { "nooption",   NOOPTION },
  84         { "nooptions",  NOOPTION },
  85         { "include",    INCLUDE },
  86         { "files",      FILES },
  87         { 0, 0 },
  88 };
  89
  90
  91 static int endinclude(void);
  92 int include(const char *, int);
  93 int kw_lookup(char *);
  94 unsigned int octal(const char *);
  95 unsigned int hex(const char *);
  96 int yyerror(const char *);
  97
  98 #define YY_DECL int yylex(void)
  99 %}
 100
 101 %option nounput
 102 %option noinput
 103
 104 ID      [A-Za-z_][-A-Za-z_0-9]*
 105 PATH    [./][-/.%^A-Za-z_0-9]+
 106 %START TOEOL
 107 %START ENVC
 108 %%
 109 <ENVC>[^#\n]*   {
 110                         BEGIN 0;
 111                         yylval.str = strdup(yytext);
 112                         return ENVLINE;
 113                 }
 114 {ID}            {
 115                         int i;
 116
 117                         BEGIN 0;
 118                         if ((i = kw_lookup(yytext)) == -1)
 119                         {
 120                                 yylval.str = strdup(yytext);
 121                                 return ID;
 122                         }
 123                         /* We'll glom onto the rest of an envvar line */
 124                         if (i == ENVVAR)
 125                                 BEGIN ENVC;
 126                         return i;
 127                 }
 128 \\\"[^"]*\\\"   {
 129                         BEGIN 0;
 130                         yytext[yyleng-2] = '"';
 131                         yytext[yyleng-1] = '\0';
 132                         yylval.str = strdup(yytext + 1);
 133                         return ID;
 134                 }
 135 \"[^"]+\"       {
 136                         BEGIN 0;
 137                         yytext[yyleng-1] = '\0';
 138                         yylval.str = strdup(yytext + 1);
 139                         return ID;
 140                 }
 141 <TOEOL>[^# \t\n]*       {
 142                         BEGIN 0;
 143                         yylval.str = strdup(yytext);
 144                         return ID;
 145                 }
 146 0[0-7]*         {
 147                         yylval.val = octal(yytext);
 148                         return NUMBER;
 149                 }
 150 0x[0-9a-fA-F]+  {
 151                         yylval.val = hex(yytext);
 152                         return NUMBER;
 153                 }
 154 -?[1-9][0-9]*   {
 155                         yylval.val = atoi(yytext);
 156                         return NUMBER;
 157                 }
 158 "?"             {
 159                         yylval.val = -1;
 160                         return NUMBER;
 161                 }
 162 \n/[ \t]        {
 163                         yyline++;
 164                 }
 165 \n              {
 166                         yyline++;
 167                         return SEMICOLON;
 168                 }
 169 #.*             {       /* Ignored (comment) */;        }
 170 [ \t\f]*        {       /* Ignored (white space) */;    }
 171 ";"             {       return SEMICOLON;               }
 172 ","             {       return COMMA;                   }
 173 "="             {       BEGIN TOEOL; return EQUALS;     }
 174 "+="            {       BEGIN TOEOL; return PLUSEQUALS; }
 175 <<EOF>>         {
 176                         int tok;
 177
 178                         if (inclp == NULL)
 179                                 return YY_NULL;
 180                         tok = endinclude();
 181                         if (tok != 0)
 182                                 return tok;
 183                         /* otherwise continue scanning */
 184                 }
 185 {PATH}          {
 186                         BEGIN 0;
 187                         yylval.str = strdup(yytext);
 188                         return PATH;
 189                 }
 190 .               {       return yytext[0];               }
 191
 192 %%
 193 /*
 194  * kw_lookup
 195  *      Look up a string in the keyword table.  Returns a -1 if the
 196  *      string is not a keyword otherwise it returns the keyword number
 197  */
 198
 199 int
 200 kw_lookup(char *word)
 201 {
 202         struct kt *kp;
 203
 204         for (kp = key_words; kp->kt_name != 0; kp++)
 205                 if (eq(word, kp->kt_name))
 206                         return kp->kt_val;
 207         return -1;
 208 }
 209
 210 /*
 211  * Number conversion routines
 212  */
 213
 214 unsigned int
 215 octal(const char *str)
 216 {
 217         unsigned int num;
 218
 219         (void) sscanf(str, "%o", &num);
 220         return num;
 221 }
 222
 223 unsigned int
 224 hex(const char *str)
 225 {
 226         unsigned int num;
 227
 228         (void) sscanf(str+2, "%x", &num);
 229         return num;
 230 }
 231
 232 void
 233 cfgfile_add(const char *fname)
 234 {
 235         struct cfgfile *cf;
 236
 237         cf = calloc(1, sizeof(*cf));
 238         if (cf == NULL)
 239                 err(EXIT_FAILURE, "calloc");
 240         assert(cf != NULL);
 241         asprintf(&cf->cfg_path, "%s", fname);
 242         STAILQ_INSERT_TAIL(&cfgfiles, cf, cfg_next);
 243 }
 244
 245 void
 246 cfgfile_removeall(void)
 247 {
 248         struct cfgfile *cf;
 249
 250         while (!STAILQ_EMPTY(&cfgfiles)) {
 251                 cf = STAILQ_FIRST(&cfgfiles);
 252                 STAILQ_REMOVE_HEAD(&cfgfiles, cfg_next);
 253                 if (cf->cfg_path != NULL)
 254                         free(cf->cfg_path);
 255                 free(cf);
 256         }
 257 }
 258
 259 /*
 260  * Open the named file for inclusion at the current point.  Returns 0 on
 261  * success (file opened and previous state pushed), nonzero on failure
 262  * (fopen failed, complaint made).  The `ateof' parameter controls the
 263  * token to be inserted at the end of the include file. If ateof == 0,
 264  * then nothing is inserted.
 265  */
 266 int
 267 include(const char *fname, int ateof)
 268 {
 269         FILE *fp;
 270         struct incl *in;
 271         struct includepath* ipath;
 272         char *fnamebuf;
 273
 274         fnamebuf = NULL;
 275         fp = fopen(fname, "r");
 276         if (fp == NULL && fname[0] != '.' && fname[0] != '/') {
 277                 asprintf(&fnamebuf, "../../conf/%s", fname);
 278                 if (fnamebuf != NULL) {
 279                         fp = fopen(fnamebuf, "r");
 280                         if (fp == NULL)
 281                                 free(fnamebuf);
 282                 }
 283         }
 284         if (fp == NULL) {
 285                 SLIST_FOREACH(ipath, &includepath, path_next) {
 286                         asprintf(&fnamebuf, "%s/%s", ipath->path, fname);
 287                         if (fnamebuf != NULL) {
 288                                 fp = fopen(fnamebuf, "r");
 289                         }
 290                         if (fp != NULL)
 291                                 break;
 292                         free(fnamebuf);
 293                 }
 294         }
 295         if (fp == NULL) {
 296                 yyerror("cannot open included file");
 297                 return (-1);
 298         }
 299         cfgfile_add(fnamebuf == NULL ? fname : fnamebuf);
 300         in = malloc(sizeof(*in));
 301         assert(in != NULL);
 302         in->in_prev = inclp;
 303         in->in_buf = YY_CURRENT_BUFFER;
 304         in->in_fname = yyfile;
 305         in->in_lineno = yyline;
 306         in->in_ateof = ateof;
 307         inclp = in;
 308         yy_switch_to_buffer(yy_create_buffer(fp, YY_BUF_SIZE));
 309         yyfile = fname;
 310         yyline = 0;
 311         return (0);
 312 }
 313
 314 /*
 315  * Terminate the most recent inclusion.
 316  */
 317 static int
 318 endinclude(void)
 319 {
 320         struct incl *in;
 321         int ateof;
 322
 323         in = inclp;
 324         assert(in != NULL);
 325         inclp = in->in_prev;
 326         lastfile = yyfile;
 327         yy_delete_buffer(YY_CURRENT_BUFFER);
 328         (void)fclose(yyin);
 329         yy_switch_to_buffer(in->in_buf);
 330         yyfile = in->in_fname;
 331         yyline = in->in_lineno;
 332         ateof  = in->in_ateof;
 333         free(in);
 334
 335         return (ateof);
 336 }