usr.sbin/config/lang.l

   1 %{
   2 /*-
   3  * Copyright (c) 1980, 1993
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  * 3. All advertising materials mentioning features or use of this software
  15  *    must display the following acknowledgement:
  16  *      This product includes software developed by the University of
  17  *      California, Berkeley and its contributors.
  18  * 4. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  *      @(#)lang.l      8.1 (Berkeley) 6/6/93
  35  * $FreeBSD$
  36  */
  37
  38 #include <assert.h>
  39 #include <ctype.h>
  40 #include <string.h>
  41 #include "y.tab.h"
  42 #include "config.h"
  43
  44 #define YY_NO_UNPUT
  45
  46 /*
  47  * Data for returning to previous files from include files.
  48  */
  49 struct incl {
  50         struct  incl *in_prev;  /* previous includes in effect, if any */
  51         YY_BUFFER_STATE in_buf; /* previous lex state */
  52         const   char *in_fname; /* previous file name */
  53         int     in_lineno;      /* previous line number */
  54         int     in_ateof;       /* token to insert at EOF */
  55 };
  56 static struct   incl *inclp;
  57 static const    char *lastfile;
  58
  59 /*
  60  * Key word table
  61  */
  62
  63 struct kt {
  64         const char *kt_name;
  65         int kt_val;
  66 } key_words[] = {
  67         { "config",     CONFIG },
  68         { "cpu",        CPU },
  69         { "device",     DEVICE },
  70         { "env",        ENV },
  71         { "hints",      HINTS },
  72         { "ident",      IDENT },
  73         { "machine",    ARCH }, /* MACHINE is defined in /sys/param.h */
  74         { "makeoptions", MAKEOPTIONS },
  75         { "maxusers",   MAXUSERS },
  76         { "profile",    PROFILE },
  77         { "option",     OPTIONS },
  78         { "options",    OPTIONS },
  79         { "include",    INCLUDE },
  80         { 0, 0 },
  81 };
  82
  83
  84 static int endinclude(void);
  85 int include(const char *, int);
  86 int kw_lookup(char *);
  87 int octal(char *);
  88 int hex(char *);
  89 int yyerror(const char *);
  90
  91 %}
  92 WORD    [A-Za-z_][-A-Za-z_]*
  93 ID      [A-Za-z_][-A-Za-z_0-9]*
  94 %START NONUM TOEOL
  95 %%
  96 <NONUM>{WORD}   {
  97                         int i;
  98
  99                         BEGIN 0;
 100                         if ((i = kw_lookup(yytext)) == -1)
 101                         {
 102                                 yylval.str = strdup(yytext);
 103                                 return ID;
 104                         }
 105                         return i;
 106                 }
 107 <INITIAL>{WORD}/[0-9]* {
 108                         int i;
 109
 110                         if ((i = kw_lookup(yytext)) == -1)
 111                                 REJECT;
 112                         if (i == DEVICE)
 113                                 BEGIN NONUM;
 114                         return i;
 115                 }
 116 <INITIAL>{ID}   {
 117                         BEGIN 0;
 118                         yylval.str = strdup(yytext);
 119                         return ID;
 120                 }
 121 \\\"[^"]+\\\"   {
 122                         BEGIN 0;
 123                         yytext[yyleng-2] = '"';
 124                         yytext[yyleng-1] = '\0';
 125                         yylval.str = strdup(yytext + 1);
 126                         return ID;
 127                 }
 128 \"[^"]+\"       {
 129                         BEGIN 0;
 130                         yytext[yyleng-1] = '\0';
 131                         yylval.str = strdup(yytext + 1);
 132                         return ID;
 133                 }
 134 <TOEOL>[^# \t\n]*       {
 135                         BEGIN 0;
 136                         yylval.str = strdup(yytext);
 137                         return ID;
 138                 }
 139 0[0-7]*         {
 140                         yylval.val = octal(yytext);
 141                         return NUMBER;
 142                 }
 143 0x[0-9a-fA-F]+  {
 144                         yylval.val = hex(yytext);
 145                         return NUMBER;
 146                 }
 147 -?[1-9][0-9]*   {
 148                         yylval.val = atoi(yytext);
 149                         return NUMBER;
 150                 }
 151 "?"             {
 152                         yylval.val = -1;
 153                         return NUMBER;
 154                 }
 155 \n/[ \t]        {
 156                         yyline++;
 157                 }
 158 \n              {
 159                         yyline++;
 160                         return SEMICOLON;
 161                 }
 162 #.*             {       /* Ignored (comment) */;        }
 163 [ \t\f]*        {       /* Ignored (white space) */;    }
 164 ";"             {       return SEMICOLON;               }
 165 ","             {       return COMMA;                   }
 166 "="             {       BEGIN TOEOL; return EQUALS;     }
 167 <<EOF>>         {
 168                         int tok;
 169
 170                         if (inclp == NULL)
 171                                 return YY_NULL;
 172                         tok = endinclude();
 173                         if (tok != 0)
 174                                 return tok;
 175                         /* otherwise continue scanning */
 176                 }
 177 .               {       return yytext[0];               }
 178
 179 %%
 180 /*
 181  * kw_lookup
 182  *      Look up a string in the keyword table.  Returns a -1 if the
 183  *      string is not a keyword otherwise it returns the keyword number
 184  */
 185
 186 int
 187 kw_lookup(char *word)
 188 {
 189         struct kt *kp;
 190
 191         for (kp = key_words; kp->kt_name != 0; kp++)
 192                 if (eq(word, kp->kt_name))
 193                         return kp->kt_val;
 194         return -1;
 195 }
 196
 197 /*
 198  * Number conversion routines
 199  */
 200
 201 int
 202 octal(char *str)
 203 {
 204         int num;
 205
 206         (void) sscanf(str, "%o", &num);
 207         return num;
 208 }
 209
 210 int
 211 hex(char *str)
 212 {
 213         int num;
 214
 215         (void) sscanf(str+2, "%x", &num);
 216         return num;
 217 }
 218
 219
 220 /*
 221  * Open the named file for inclusion at the current point.  Returns 0 on
 222  * success (file opened and previous state pushed), nonzero on failure
 223  * (fopen failed, complaint made).  The `ateof' parameter controls the
 224  * token to be inserted at the end of the include file. If ateof == 0,
 225  * then nothing is inserted.
 226  */
 227 int
 228 include(const char *fname, int ateof)
 229 {
 230         FILE *fp;
 231         struct incl *in;
 232
 233         fp = fopen(fname, "r");
 234         if (fp == NULL) {
 235                 yyerror("cannot open file");
 236                 return (-1);
 237         }
 238         in = malloc(sizeof(*in));
 239         assert(in != NULL);
 240         in->in_prev = inclp;
 241         in->in_buf = YY_CURRENT_BUFFER;
 242         in->in_fname = yyfile;
 243         in->in_lineno = yyline;
 244         in->in_ateof = ateof;
 245         inclp = in;
 246         yy_switch_to_buffer(yy_create_buffer(fp, YY_BUF_SIZE));
 247         yyfile = fname;
 248         yyline = 0;
 249         return (0);
 250 }
 251
 252 /*
 253  * Terminate the most recent inclusion.
 254  */
 255 static int
 256 endinclude()
 257 {
 258         struct incl *in;
 259         int ateof;
 260
 261         in = inclp;
 262         assert(in != NULL);
 263         inclp = in->in_prev;
 264         lastfile = yyfile;
 265         yy_delete_buffer(YY_CURRENT_BUFFER);
 266         (void)fclose(yyin);
 267         yy_switch_to_buffer(in->in_buf);
 268         yyfile = in->in_fname;
 269         yyline = in->in_lineno;
 270         ateof  = in->in_ateof;
 271         free(in);
 272
 273         return (ateof);
 274 }