util/configlexer.lex

   1 %{
   2 /*
   3  * configlexer.lex - lexical analyzer for unbound config file
   4  *
   5  * Copyright (c) 2001-2006, NLnet Labs. All rights reserved
   6  *
   7  * See LICENSE for the license.
   8  *
   9  */
  10
  11 /* because flex keeps having sign-unsigned compare problems that are unfixed*/
  12 #if defined(__clang__)||(defined(__GNUC__)&&((__GNUC__ >4)||(defined(__GNUC_MINOR__)&&(__GNUC__ ==4)&&(__GNUC_MINOR__ >=2))))
  13 #pragma GCC diagnostic ignored "-Wsign-compare"
  14 #endif
  15
  16 #include <ctype.h>
  17 #include <strings.h>
  18 #ifdef HAVE_GLOB_H
  19 # include <glob.h>
  20 #endif
  21
  22 #include "util/config_file.h"
  23 #include "util/configparser.h"
  24 void ub_c_error(const char *message);
  25
  26 #if 0
  27 #define LEXOUT(s)  printf s /* used ONLY when debugging */
  28 #else
  29 #define LEXOUT(s)
  30 #endif
  31
  32 /** avoid warning in about fwrite return value */
  33 #define ECHO ub_c_error_msg("syntax error at text: %s", yytext)
  34
  35 /** A parser variable, this is a statement in the config file which is
  36  * of the form variable: value1 value2 ...  nargs is the number of values. */
  37 #define YDVAR(nargs, var) \
  38         num_args=(nargs); \
  39         LEXOUT(("v(%s%d) ", yytext, num_args)); \
  40         if(num_args > 0) { BEGIN(val); } \
  41         return (var);
  42
  43 struct inc_state {
  44         char* filename;
  45         int line;
  46         YY_BUFFER_STATE buffer;
  47         struct inc_state* next;
  48         int inc_toplevel;
  49 };
  50 static struct inc_state* config_include_stack = NULL;
  51 static int inc_depth = 0;
  52 static int inc_prev = 0;
  53 static int num_args = 0;
  54 static int inc_toplevel = 0;
  55
  56 void init_cfg_parse(void)
  57 {
  58         config_include_stack = NULL;
  59         inc_depth = 0;
  60         inc_prev = 0;
  61         num_args = 0;
  62         inc_toplevel = 0;
  63 }
  64
  65 static void config_start_include(const char* filename, int toplevel)
  66 {
  67         FILE *input;
  68         struct inc_state* s;
  69         char* nm;
  70         if(inc_depth+1 > 100000) {
  71                 ub_c_error_msg("too many include files");
  72                 return;
  73         }
  74         if(*filename == '\0') {
  75                 ub_c_error_msg("empty include file name");
  76                 return;
  77         }
  78         s = (struct inc_state*)malloc(sizeof(*s));
  79         if(!s) {
  80                 ub_c_error_msg("include %s: malloc failure", filename);
  81                 return;
  82         }
  83         if(cfg_parser->chroot && strncmp(filename, cfg_parser->chroot,
  84                 strlen(cfg_parser->chroot)) == 0) {
  85                 filename += strlen(cfg_parser->chroot);
  86         }
  87         nm = strdup(filename);
  88         if(!nm) {
  89                 ub_c_error_msg("include %s: strdup failure", filename);
  90                 free(s);
  91                 return;
  92         }
  93         input = fopen(filename, "r");
  94         if(!input) {
  95                 ub_c_error_msg("cannot open include file '%s': %s",
  96                         filename, strerror(errno));
  97                 free(s);
  98                 free(nm);
  99                 return;
 100         }
 101         LEXOUT(("switch_to_include_file(%s)\n", filename));
 102         inc_depth++;
 103         s->filename = cfg_parser->filename;
 104         s->line = cfg_parser->line;
 105         s->buffer = YY_CURRENT_BUFFER;
 106         s->inc_toplevel = inc_toplevel;
 107         s->next = config_include_stack;
 108         config_include_stack = s;
 109         cfg_parser->filename = nm;
 110         cfg_parser->line = 1;
 111         inc_toplevel = toplevel;
 112         yy_switch_to_buffer(yy_create_buffer(input, YY_BUF_SIZE));
 113 }
 114
 115 static void config_start_include_glob(const char* filename, int toplevel)
 116 {
 117
 118         /* check for wildcards */
 119 #ifdef HAVE_GLOB
 120         glob_t g;
 121         int i, r, flags;
 122         if(!(!strchr(filename, '*') && !strchr(filename, '?') && !strchr(filename, '[') &&
 123                 !strchr(filename, '{') && !strchr(filename, '~'))) {
 124                 flags = 0
 125 #ifdef GLOB_ERR
 126                         | GLOB_ERR
 127 #endif
 128                          /* do not set GLOB_NOSORT so the results are sorted
 129                             and in a predictable order. */
 130 #ifdef GLOB_BRACE
 131                         | GLOB_BRACE
 132 #endif
 133 #ifdef GLOB_TILDE
 134                         | GLOB_TILDE
 135 #endif
 136                 ;
 137                 memset(&g, 0, sizeof(g));
 138                 if(cfg_parser->chroot && strncmp(filename, cfg_parser->chroot,
 139                         strlen(cfg_parser->chroot)) == 0) {
 140                         filename += strlen(cfg_parser->chroot);
 141                 }
 142                 r = glob(filename, flags, NULL, &g);
 143                 if(r) {
 144                         /* some error */
 145                         globfree(&g);
 146                         if(r == GLOB_NOMATCH)
 147                                 return; /* no matches for pattern */
 148                         config_start_include(filename, toplevel); /* let original deal with it */
 149                         return;
 150                 }
 151                 /* process files found, if any */
 152                 for(i=(int)g.gl_pathc-1; i>=0; i--) {
 153                         config_start_include(g.gl_pathv[i], toplevel);
 154                 }
 155                 globfree(&g);
 156                 return;
 157         }
 158 #endif /* HAVE_GLOB */
 159
 160         config_start_include(filename, toplevel);
 161 }
 162
 163 static void config_end_include(void)
 164 {
 165         struct inc_state* s = config_include_stack;
 166         --inc_depth;
 167         if(!s) return;
 168         free(cfg_parser->filename);
 169         cfg_parser->filename = s->filename;
 170         cfg_parser->line = s->line;
 171         yy_delete_buffer(YY_CURRENT_BUFFER);
 172         yy_switch_to_buffer(s->buffer);
 173         config_include_stack = s->next;
 174         inc_toplevel = s->inc_toplevel;
 175         free(s);
 176 }
 177
 178 #ifndef yy_set_bol /* compat definition, for flex 2.4.6 */
 179 #define yy_set_bol(at_bol) \
 180         { \
 181                 if ( ! yy_current_buffer ) \
 182                         yy_current_buffer = yy_create_buffer( yyin, YY_BUF_SIZE ); \
 183                 yy_current_buffer->yy_ch_buf[0] = ((at_bol)?'\n':' '); \
 184         }
 185 #endif
 186
 187 %}
 188 %option noinput
 189 %option nounput
 190 %{
 191 #ifndef YY_NO_UNPUT
 192 #define YY_NO_UNPUT 1
 193 #endif
 194 #ifndef YY_NO_INPUT
 195 #define YY_NO_INPUT 1
 196 #endif
 197 %}
 198
 199 SPACE   [ \t]
 200 LETTER  [a-zA-Z]
 201 UNQUOTEDLETTER [^\'\"\n\r \t\\]|\\.
 202 UNQUOTEDLETTER_NOCOLON [^\:\'\"\n\r \t\\]|\\.
 203 NEWLINE [\r\n]
 204 COMMENT \#
 205 COLON   \:
 206 DQANY     [^\"\n\r\\]|\\.
 207 SQANY     [^\'\n\r\\]|\\.
 208
 209 %x      quotedstring singlequotedstr include include_quoted val include_toplevel include_toplevel_quoted
 210
 211 %%
 212 <INITIAL,val>{SPACE}*   {
 213         LEXOUT(("SP ")); /* ignore */ }
 214 <INITIAL,val>{SPACE}*{COMMENT}.*        {
 215         /* note that flex makes the longest match and '.' is any but not nl */
 216         LEXOUT(("comment(%s) ", yytext)); /* ignore */ }
 217 server{COLON}                   { YDVAR(0, VAR_SERVER) }
 218 qname-minimisation{COLON}       { YDVAR(1, VAR_QNAME_MINIMISATION) }
 219 qname-minimisation-strict{COLON} { YDVAR(1, VAR_QNAME_MINIMISATION_STRICT) }
 220 num-threads{COLON}              { YDVAR(1, VAR_NUM_THREADS) }
 221 verbosity{COLON}                { YDVAR(1, VAR_VERBOSITY) }
 222 port{COLON}                     { YDVAR(1, VAR_PORT) }
 223 outgoing-range{COLON}           { YDVAR(1, VAR_OUTGOING_RANGE) }
 224 outgoing-port-permit{COLON}     { YDVAR(1, VAR_OUTGOING_PORT_PERMIT) }
 225 outgoing-port-avoid{COLON}      { YDVAR(1, VAR_OUTGOING_PORT_AVOID) }
 226 outgoing-num-tcp{COLON}         { YDVAR(1, VAR_OUTGOING_NUM_TCP) }
 227 incoming-num-tcp{COLON}         { YDVAR(1, VAR_INCOMING_NUM_TCP) }
 228 do-ip4{COLON}                   { YDVAR(1, VAR_DO_IP4) }
 229 do-ip6{COLON}                   { YDVAR(1, VAR_DO_IP6) }
 230 prefer-ip4{COLON}               { YDVAR(1, VAR_PREFER_IP4) }
 231 prefer-ip6{COLON}               { YDVAR(1, VAR_PREFER_IP6) }
 232 do-udp{COLON}                   { YDVAR(1, VAR_DO_UDP) }
 233 do-tcp{COLON}                   { YDVAR(1, VAR_DO_TCP) }
 234 tcp-upstream{COLON}             { YDVAR(1, VAR_TCP_UPSTREAM) }
 235 tcp-mss{COLON}                  { YDVAR(1, VAR_TCP_MSS) }
 236 outgoing-tcp-mss{COLON}         { YDVAR(1, VAR_OUTGOING_TCP_MSS) }
 237 tcp-idle-timeout{COLON}         { YDVAR(1, VAR_TCP_IDLE_TIMEOUT) }
 238 edns-tcp-keepalive{COLON}       { YDVAR(1, VAR_EDNS_TCP_KEEPALIVE) }
 239 edns-tcp-keepalive-timeout{COLON} { YDVAR(1, VAR_EDNS_TCP_KEEPALIVE_TIMEOUT) }
 240 ssl-upstream{COLON}             { YDVAR(1, VAR_SSL_UPSTREAM) }
 241 tls-upstream{COLON}             { YDVAR(1, VAR_SSL_UPSTREAM) }
 242 ssl-service-key{COLON}          { YDVAR(1, VAR_SSL_SERVICE_KEY) }
 243 tls-service-key{COLON}          { YDVAR(1, VAR_SSL_SERVICE_KEY) }
 244 ssl-service-pem{COLON}          { YDVAR(1, VAR_SSL_SERVICE_PEM) }
 245 tls-service-pem{COLON}          { YDVAR(1, VAR_SSL_SERVICE_PEM) }
 246 ssl-port{COLON}                 { YDVAR(1, VAR_SSL_PORT) }
 247 tls-port{COLON}                 { YDVAR(1, VAR_SSL_PORT) }
 248 ssl-cert-bundle{COLON}          { YDVAR(1, VAR_TLS_CERT_BUNDLE) }
 249 tls-cert-bundle{COLON}          { YDVAR(1, VAR_TLS_CERT_BUNDLE) }
 250 tls-win-cert{COLON}             { YDVAR(1, VAR_TLS_WIN_CERT) }
 251 additional-ssl-port{COLON}      { YDVAR(1, VAR_TLS_ADDITIONAL_PORT) }
 252 additional-tls-port{COLON}      { YDVAR(1, VAR_TLS_ADDITIONAL_PORT) }
 253 tls-additional-ports{COLON}     { YDVAR(1, VAR_TLS_ADDITIONAL_PORT) }
 254 tls-additional-port{COLON}      { YDVAR(1, VAR_TLS_ADDITIONAL_PORT) }
 255 tls-session-ticket-keys{COLON}  { YDVAR(1, VAR_TLS_SESSION_TICKET_KEYS) }
 256 tls-ciphers{COLON}              { YDVAR(1, VAR_TLS_CIPHERS) }
 257 tls-ciphersuites{COLON}         { YDVAR(1, VAR_TLS_CIPHERSUITES) }
 258 tls-use-sni{COLON}              { YDVAR(1, VAR_TLS_USE_SNI) }
 259 use-systemd{COLON}              { YDVAR(1, VAR_USE_SYSTEMD) }
 260 do-daemonize{COLON}             { YDVAR(1, VAR_DO_DAEMONIZE) }
 261 interface{COLON}                { YDVAR(1, VAR_INTERFACE) }
 262 ip-address{COLON}               { YDVAR(1, VAR_INTERFACE) }
 263 outgoing-interface{COLON}       { YDVAR(1, VAR_OUTGOING_INTERFACE) }
 264 interface-automatic{COLON}      { YDVAR(1, VAR_INTERFACE_AUTOMATIC) }
 265 so-rcvbuf{COLON}                { YDVAR(1, VAR_SO_RCVBUF) }
 266 so-sndbuf{COLON}                { YDVAR(1, VAR_SO_SNDBUF) }
 267 so-reuseport{COLON}             { YDVAR(1, VAR_SO_REUSEPORT) }
 268 ip-transparent{COLON}           { YDVAR(1, VAR_IP_TRANSPARENT) }
 269 ip-freebind{COLON}              { YDVAR(1, VAR_IP_FREEBIND) }
 270 ip-dscp{COLON}          { YDVAR(1, VAR_IP_DSCP) }
 271 chroot{COLON}                   { YDVAR(1, VAR_CHROOT) }
 272 username{COLON}                 { YDVAR(1, VAR_USERNAME) }
 273 directory{COLON}                { YDVAR(1, VAR_DIRECTORY) }
 274 logfile{COLON}                  { YDVAR(1, VAR_LOGFILE) }
 275 pidfile{COLON}                  { YDVAR(1, VAR_PIDFILE) }
 276 root-hints{COLON}               { YDVAR(1, VAR_ROOT_HINTS) }
 277 stream-wait-size{COLON}         { YDVAR(1, VAR_STREAM_WAIT_SIZE) }
 278 edns-buffer-size{COLON}         { YDVAR(1, VAR_EDNS_BUFFER_SIZE) }
 279 msg-buffer-size{COLON}          { YDVAR(1, VAR_MSG_BUFFER_SIZE) }
 280 msg-cache-size{COLON}           { YDVAR(1, VAR_MSG_CACHE_SIZE) }
 281 msg-cache-slabs{COLON}          { YDVAR(1, VAR_MSG_CACHE_SLABS) }
 282 rrset-cache-size{COLON}         { YDVAR(1, VAR_RRSET_CACHE_SIZE) }
 283 rrset-cache-slabs{COLON}        { YDVAR(1, VAR_RRSET_CACHE_SLABS) }
 284 cache-max-ttl{COLON}            { YDVAR(1, VAR_CACHE_MAX_TTL) }
 285 cache-max-negative-ttl{COLON}   { YDVAR(1, VAR_CACHE_MAX_NEGATIVE_TTL) }
 286 cache-min-ttl{COLON}            { YDVAR(1, VAR_CACHE_MIN_TTL) }
 287 infra-host-ttl{COLON}           { YDVAR(1, VAR_INFRA_HOST_TTL) }
 288 infra-lame-ttl{COLON}           { YDVAR(1, VAR_INFRA_LAME_TTL) }
 289 infra-cache-slabs{COLON}        { YDVAR(1, VAR_INFRA_CACHE_SLABS) }
 290 infra-cache-numhosts{COLON}     { YDVAR(1, VAR_INFRA_CACHE_NUMHOSTS) }
 291 infra-cache-lame-size{COLON}    { YDVAR(1, VAR_INFRA_CACHE_LAME_SIZE) }
 292 infra-cache-min-rtt{COLON}      { YDVAR(1, VAR_INFRA_CACHE_MIN_RTT) }
 293 num-queries-per-thread{COLON}   { YDVAR(1, VAR_NUM_QUERIES_PER_THREAD) }
 294 jostle-timeout{COLON}           { YDVAR(1, VAR_JOSTLE_TIMEOUT) }
 295 delay-close{COLON}              { YDVAR(1, VAR_DELAY_CLOSE) }
 296 target-fetch-policy{COLON}      { YDVAR(1, VAR_TARGET_FETCH_POLICY) }
 297 harden-short-bufsize{COLON}     { YDVAR(1, VAR_HARDEN_SHORT_BUFSIZE) }
 298 harden-large-queries{COLON}     { YDVAR(1, VAR_HARDEN_LARGE_QUERIES) }
 299 harden-glue{COLON}              { YDVAR(1, VAR_HARDEN_GLUE) }
 300 harden-dnssec-stripped{COLON}   { YDVAR(1, VAR_HARDEN_DNSSEC_STRIPPED) }
 301 harden-below-nxdomain{COLON}    { YDVAR(1, VAR_HARDEN_BELOW_NXDOMAIN) }
 302 harden-referral-path{COLON}     { YDVAR(1, VAR_HARDEN_REFERRAL_PATH) }
 303 harden-algo-downgrade{COLON}    { YDVAR(1, VAR_HARDEN_ALGO_DOWNGRADE) }
 304 use-caps-for-id{COLON}          { YDVAR(1, VAR_USE_CAPS_FOR_ID) }
 305 caps-whitelist{COLON}           { YDVAR(1, VAR_CAPS_WHITELIST) }
 306 unwanted-reply-threshold{COLON} { YDVAR(1, VAR_UNWANTED_REPLY_THRESHOLD) }
 307 private-address{COLON}          { YDVAR(1, VAR_PRIVATE_ADDRESS) }
 308 private-domain{COLON}           { YDVAR(1, VAR_PRIVATE_DOMAIN) }
 309 prefetch-key{COLON}             { YDVAR(1, VAR_PREFETCH_KEY) }
 310 prefetch{COLON}                 { YDVAR(1, VAR_PREFETCH) }
 311 deny-any{COLON}                 { YDVAR(1, VAR_DENY_ANY) }
 312 stub-zone{COLON}                { YDVAR(0, VAR_STUB_ZONE) }
 313 name{COLON}                     { YDVAR(1, VAR_NAME) }
 314 stub-addr{COLON}                { YDVAR(1, VAR_STUB_ADDR) }
 315 stub-host{COLON}                { YDVAR(1, VAR_STUB_HOST) }
 316 stub-prime{COLON}               { YDVAR(1, VAR_STUB_PRIME) }
 317 stub-first{COLON}               { YDVAR(1, VAR_STUB_FIRST) }
 318 stub-no-cache{COLON}            { YDVAR(1, VAR_STUB_NO_CACHE) }
 319 stub-ssl-upstream{COLON}        { YDVAR(1, VAR_STUB_SSL_UPSTREAM) }
 320 stub-tls-upstream{COLON}        { YDVAR(1, VAR_STUB_SSL_UPSTREAM) }
 321 forward-zone{COLON}             { YDVAR(0, VAR_FORWARD_ZONE) }
 322 forward-addr{COLON}             { YDVAR(1, VAR_FORWARD_ADDR) }
 323 forward-host{COLON}             { YDVAR(1, VAR_FORWARD_HOST) }
 324 forward-first{COLON}            { YDVAR(1, VAR_FORWARD_FIRST) }
 325 forward-no-cache{COLON}         { YDVAR(1, VAR_FORWARD_NO_CACHE) }
 326 forward-ssl-upstream{COLON}     { YDVAR(1, VAR_FORWARD_SSL_UPSTREAM) }
 327 forward-tls-upstream{COLON}     { YDVAR(1, VAR_FORWARD_SSL_UPSTREAM) }
 328 auth-zone{COLON}                { YDVAR(0, VAR_AUTH_ZONE) }
 329 rpz{COLON}                      { YDVAR(0, VAR_RPZ) }
 330 tags{COLON}                     { YDVAR(1, VAR_TAGS) }
 331 rpz-action-override{COLON}      { YDVAR(1, VAR_RPZ_ACTION_OVERRIDE) }
 332 rpz-cname-override{COLON}       { YDVAR(1, VAR_RPZ_CNAME_OVERRIDE) }
 333 rpz-log{COLON}                  { YDVAR(1, VAR_RPZ_LOG) }
 334 rpz-log-name{COLON}             { YDVAR(1, VAR_RPZ_LOG_NAME) }
 335 zonefile{COLON}                 { YDVAR(1, VAR_ZONEFILE) }
 336 master{COLON}                   { YDVAR(1, VAR_MASTER) }
 337 url{COLON}                      { YDVAR(1, VAR_URL) }
 338 allow-notify{COLON}             { YDVAR(1, VAR_ALLOW_NOTIFY) }
 339 for-downstream{COLON}           { YDVAR(1, VAR_FOR_DOWNSTREAM) }
 340 for-upstream{COLON}             { YDVAR(1, VAR_FOR_UPSTREAM) }
 341 fallback-enabled{COLON}         { YDVAR(1, VAR_FALLBACK_ENABLED) }
 342 view{COLON}                     { YDVAR(0, VAR_VIEW) }
 343 view-first{COLON}               { YDVAR(1, VAR_VIEW_FIRST) }
 344 do-not-query-address{COLON}     { YDVAR(1, VAR_DO_NOT_QUERY_ADDRESS) }
 345 do-not-query-localhost{COLON}   { YDVAR(1, VAR_DO_NOT_QUERY_LOCALHOST) }
 346 access-control{COLON}           { YDVAR(2, VAR_ACCESS_CONTROL) }
 347 send-client-subnet{COLON}       { YDVAR(1, VAR_SEND_CLIENT_SUBNET) }
 348 client-subnet-zone{COLON}       { YDVAR(1, VAR_CLIENT_SUBNET_ZONE) }
 349 client-subnet-always-forward{COLON} { YDVAR(1, VAR_CLIENT_SUBNET_ALWAYS_FORWARD) }
 350 client-subnet-opcode{COLON}     { YDVAR(1, VAR_CLIENT_SUBNET_OPCODE) }
 351 max-client-subnet-ipv4{COLON}   { YDVAR(1, VAR_MAX_CLIENT_SUBNET_IPV4) }
 352 max-client-subnet-ipv6{COLON}   { YDVAR(1, VAR_MAX_CLIENT_SUBNET_IPV6) }
 353 min-client-subnet-ipv4{COLON}   { YDVAR(1, VAR_MIN_CLIENT_SUBNET_IPV4) }
 354 min-client-subnet-ipv6{COLON}   { YDVAR(1, VAR_MIN_CLIENT_SUBNET_IPV6) }
 355 max-ecs-tree-size-ipv4{COLON}   { YDVAR(1, VAR_MAX_ECS_TREE_SIZE_IPV4) }
 356 max-ecs-tree-size-ipv6{COLON}   { YDVAR(1, VAR_MAX_ECS_TREE_SIZE_IPV6) }
 357 hide-identity{COLON}            { YDVAR(1, VAR_HIDE_IDENTITY) }
 358 hide-version{COLON}             { YDVAR(1, VAR_HIDE_VERSION) }
 359 hide-trustanchor{COLON}         { YDVAR(1, VAR_HIDE_TRUSTANCHOR) }
 360 identity{COLON}                 { YDVAR(1, VAR_IDENTITY) }
 361 version{COLON}                  { YDVAR(1, VAR_VERSION) }
 362 module-config{COLON}            { YDVAR(1, VAR_MODULE_CONF) }
 363 dlv-anchor{COLON}               { YDVAR(1, VAR_DLV_ANCHOR) }
 364 dlv-anchor-file{COLON}          { YDVAR(1, VAR_DLV_ANCHOR_FILE) }
 365 trust-anchor-file{COLON}        { YDVAR(1, VAR_TRUST_ANCHOR_FILE) }
 366 auto-trust-anchor-file{COLON}   { YDVAR(1, VAR_AUTO_TRUST_ANCHOR_FILE) }
 367 trusted-keys-file{COLON}        { YDVAR(1, VAR_TRUSTED_KEYS_FILE) }
 368 trust-anchor{COLON}             { YDVAR(1, VAR_TRUST_ANCHOR) }
 369 trust-anchor-signaling{COLON}   { YDVAR(1, VAR_TRUST_ANCHOR_SIGNALING) }
 370 root-key-sentinel{COLON}        { YDVAR(1, VAR_ROOT_KEY_SENTINEL) }
 371 val-override-date{COLON}        { YDVAR(1, VAR_VAL_OVERRIDE_DATE) }
 372 val-sig-skew-min{COLON}         { YDVAR(1, VAR_VAL_SIG_SKEW_MIN) }
 373 val-sig-skew-max{COLON}         { YDVAR(1, VAR_VAL_SIG_SKEW_MAX) }
 374 val-bogus-ttl{COLON}            { YDVAR(1, VAR_BOGUS_TTL) }
 375 val-clean-additional{COLON}     { YDVAR(1, VAR_VAL_CLEAN_ADDITIONAL) }
 376 val-permissive-mode{COLON}      { YDVAR(1, VAR_VAL_PERMISSIVE_MODE) }
 377 aggressive-nsec{COLON}          { YDVAR(1, VAR_AGGRESSIVE_NSEC) }
 378 ignore-cd-flag{COLON}           { YDVAR(1, VAR_IGNORE_CD_FLAG) }
 379 serve-expired{COLON}            { YDVAR(1, VAR_SERVE_EXPIRED) }
 380 serve-expired-ttl{COLON}        { YDVAR(1, VAR_SERVE_EXPIRED_TTL) }
 381 serve-expired-ttl-reset{COLON}  { YDVAR(1, VAR_SERVE_EXPIRED_TTL_RESET) }
 382 serve-expired-reply-ttl{COLON}  { YDVAR(1, VAR_SERVE_EXPIRED_REPLY_TTL) }
 383 serve-expired-client-timeout{COLON}     { YDVAR(1, VAR_SERVE_EXPIRED_CLIENT_TIMEOUT) }
 384 fake-dsa{COLON}                 { YDVAR(1, VAR_FAKE_DSA) }
 385 fake-sha1{COLON}                { YDVAR(1, VAR_FAKE_SHA1) }
 386 val-log-level{COLON}            { YDVAR(1, VAR_VAL_LOG_LEVEL) }
 387 key-cache-size{COLON}           { YDVAR(1, VAR_KEY_CACHE_SIZE) }
 388 key-cache-slabs{COLON}          { YDVAR(1, VAR_KEY_CACHE_SLABS) }
 389 neg-cache-size{COLON}           { YDVAR(1, VAR_NEG_CACHE_SIZE) }
 390 val-nsec3-keysize-iterations{COLON}     {
 391                                   YDVAR(1, VAR_VAL_NSEC3_KEYSIZE_ITERATIONS) }
 392 add-holddown{COLON}             { YDVAR(1, VAR_ADD_HOLDDOWN) }
 393 del-holddown{COLON}             { YDVAR(1, VAR_DEL_HOLDDOWN) }
 394 keep-missing{COLON}             { YDVAR(1, VAR_KEEP_MISSING) }
 395 permit-small-holddown{COLON}    { YDVAR(1, VAR_PERMIT_SMALL_HOLDDOWN) }
 396 use-syslog{COLON}               { YDVAR(1, VAR_USE_SYSLOG) }
 397 log-identity{COLON}             { YDVAR(1, VAR_LOG_IDENTITY) }
 398 log-time-ascii{COLON}           { YDVAR(1, VAR_LOG_TIME_ASCII) }
 399 log-queries{COLON}              { YDVAR(1, VAR_LOG_QUERIES) }
 400 log-replies{COLON}              { YDVAR(1, VAR_LOG_REPLIES) }
 401 log-tag-queryreply{COLON}       { YDVAR(1, VAR_LOG_TAG_QUERYREPLY) }
 402 log-local-actions{COLON}       { YDVAR(1, VAR_LOG_LOCAL_ACTIONS) }
 403 log-servfail{COLON}             { YDVAR(1, VAR_LOG_SERVFAIL) }
 404 local-zone{COLON}               { YDVAR(2, VAR_LOCAL_ZONE) }
 405 local-data{COLON}               { YDVAR(1, VAR_LOCAL_DATA) }
 406 local-data-ptr{COLON}           { YDVAR(1, VAR_LOCAL_DATA_PTR) }
 407 unblock-lan-zones{COLON}        { YDVAR(1, VAR_UNBLOCK_LAN_ZONES) }
 408 insecure-lan-zones{COLON}       { YDVAR(1, VAR_INSECURE_LAN_ZONES) }
 409 statistics-interval{COLON}      { YDVAR(1, VAR_STATISTICS_INTERVAL) }
 410 statistics-cumulative{COLON}    { YDVAR(1, VAR_STATISTICS_CUMULATIVE) }
 411 extended-statistics{COLON}      { YDVAR(1, VAR_EXTENDED_STATISTICS) }
 412 shm-enable{COLON}               { YDVAR(1, VAR_SHM_ENABLE) }
 413 shm-key{COLON}                  { YDVAR(1, VAR_SHM_KEY) }
 414 remote-control{COLON}           { YDVAR(0, VAR_REMOTE_CONTROL) }
 415 control-enable{COLON}           { YDVAR(1, VAR_CONTROL_ENABLE) }
 416 control-interface{COLON}        { YDVAR(1, VAR_CONTROL_INTERFACE) }
 417 control-port{COLON}             { YDVAR(1, VAR_CONTROL_PORT) }
 418 control-use-cert{COLON}         { YDVAR(1, VAR_CONTROL_USE_CERT) }
 419 server-key-file{COLON}          { YDVAR(1, VAR_SERVER_KEY_FILE) }
 420 server-cert-file{COLON}         { YDVAR(1, VAR_SERVER_CERT_FILE) }
 421 control-key-file{COLON}         { YDVAR(1, VAR_CONTROL_KEY_FILE) }
 422 control-cert-file{COLON}        { YDVAR(1, VAR_CONTROL_CERT_FILE) }
 423 python-script{COLON}            { YDVAR(1, VAR_PYTHON_SCRIPT) }
 424 python{COLON}                   { YDVAR(0, VAR_PYTHON) }
 425 dynlib-file{COLON}              { YDVAR(1, VAR_DYNLIB_FILE) }
 426 dynlib{COLON}                   { YDVAR(0, VAR_DYNLIB) }
 427 domain-insecure{COLON}          { YDVAR(1, VAR_DOMAIN_INSECURE) }
 428 minimal-responses{COLON}        { YDVAR(1, VAR_MINIMAL_RESPONSES) }
 429 rrset-roundrobin{COLON}         { YDVAR(1, VAR_RRSET_ROUNDROBIN) }
 430 unknown-server-time-limit{COLON} { YDVAR(1, VAR_UNKNOWN_SERVER_TIME_LIMIT) }
 431 max-udp-size{COLON}             { YDVAR(1, VAR_MAX_UDP_SIZE) }
 432 dns64-prefix{COLON}             { YDVAR(1, VAR_DNS64_PREFIX) }
 433 dns64-synthall{COLON}           { YDVAR(1, VAR_DNS64_SYNTHALL) }
 434 dns64-ignore-aaaa{COLON}        { YDVAR(1, VAR_DNS64_IGNORE_AAAA) }
 435 define-tag{COLON}               { YDVAR(1, VAR_DEFINE_TAG) }
 436 local-zone-tag{COLON}           { YDVAR(2, VAR_LOCAL_ZONE_TAG) }
 437 access-control-tag{COLON}       { YDVAR(2, VAR_ACCESS_CONTROL_TAG) }
 438 access-control-tag-action{COLON} { YDVAR(3, VAR_ACCESS_CONTROL_TAG_ACTION) }
 439 access-control-tag-data{COLON}  { YDVAR(3, VAR_ACCESS_CONTROL_TAG_DATA) }
 440 access-control-view{COLON}      { YDVAR(2, VAR_ACCESS_CONTROL_VIEW) }
 441 local-zone-override{COLON}      { YDVAR(3, VAR_LOCAL_ZONE_OVERRIDE) }
 442 dnstap{COLON}                   { YDVAR(0, VAR_DNSTAP) }
 443 dnstap-enable{COLON}            { YDVAR(1, VAR_DNSTAP_ENABLE) }
 444 dnstap-bidirectional{COLON}     { YDVAR(1, VAR_DNSTAP_BIDIRECTIONAL) }
 445 dnstap-socket-path{COLON}       { YDVAR(1, VAR_DNSTAP_SOCKET_PATH) }
 446 dnstap-ip{COLON}                { YDVAR(1, VAR_DNSTAP_IP) }
 447 dnstap-tls{COLON}               { YDVAR(1, VAR_DNSTAP_TLS) }
 448 dnstap-tls-server-name{COLON}   { YDVAR(1, VAR_DNSTAP_TLS_SERVER_NAME) }
 449 dnstap-tls-cert-bundle{COLON}   { YDVAR(1, VAR_DNSTAP_TLS_CERT_BUNDLE) }
 450 dnstap-tls-client-key-file{COLON}       {
 451                 YDVAR(1, VAR_DNSTAP_TLS_CLIENT_KEY_FILE) }
 452 dnstap-tls-client-cert-file{COLON}      {
 453                 YDVAR(1, VAR_DNSTAP_TLS_CLIENT_CERT_FILE) }
 454 dnstap-send-identity{COLON}     { YDVAR(1, VAR_DNSTAP_SEND_IDENTITY) }
 455 dnstap-send-version{COLON}      { YDVAR(1, VAR_DNSTAP_SEND_VERSION) }
 456 dnstap-identity{COLON}          { YDVAR(1, VAR_DNSTAP_IDENTITY) }
 457 dnstap-version{COLON}           { YDVAR(1, VAR_DNSTAP_VERSION) }
 458 dnstap-log-resolver-query-messages{COLON}       {
 459                 YDVAR(1, VAR_DNSTAP_LOG_RESOLVER_QUERY_MESSAGES) }
 460 dnstap-log-resolver-response-messages{COLON}    {
 461                 YDVAR(1, VAR_DNSTAP_LOG_RESOLVER_RESPONSE_MESSAGES) }
 462 dnstap-log-client-query-messages{COLON}         {
 463                 YDVAR(1, VAR_DNSTAP_LOG_CLIENT_QUERY_MESSAGES) }
 464 dnstap-log-client-response-messages{COLON}      {
 465                 YDVAR(1, VAR_DNSTAP_LOG_CLIENT_RESPONSE_MESSAGES) }
 466 dnstap-log-forwarder-query-messages{COLON}      {
 467                 YDVAR(1, VAR_DNSTAP_LOG_FORWARDER_QUERY_MESSAGES) }
 468 dnstap-log-forwarder-response-messages{COLON}   {
 469                 YDVAR(1, VAR_DNSTAP_LOG_FORWARDER_RESPONSE_MESSAGES) }
 470 disable-dnssec-lame-check{COLON} { YDVAR(1, VAR_DISABLE_DNSSEC_LAME_CHECK) }
 471 ip-ratelimit{COLON}             { YDVAR(1, VAR_IP_RATELIMIT) }
 472 ratelimit{COLON}                { YDVAR(1, VAR_RATELIMIT) }
 473 ip-ratelimit-slabs{COLON}               { YDVAR(1, VAR_IP_RATELIMIT_SLABS) }
 474 ratelimit-slabs{COLON}          { YDVAR(1, VAR_RATELIMIT_SLABS) }
 475 ip-ratelimit-size{COLON}                { YDVAR(1, VAR_IP_RATELIMIT_SIZE) }
 476 ratelimit-size{COLON}           { YDVAR(1, VAR_RATELIMIT_SIZE) }
 477 ratelimit-for-domain{COLON}     { YDVAR(2, VAR_RATELIMIT_FOR_DOMAIN) }
 478 ratelimit-below-domain{COLON}   { YDVAR(2, VAR_RATELIMIT_BELOW_DOMAIN) }
 479 ip-ratelimit-factor{COLON}              { YDVAR(1, VAR_IP_RATELIMIT_FACTOR) }
 480 ratelimit-factor{COLON}         { YDVAR(1, VAR_RATELIMIT_FACTOR) }
 481 low-rtt{COLON}                  { YDVAR(1, VAR_LOW_RTT) }
 482 fast-server-num{COLON}          { YDVAR(1, VAR_FAST_SERVER_NUM) }
 483 low-rtt-pct{COLON}              { YDVAR(1, VAR_FAST_SERVER_PERMIL) }
 484 low-rtt-permil{COLON}           { YDVAR(1, VAR_FAST_SERVER_PERMIL) }
 485 fast-server-permil{COLON}       { YDVAR(1, VAR_FAST_SERVER_PERMIL) }
 486 response-ip-tag{COLON}          { YDVAR(2, VAR_RESPONSE_IP_TAG) }
 487 response-ip{COLON}              { YDVAR(2, VAR_RESPONSE_IP) }
 488 response-ip-data{COLON}         { YDVAR(2, VAR_RESPONSE_IP_DATA) }
 489 dnscrypt{COLON}                 { YDVAR(0, VAR_DNSCRYPT) }
 490 dnscrypt-enable{COLON}          { YDVAR(1, VAR_DNSCRYPT_ENABLE) }
 491 dnscrypt-port{COLON}            { YDVAR(1, VAR_DNSCRYPT_PORT) }
 492 dnscrypt-provider{COLON}        { YDVAR(1, VAR_DNSCRYPT_PROVIDER) }
 493 dnscrypt-secret-key{COLON}      { YDVAR(1, VAR_DNSCRYPT_SECRET_KEY) }
 494 dnscrypt-provider-cert{COLON}   { YDVAR(1, VAR_DNSCRYPT_PROVIDER_CERT) }
 495 dnscrypt-provider-cert-rotated{COLON}   { YDVAR(1, VAR_DNSCRYPT_PROVIDER_CERT_ROTATED) }
 496 dnscrypt-shared-secret-cache-size{COLON}        {
 497                 YDVAR(1, VAR_DNSCRYPT_SHARED_SECRET_CACHE_SIZE) }
 498 dnscrypt-shared-secret-cache-slabs{COLON}       {
 499                 YDVAR(1, VAR_DNSCRYPT_SHARED_SECRET_CACHE_SLABS) }
 500 dnscrypt-nonce-cache-size{COLON}        { YDVAR(1, VAR_DNSCRYPT_NONCE_CACHE_SIZE) }
 501 dnscrypt-nonce-cache-slabs{COLON}       { YDVAR(1, VAR_DNSCRYPT_NONCE_CACHE_SLABS) }
 502 ipsecmod-enabled{COLON}         { YDVAR(1, VAR_IPSECMOD_ENABLED) }
 503 ipsecmod-ignore-bogus{COLON}    { YDVAR(1, VAR_IPSECMOD_IGNORE_BOGUS) }
 504 ipsecmod-hook{COLON}            { YDVAR(1, VAR_IPSECMOD_HOOK) }
 505 ipsecmod-max-ttl{COLON}         { YDVAR(1, VAR_IPSECMOD_MAX_TTL) }
 506 ipsecmod-whitelist{COLON}       { YDVAR(1, VAR_IPSECMOD_WHITELIST) }
 507 ipsecmod-strict{COLON}          { YDVAR(1, VAR_IPSECMOD_STRICT) }
 508 cachedb{COLON}                  { YDVAR(0, VAR_CACHEDB) }
 509 backend{COLON}                  { YDVAR(1, VAR_CACHEDB_BACKEND) }
 510 secret-seed{COLON}              { YDVAR(1, VAR_CACHEDB_SECRETSEED) }
 511 redis-server-host{COLON}        { YDVAR(1, VAR_CACHEDB_REDISHOST) }
 512 redis-server-port{COLON}        { YDVAR(1, VAR_CACHEDB_REDISPORT) }
 513 redis-timeout{COLON}            { YDVAR(1, VAR_CACHEDB_REDISTIMEOUT) }
 514 redis-expire-records{COLON}     { YDVAR(1, VAR_CACHEDB_REDISEXPIRERECORDS) }
 515 ipset{COLON}                    { YDVAR(0, VAR_IPSET) }
 516 name-v4{COLON}                  { YDVAR(1, VAR_IPSET_NAME_V4) }
 517 name-v6{COLON}                  { YDVAR(1, VAR_IPSET_NAME_V6) }
 518 udp-upstream-without-downstream{COLON} { YDVAR(1, VAR_UDP_UPSTREAM_WITHOUT_DOWNSTREAM) }
 519 tcp-connection-limit{COLON}     { YDVAR(2, VAR_TCP_CONNECTION_LIMIT) }
 520 <INITIAL,val>{NEWLINE}          { LEXOUT(("NL\n")); cfg_parser->line++; }
 521
 522         /* Quoted strings. Strip leading and ending quotes */
 523 <val>\"                 { BEGIN(quotedstring); LEXOUT(("QS ")); }
 524 <quotedstring><<EOF>>   {
 525         yyerror("EOF inside quoted string");
 526         if(--num_args == 0) { BEGIN(INITIAL); }
 527         else                { BEGIN(val); }
 528 }
 529 <quotedstring>{DQANY}*  { LEXOUT(("STR(%s) ", yytext)); yymore(); }
 530 <quotedstring>{NEWLINE} { yyerror("newline inside quoted string, no end \"");
 531                           cfg_parser->line++; BEGIN(INITIAL); }
 532 <quotedstring>\" {
 533         LEXOUT(("QE "));
 534         if(--num_args == 0) { BEGIN(INITIAL); }
 535         else                { BEGIN(val); }
 536         yytext[yyleng - 1] = '\0';
 537         yylval.str = strdup(yytext);
 538         if(!yylval.str)
 539                 yyerror("out of memory");
 540         return STRING_ARG;
 541 }
 542
 543         /* Single Quoted strings. Strip leading and ending quotes */
 544 <val>\'                 { BEGIN(singlequotedstr); LEXOUT(("SQS ")); }
 545 <singlequotedstr><<EOF>>   {
 546         yyerror("EOF inside quoted string");
 547         if(--num_args == 0) { BEGIN(INITIAL); }
 548         else                { BEGIN(val); }
 549 }
 550 <singlequotedstr>{SQANY}*  { LEXOUT(("STR(%s) ", yytext)); yymore(); }
 551 <singlequotedstr>{NEWLINE} { yyerror("newline inside quoted string, no end '");
 552                              cfg_parser->line++; BEGIN(INITIAL); }
 553 <singlequotedstr>\' {
 554         LEXOUT(("SQE "));
 555         if(--num_args == 0) { BEGIN(INITIAL); }
 556         else                { BEGIN(val); }
 557         yytext[yyleng - 1] = '\0';
 558         yylval.str = strdup(yytext);
 559         if(!yylval.str)
 560                 yyerror("out of memory");
 561         return STRING_ARG;
 562 }
 563
 564         /* include: directive */
 565 <INITIAL,val>include{COLON}     {
 566         LEXOUT(("v(%s) ", yytext)); inc_prev = YYSTATE; BEGIN(include); }
 567 <include><<EOF>>        {
 568         yyerror("EOF inside include directive");
 569         BEGIN(inc_prev);
 570 }
 571 <include>{SPACE}*       { LEXOUT(("ISP ")); /* ignore */ }
 572 <include>{NEWLINE}      { LEXOUT(("NL\n")); cfg_parser->line++;}
 573 <include>\"             { LEXOUT(("IQS ")); BEGIN(include_quoted); }
 574 <include>{UNQUOTEDLETTER}*      {
 575         LEXOUT(("Iunquotedstr(%s) ", yytext));
 576         config_start_include_glob(yytext, 0);
 577         BEGIN(inc_prev);
 578 }
 579 <include_quoted><<EOF>> {
 580         yyerror("EOF inside quoted string");
 581         BEGIN(inc_prev);
 582 }
 583 <include_quoted>{DQANY}*        { LEXOUT(("ISTR(%s) ", yytext)); yymore(); }
 584 <include_quoted>{NEWLINE}       { yyerror("newline before \" in include name");
 585                                   cfg_parser->line++; BEGIN(inc_prev); }
 586 <include_quoted>\"      {
 587         LEXOUT(("IQE "));
 588         yytext[yyleng - 1] = '\0';
 589         config_start_include_glob(yytext, 0);
 590         BEGIN(inc_prev);
 591 }
 592 <INITIAL,val><<EOF>>    {
 593         LEXOUT(("LEXEOF "));
 594         yy_set_bol(1); /* Set beginning of line, so "^" rules match.  */
 595         if (!config_include_stack) {
 596                 yyterminate();
 597         } else {
 598                 int prev_toplevel = inc_toplevel;
 599                 fclose(yyin);
 600                 config_end_include();
 601                 if(prev_toplevel) return (VAR_FORCE_TOPLEVEL);
 602         }
 603 }
 604
 605         /* include-toplevel: directive */
 606 <INITIAL,val>include-toplevel{COLON} {
 607         LEXOUT(("v(%s) ", yytext)); inc_prev = YYSTATE; BEGIN(include_toplevel);
 608 }
 609 <include_toplevel><<EOF>> {
 610         yyerror("EOF inside include_toplevel directive");
 611         BEGIN(inc_prev);
 612 }
 613 <include_toplevel>{SPACE}* { LEXOUT(("ITSP ")); /* ignore */ }
 614 <include_toplevel>{NEWLINE} { LEXOUT(("NL\n")); cfg_parser->line++; }
 615 <include_toplevel>\" { LEXOUT(("ITQS ")); BEGIN(include_toplevel_quoted); }
 616 <include_toplevel>{UNQUOTEDLETTER}* {
 617         LEXOUT(("ITunquotedstr(%s) ", yytext));
 618         config_start_include_glob(yytext, 1);
 619         BEGIN(inc_prev);
 620         return (VAR_FORCE_TOPLEVEL);
 621 }
 622 <include_toplevel_quoted><<EOF>> {
 623         yyerror("EOF inside quoted string");
 624         BEGIN(inc_prev);
 625 }
 626 <include_toplevel_quoted>{DQANY}* { LEXOUT(("ITSTR(%s) ", yytext)); yymore(); }
 627 <include_toplevel_quoted>{NEWLINE} {
 628         yyerror("newline before \" in include name");
 629         cfg_parser->line++; BEGIN(inc_prev);
 630 }
 631 <include_toplevel_quoted>\" {
 632         LEXOUT(("ITQE "));
 633         yytext[yyleng - 1] = '\0';
 634         config_start_include_glob(yytext, 1);
 635         BEGIN(inc_prev);
 636         return (VAR_FORCE_TOPLEVEL);
 637 }
 638
 639 <val>{UNQUOTEDLETTER}*  { LEXOUT(("unquotedstr(%s) ", yytext));
 640                         if(--num_args == 0) { BEGIN(INITIAL); }
 641                         yylval.str = strdup(yytext); return STRING_ARG; }
 642
 643 {UNQUOTEDLETTER_NOCOLON}*       {
 644         ub_c_error_msg("unknown keyword '%s'", yytext);
 645         }
 646
 647 <*>.    {
 648         ub_c_error_msg("stray '%s'", yytext);
 649         }
 650
 651 %%