usr.sbin/ctld/parse.y

   1 %{
   2 /*-
   3  * Copyright (c) 2012 The FreeBSD Foundation
   4  * All rights reserved.
   5  *
   6  * This software was developed by Edward Tomasz Napierala under sponsorship
   7  * from the FreeBSD Foundation.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  *
  18  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  19  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  22  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  24  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  25  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  26  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  27  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  28  * SUCH DAMAGE.
  29  *
  30  * $FreeBSD$
  31  */
  32
  33 #include <sys/queue.h>
  34 #include <sys/types.h>
  35 #include <sys/stat.h>
  36 #include <assert.h>
  37 #include <stdio.h>
  38 #include <stdint.h>
  39 #include <stdlib.h>
  40 #include <string.h>
  41
  42 #include "ctld.h"
  43
  44 extern FILE *yyin;
  45 extern char *yytext;
  46 extern int lineno;
  47
  48 static struct conf *conf = NULL;
  49 static struct auth_group *auth_group = NULL;
  50 static struct portal_group *portal_group = NULL;
  51 static struct target *target = NULL;
  52 static struct lun *lun = NULL;
  53
  54 extern void     yyerror(const char *);
  55 extern int      yylex(void);
  56 extern void     yyrestart(FILE *);
  57
  58 %}
  59
  60 %token ALIAS AUTH_GROUP AUTH_TYPE BACKEND BLOCKSIZE CHAP CHAP_MUTUAL
  61 %token CLOSING_BRACKET DEBUG DEVICE_ID DISCOVERY_AUTH_GROUP DISCOVERY_FILTER
  62 %token INITIATOR_NAME INITIATOR_PORTAL ISNS_SERVER ISNS_PERIOD ISNS_TIMEOUT
  63 %token LISTEN LISTEN_ISER LUN MAXPROC OFFLOAD OPENING_BRACKET OPTION
  64 %token PATH PIDFILE PORTAL_GROUP REDIRECT SEMICOLON SERIAL SIZE STR
  65 %token TARGET TIMEOUT
  66
  67 %union
  68 {
  69         char *str;
  70 }
  71
  72 %token <str> STR
  73
  74 %%
  75
  76 statements:
  77         |
  78         statements statement
  79         |
  80         statements statement SEMICOLON
  81         ;
  82
  83 statement:
  84         debug
  85         |
  86         timeout
  87         |
  88         maxproc
  89         |
  90         pidfile
  91         |
  92         isns_server
  93         |
  94         isns_period
  95         |
  96         isns_timeout
  97         |
  98         auth_group
  99         |
 100         portal_group
 101         |
 102         lun
 103         |
 104         target
 105         ;
 106
 107 debug:          DEBUG STR
 108         {
 109                 uint64_t tmp;
 110
 111                 if (expand_number($2, &tmp) != 0) {
 112                         yyerror("invalid numeric value");
 113                         free($2);
 114                         return (1);
 115                 }
 116
 117                 conf->conf_debug = tmp;
 118         }
 119         ;
 120
 121 timeout:        TIMEOUT STR
 122         {
 123                 uint64_t tmp;
 124
 125                 if (expand_number($2, &tmp) != 0) {
 126                         yyerror("invalid numeric value");
 127                         free($2);
 128                         return (1);
 129                 }
 130
 131                 conf->conf_timeout = tmp;
 132         }
 133         ;
 134
 135 maxproc:        MAXPROC STR
 136         {
 137                 uint64_t tmp;
 138
 139                 if (expand_number($2, &tmp) != 0) {
 140                         yyerror("invalid numeric value");
 141                         free($2);
 142                         return (1);
 143                 }
 144
 145                 conf->conf_maxproc = tmp;
 146         }
 147         ;
 148
 149 pidfile:        PIDFILE STR
 150         {
 151                 if (conf->conf_pidfile_path != NULL) {
 152                         log_warnx("pidfile specified more than once");
 153                         free($2);
 154                         return (1);
 155                 }
 156                 conf->conf_pidfile_path = $2;
 157         }
 158         ;
 159
 160 isns_server:    ISNS_SERVER STR
 161         {
 162                 int error;
 163
 164                 error = isns_new(conf, $2);
 165                 free($2);
 166                 if (error != 0)
 167                         return (1);
 168         }
 169         ;
 170
 171 isns_period:    ISNS_PERIOD STR
 172         {
 173                 uint64_t tmp;
 174
 175                 if (expand_number($2, &tmp) != 0) {
 176                         yyerror("invalid numeric value");
 177                         free($2);
 178                         return (1);
 179                 }
 180
 181                 conf->conf_isns_period = tmp;
 182         }
 183         ;
 184
 185 isns_timeout:   ISNS_TIMEOUT STR
 186         {
 187                 uint64_t tmp;
 188
 189                 if (expand_number($2, &tmp) != 0) {
 190                         yyerror("invalid numeric value");
 191                         free($2);
 192                         return (1);
 193                 }
 194
 195                 conf->conf_isns_timeout = tmp;
 196         }
 197         ;
 198
 199 auth_group:     AUTH_GROUP auth_group_name
 200     OPENING_BRACKET auth_group_entries CLOSING_BRACKET
 201         {
 202                 auth_group = NULL;
 203         }
 204         ;
 205
 206 auth_group_name:        STR
 207         {
 208                 /*
 209                  * Make it possible to redefine default
 210                  * auth-group. but only once.
 211                  */
 212                 if (strcmp($1, "default") == 0 &&
 213                     conf->conf_default_ag_defined == false) {
 214                         auth_group = auth_group_find(conf, $1);
 215                         conf->conf_default_ag_defined = true;
 216                 } else {
 217                         auth_group = auth_group_new(conf, $1);
 218                 }
 219                 free($1);
 220                 if (auth_group == NULL)
 221                         return (1);
 222         }
 223         ;
 224
 225 auth_group_entries:
 226         |
 227         auth_group_entries auth_group_entry
 228         |
 229         auth_group_entries auth_group_entry SEMICOLON
 230         ;
 231
 232 auth_group_entry:
 233         auth_group_auth_type
 234         |
 235         auth_group_chap
 236         |
 237         auth_group_chap_mutual
 238         |
 239         auth_group_initiator_name
 240         |
 241         auth_group_initiator_portal
 242         ;
 243
 244 auth_group_auth_type:   AUTH_TYPE STR
 245         {
 246                 int error;
 247
 248                 error = auth_group_set_type(auth_group, $2);
 249                 free($2);
 250                 if (error != 0)
 251                         return (1);
 252         }
 253         ;
 254
 255 auth_group_chap:        CHAP STR STR
 256         {
 257                 const struct auth *ca;
 258
 259                 ca = auth_new_chap(auth_group, $2, $3);
 260                 free($2);
 261                 free($3);
 262                 if (ca == NULL)
 263                         return (1);
 264         }
 265         ;
 266
 267 auth_group_chap_mutual: CHAP_MUTUAL STR STR STR STR
 268         {
 269                 const struct auth *ca;
 270
 271                 ca = auth_new_chap_mutual(auth_group, $2, $3, $4, $5);
 272                 free($2);
 273                 free($3);
 274                 free($4);
 275                 free($5);
 276                 if (ca == NULL)
 277                         return (1);
 278         }
 279         ;
 280
 281 auth_group_initiator_name:      INITIATOR_NAME STR
 282         {
 283                 const struct auth_name *an;
 284
 285                 an = auth_name_new(auth_group, $2);
 286                 free($2);
 287                 if (an == NULL)
 288                         return (1);
 289         }
 290         ;
 291
 292 auth_group_initiator_portal:    INITIATOR_PORTAL STR
 293         {
 294                 const struct auth_portal *ap;
 295
 296                 ap = auth_portal_new(auth_group, $2);
 297                 free($2);
 298                 if (ap == NULL)
 299                         return (1);
 300         }
 301         ;
 302
 303 portal_group:   PORTAL_GROUP portal_group_name
 304     OPENING_BRACKET portal_group_entries CLOSING_BRACKET
 305         {
 306                 portal_group = NULL;
 307         }
 308         ;
 309
 310 portal_group_name:      STR
 311         {
 312                 /*
 313                  * Make it possible to redefine default
 314                  * portal-group. but only once.
 315                  */
 316                 if (strcmp($1, "default") == 0 &&
 317                     conf->conf_default_pg_defined == false) {
 318                         portal_group = portal_group_find(conf, $1);
 319                         conf->conf_default_pg_defined = true;
 320                 } else {
 321                         portal_group = portal_group_new(conf, $1);
 322                 }
 323                 free($1);
 324                 if (portal_group == NULL)
 325                         return (1);
 326         }
 327         ;
 328
 329 portal_group_entries:
 330         |
 331         portal_group_entries portal_group_entry
 332         |
 333         portal_group_entries portal_group_entry SEMICOLON
 334         ;
 335
 336 portal_group_entry:
 337         portal_group_discovery_auth_group
 338         |
 339         portal_group_discovery_filter
 340         |
 341         portal_group_listen
 342         |
 343         portal_group_listen_iser
 344         |
 345         portal_group_redirect
 346         ;
 347
 348 portal_group_discovery_auth_group:      DISCOVERY_AUTH_GROUP STR
 349         {
 350                 if (portal_group->pg_discovery_auth_group != NULL) {
 351                         log_warnx("discovery-auth-group for portal-group "
 352                             "\"%s\" specified more than once",
 353                             portal_group->pg_name);
 354                         return (1);
 355                 }
 356                 portal_group->pg_discovery_auth_group =
 357                     auth_group_find(conf, $2);
 358                 if (portal_group->pg_discovery_auth_group == NULL) {
 359                         log_warnx("unknown discovery-auth-group \"%s\" "
 360                             "for portal-group \"%s\"",
 361                             $2, portal_group->pg_name);
 362                         return (1);
 363                 }
 364                 free($2);
 365         }
 366         ;
 367
 368 portal_group_discovery_filter:  DISCOVERY_FILTER STR
 369         {
 370                 int error;
 371
 372                 error = portal_group_set_filter(portal_group, $2);
 373                 free($2);
 374                 if (error != 0)
 375                         return (1);
 376         }
 377         ;
 378
 379 portal_group_listen:    LISTEN STR
 380         {
 381                 int error;
 382
 383                 error = portal_group_add_listen(portal_group, $2, false);
 384                 free($2);
 385                 if (error != 0)
 386                         return (1);
 387         }
 388         ;
 389
 390 portal_group_listen_iser:       LISTEN_ISER STR
 391         {
 392                 int error;
 393
 394                 error = portal_group_add_listen(portal_group, $2, true);
 395                 free($2);
 396                 if (error != 0)
 397                         return (1);
 398         }
 399         ;
 400
 401 portal_group_redirect:  REDIRECT STR
 402         {
 403                 int error;
 404
 405                 error = portal_group_set_redirection(portal_group, $2);
 406                 free($2);
 407                 if (error != 0)
 408                         return (1);
 409         }
 410         ;
 411
 412 lun:    LUN lun_name
 413     OPENING_BRACKET lun_entries CLOSING_BRACKET
 414         {
 415                 lun = NULL;
 416         }
 417         ;
 418
 419 lun_name:       STR
 420         {
 421                 lun = lun_new(conf, $1);
 422                 free($1);
 423                 if (lun == NULL)
 424                         return (1);
 425         }
 426         ;
 427
 428 target: TARGET target_name
 429     OPENING_BRACKET target_entries CLOSING_BRACKET
 430         {
 431                 target = NULL;
 432         }
 433         ;
 434
 435 target_name:    STR
 436         {
 437                 target = target_new(conf, $1);
 438                 free($1);
 439                 if (target == NULL)
 440                         return (1);
 441         }
 442         ;
 443
 444 target_entries:
 445         |
 446         target_entries target_entry
 447         |
 448         target_entries target_entry SEMICOLON
 449         ;
 450
 451 target_entry:
 452         target_alias
 453         |
 454         target_auth_group
 455         |
 456         target_auth_type
 457         |
 458         target_chap
 459         |
 460         target_chap_mutual
 461         |
 462         target_initiator_name
 463         |
 464         target_initiator_portal
 465         |
 466         target_offload
 467         |
 468         target_portal_group
 469         |
 470         target_redirect
 471         |
 472         target_lun
 473         |
 474         target_lun_ref
 475         ;
 476
 477 target_alias:   ALIAS STR
 478         {
 479                 if (target->t_alias != NULL) {
 480                         log_warnx("alias for target \"%s\" "
 481                             "specified more than once", target->t_name);
 482                         return (1);
 483                 }
 484                 target->t_alias = $2;
 485         }
 486         ;
 487
 488 target_auth_group:      AUTH_GROUP STR
 489         {
 490                 if (target->t_auth_group != NULL) {
 491                         if (target->t_auth_group->ag_name != NULL)
 492                                 log_warnx("auth-group for target \"%s\" "
 493                                     "specified more than once", target->t_name);
 494                         else
 495                                 log_warnx("cannot use both auth-group and explicit "
 496                                     "authorisations for target \"%s\"",
 497                                     target->t_name);
 498                         return (1);
 499                 }
 500                 target->t_auth_group = auth_group_find(conf, $2);
 501                 if (target->t_auth_group == NULL) {
 502                         log_warnx("unknown auth-group \"%s\" for target "
 503                             "\"%s\"", $2, target->t_name);
 504                         return (1);
 505                 }
 506                 free($2);
 507         }
 508         ;
 509
 510 target_auth_type:       AUTH_TYPE STR
 511         {
 512                 int error;
 513
 514                 if (target->t_auth_group != NULL) {
 515                         if (target->t_auth_group->ag_name != NULL) {
 516                                 log_warnx("cannot use both auth-group and "
 517                                     "auth-type for target \"%s\"",
 518                                     target->t_name);
 519                                 return (1);
 520                         }
 521                 } else {
 522                         target->t_auth_group = auth_group_new(conf, NULL);
 523                         if (target->t_auth_group == NULL) {
 524                                 free($2);
 525                                 return (1);
 526                         }
 527                         target->t_auth_group->ag_target = target;
 528                 }
 529                 error = auth_group_set_type(target->t_auth_group, $2);
 530                 free($2);
 531                 if (error != 0)
 532                         return (1);
 533         }
 534         ;
 535
 536 target_chap:    CHAP STR STR
 537         {
 538                 const struct auth *ca;
 539
 540                 if (target->t_auth_group != NULL) {
 541                         if (target->t_auth_group->ag_name != NULL) {
 542                                 log_warnx("cannot use both auth-group and "
 543                                     "chap for target \"%s\"",
 544                                     target->t_name);
 545                                 free($2);
 546                                 free($3);
 547                                 return (1);
 548                         }
 549                 } else {
 550                         target->t_auth_group = auth_group_new(conf, NULL);
 551                         if (target->t_auth_group == NULL) {
 552                                 free($2);
 553                                 free($3);
 554                                 return (1);
 555                         }
 556                         target->t_auth_group->ag_target = target;
 557                 }
 558                 ca = auth_new_chap(target->t_auth_group, $2, $3);
 559                 free($2);
 560                 free($3);
 561                 if (ca == NULL)
 562                         return (1);
 563         }
 564         ;
 565
 566 target_chap_mutual:     CHAP_MUTUAL STR STR STR STR
 567         {
 568                 const struct auth *ca;
 569
 570                 if (target->t_auth_group != NULL) {
 571                         if (target->t_auth_group->ag_name != NULL) {
 572                                 log_warnx("cannot use both auth-group and "
 573                                     "chap-mutual for target \"%s\"",
 574                                     target->t_name);
 575                                 free($2);
 576                                 free($3);
 577                                 free($4);
 578                                 free($5);
 579                                 return (1);
 580                         }
 581                 } else {
 582                         target->t_auth_group = auth_group_new(conf, NULL);
 583                         if (target->t_auth_group == NULL) {
 584                                 free($2);
 585                                 free($3);
 586                                 free($4);
 587                                 free($5);
 588                                 return (1);
 589                         }
 590                         target->t_auth_group->ag_target = target;
 591                 }
 592                 ca = auth_new_chap_mutual(target->t_auth_group,
 593                     $2, $3, $4, $5);
 594                 free($2);
 595                 free($3);
 596                 free($4);
 597                 free($5);
 598                 if (ca == NULL)
 599                         return (1);
 600         }
 601         ;
 602
 603 target_initiator_name:  INITIATOR_NAME STR
 604         {
 605                 const struct auth_name *an;
 606
 607                 if (target->t_auth_group != NULL) {
 608                         if (target->t_auth_group->ag_name != NULL) {
 609                                 log_warnx("cannot use both auth-group and "
 610                                     "initiator-name for target \"%s\"",
 611                                     target->t_name);
 612                                 free($2);
 613                                 return (1);
 614                         }
 615                 } else {
 616                         target->t_auth_group = auth_group_new(conf, NULL);
 617                         if (target->t_auth_group == NULL) {
 618                                 free($2);
 619                                 return (1);
 620                         }
 621                         target->t_auth_group->ag_target = target;
 622                 }
 623                 an = auth_name_new(target->t_auth_group, $2);
 624                 free($2);
 625                 if (an == NULL)
 626                         return (1);
 627         }
 628         ;
 629
 630 target_initiator_portal:        INITIATOR_PORTAL STR
 631         {
 632                 const struct auth_portal *ap;
 633
 634                 if (target->t_auth_group != NULL) {
 635                         if (target->t_auth_group->ag_name != NULL) {
 636                                 log_warnx("cannot use both auth-group and "
 637                                     "initiator-portal for target \"%s\"",
 638                                     target->t_name);
 639                                 free($2);
 640                                 return (1);
 641                         }
 642                 } else {
 643                         target->t_auth_group = auth_group_new(conf, NULL);
 644                         if (target->t_auth_group == NULL) {
 645                                 free($2);
 646                                 return (1);
 647                         }
 648                         target->t_auth_group->ag_target = target;
 649                 }
 650                 ap = auth_portal_new(target->t_auth_group, $2);
 651                 free($2);
 652                 if (ap == NULL)
 653                         return (1);
 654         }
 655         ;
 656
 657 target_offload: OFFLOAD STR
 658         {
 659                 int error;
 660
 661                 error = target_set_offload(target, $2);
 662                 free($2);
 663                 if (error != 0)
 664                         return (1);
 665         }
 666         ;
 667
 668 target_portal_group:    PORTAL_GROUP STR STR
 669         {
 670                 struct portal_group *tpg;
 671                 struct auth_group *tag;
 672                 struct port *tp;
 673
 674                 tpg = portal_group_find(conf, $2);
 675                 if (tpg == NULL) {
 676                         log_warnx("unknown portal-group \"%s\" for target "
 677                             "\"%s\"", $2, target->t_name);
 678                         free($2);
 679                         free($3);
 680                         return (1);
 681                 }
 682                 tag = auth_group_find(conf, $3);
 683                 if (tag == NULL) {
 684                         log_warnx("unknown auth-group \"%s\" for target "
 685                             "\"%s\"", $3, target->t_name);
 686                         free($2);
 687                         free($3);
 688                         return (1);
 689                 }
 690                 tp = port_new(conf, target, tpg);
 691                 if (tp == NULL) {
 692                         log_warnx("can't link portal-group \"%s\" to target "
 693                             "\"%s\"", $2, target->t_name);
 694                         free($2);
 695                         return (1);
 696                 }
 697                 tp->p_auth_group = tag;
 698                 free($2);
 699                 free($3);
 700         }
 701         |               PORTAL_GROUP STR
 702         {
 703                 struct portal_group *tpg;
 704                 struct port *tp;
 705
 706                 tpg = portal_group_find(conf, $2);
 707                 if (tpg == NULL) {
 708                         log_warnx("unknown portal-group \"%s\" for target "
 709                             "\"%s\"", $2, target->t_name);
 710                         free($2);
 711                         return (1);
 712                 }
 713                 tp = port_new(conf, target, tpg);
 714                 if (tp == NULL) {
 715                         log_warnx("can't link portal-group \"%s\" to target "
 716                             "\"%s\"", $2, target->t_name);
 717                         free($2);
 718                         return (1);
 719                 }
 720                 free($2);
 721         }
 722         ;
 723
 724 target_redirect:        REDIRECT STR
 725         {
 726                 int error;
 727
 728                 error = target_set_redirection(target, $2);
 729                 free($2);
 730                 if (error != 0)
 731                         return (1);
 732         }
 733         ;
 734
 735 target_lun:     LUN lun_number
 736     OPENING_BRACKET lun_entries CLOSING_BRACKET
 737         {
 738                 lun = NULL;
 739         }
 740         ;
 741
 742 lun_number:     STR
 743         {
 744                 uint64_t tmp;
 745                 char *name;
 746
 747                 if (expand_number($1, &tmp) != 0) {
 748                         yyerror("invalid numeric value");
 749                         free($1);
 750                         return (1);
 751                 }
 752
 753                 asprintf(&name, "%s,lun,%ju", target->t_name, tmp);
 754                 lun = lun_new(conf, name);
 755                 if (lun == NULL)
 756                         return (1);
 757
 758                 lun_set_scsiname(lun, name);
 759                 target->t_luns[tmp] = lun;
 760         }
 761         ;
 762
 763 target_lun_ref: LUN STR STR
 764         {
 765                 uint64_t tmp;
 766
 767                 if (expand_number($2, &tmp) != 0) {
 768                         yyerror("invalid numeric value");
 769                         free($2);
 770                         free($3);
 771                         return (1);
 772                 }
 773                 free($2);
 774
 775                 lun = lun_find(conf, $3);
 776                 free($3);
 777                 if (lun == NULL)
 778                         return (1);
 779
 780                 target->t_luns[tmp] = lun;
 781         }
 782         ;
 783
 784 lun_entries:
 785         |
 786         lun_entries lun_entry
 787         |
 788         lun_entries lun_entry SEMICOLON
 789         ;
 790
 791 lun_entry:
 792         lun_backend
 793         |
 794         lun_blocksize
 795         |
 796         lun_device_id
 797         |
 798         lun_option
 799         |
 800         lun_path
 801         |
 802         lun_serial
 803         |
 804         lun_size
 805         ;
 806
 807 lun_backend:    BACKEND STR
 808         {
 809                 if (lun->l_backend != NULL) {
 810                         log_warnx("backend for lun \"%s\" "
 811                             "specified more than once",
 812                             lun->l_name);
 813                         free($2);
 814                         return (1);
 815                 }
 816                 lun_set_backend(lun, $2);
 817                 free($2);
 818         }
 819         ;
 820
 821 lun_blocksize:  BLOCKSIZE STR
 822         {
 823                 uint64_t tmp;
 824
 825                 if (expand_number($2, &tmp) != 0) {
 826                         yyerror("invalid numeric value");
 827                         free($2);
 828                         return (1);
 829                 }
 830
 831                 if (lun->l_blocksize != 0) {
 832                         log_warnx("blocksize for lun \"%s\" "
 833                             "specified more than once",
 834                             lun->l_name);
 835                         return (1);
 836                 }
 837                 lun_set_blocksize(lun, tmp);
 838         }
 839         ;
 840
 841 lun_device_id:  DEVICE_ID STR
 842         {
 843                 if (lun->l_device_id != NULL) {
 844                         log_warnx("device_id for lun \"%s\" "
 845                             "specified more than once",
 846                             lun->l_name);
 847                         free($2);
 848                         return (1);
 849                 }
 850                 lun_set_device_id(lun, $2);
 851                 free($2);
 852         }
 853         ;
 854
 855 lun_option:     OPTION STR STR
 856         {
 857                 struct lun_option *clo;
 858
 859                 clo = lun_option_new(lun, $2, $3);
 860                 free($2);
 861                 free($3);
 862                 if (clo == NULL)
 863                         return (1);
 864         }
 865         ;
 866
 867 lun_path:       PATH STR
 868         {
 869                 if (lun->l_path != NULL) {
 870                         log_warnx("path for lun \"%s\" "
 871                             "specified more than once",
 872                             lun->l_name);
 873                         free($2);
 874                         return (1);
 875                 }
 876                 lun_set_path(lun, $2);
 877                 free($2);
 878         }
 879         ;
 880
 881 lun_serial:     SERIAL STR
 882         {
 883                 if (lun->l_serial != NULL) {
 884                         log_warnx("serial for lun \"%s\" "
 885                             "specified more than once",
 886                             lun->l_name);
 887                         free($2);
 888                         return (1);
 889                 }
 890                 lun_set_serial(lun, $2);
 891                 free($2);
 892         }
 893         ;
 894
 895 lun_size:       SIZE STR
 896         {
 897                 uint64_t tmp;
 898
 899                 if (expand_number($2, &tmp) != 0) {
 900                         yyerror("invalid numeric value");
 901                         free($2);
 902                         return (1);
 903                 }
 904
 905                 if (lun->l_size != 0) {
 906                         log_warnx("size for lun \"%s\" "
 907                             "specified more than once",
 908                             lun->l_name);
 909                         return (1);
 910                 }
 911                 lun_set_size(lun, tmp);
 912         }
 913         ;
 914 %%
 915
 916 void
 917 yyerror(const char *str)
 918 {
 919
 920         log_warnx("error in configuration file at line %d near '%s': %s",
 921             lineno, yytext, str);
 922 }
 923
 924 static void
 925 check_perms(const char *path)
 926 {
 927         struct stat sb;
 928         int error;
 929
 930         error = stat(path, &sb);
 931         if (error != 0) {
 932                 log_warn("stat");
 933                 return;
 934         }
 935         if (sb.st_mode & S_IWOTH) {
 936                 log_warnx("%s is world-writable", path);
 937         } else if (sb.st_mode & S_IROTH) {
 938                 log_warnx("%s is world-readable", path);
 939         } else if (sb.st_mode & S_IXOTH) {
 940                 /*
 941                  * Ok, this one doesn't matter, but still do it,
 942                  * just for consistency.
 943                  */
 944                 log_warnx("%s is world-executable", path);
 945         }
 946
 947         /*
 948          * XXX: Should we also check for owner != 0?
 949          */
 950 }
 951
 952 struct conf *
 953 conf_new_from_file(const char *path)
 954 {
 955         struct auth_group *ag;
 956         struct portal_group *pg;
 957         int error;
 958
 959         log_debugx("obtaining configuration from %s", path);
 960
 961         conf = conf_new();
 962
 963         ag = auth_group_new(conf, "default");
 964         assert(ag != NULL);
 965
 966         ag = auth_group_new(conf, "no-authentication");
 967         assert(ag != NULL);
 968         ag->ag_type = AG_TYPE_NO_AUTHENTICATION;
 969
 970         ag = auth_group_new(conf, "no-access");
 971         assert(ag != NULL);
 972         ag->ag_type = AG_TYPE_DENY;
 973
 974         pg = portal_group_new(conf, "default");
 975         assert(pg != NULL);
 976
 977         yyin = fopen(path, "r");
 978         if (yyin == NULL) {
 979                 log_warn("unable to open configuration file %s", path);
 980                 conf_delete(conf);
 981                 return (NULL);
 982         }
 983         check_perms(path);
 984         lineno = 1;
 985         yyrestart(yyin);
 986         error = yyparse();
 987         auth_group = NULL;
 988         portal_group = NULL;
 989         target = NULL;
 990         lun = NULL;
 991         fclose(yyin);
 992         if (error != 0) {
 993                 conf_delete(conf);
 994                 return (NULL);
 995         }
 996
 997         if (conf->conf_default_ag_defined == false) {
 998                 log_debugx("auth-group \"default\" not defined; "
 999                     "going with defaults");
1000                 ag = auth_group_find(conf, "default");
1001                 assert(ag != NULL);
1002                 ag->ag_type = AG_TYPE_DENY;
1003         }
1004
1005         if (conf->conf_default_pg_defined == false) {
1006                 log_debugx("portal-group \"default\" not defined; "
1007                     "going with defaults");
1008                 pg = portal_group_find(conf, "default");
1009                 assert(pg != NULL);
1010                 portal_group_add_listen(pg, "0.0.0.0:3260", false);
1011                 portal_group_add_listen(pg, "[::]:3260", false);
1012         }
1013
1014         conf->conf_kernel_port_on = true;
1015
1016         error = conf_verify(conf);
1017         if (error != 0) {
1018                 conf_delete(conf);
1019                 return (NULL);
1020         }
1021
1022         return (conf);
1023 }