util/configlexer.lex

   1 %{
   2 /*
   3  * configlexer.lex - lexical analyzer for unbound config file
   4  *
   5  * Copyright (c) 2001-2006, NLnet Labs. All rights reserved
   6  *
   7  * See LICENSE for the license.
   8  *
   9  */
  10
  11 /* because flex keeps having sign-unsigned compare problems that are unfixed*/
  12 #if defined(__clang__)||(defined(__GNUC__)&&((__GNUC__ >4)||(defined(__GNUC_MINOR__)&&(__GNUC__ ==4)&&(__GNUC_MINOR__ >=2))))
  13 #pragma GCC diagnostic ignored "-Wsign-compare"
  14 #endif
  15
  16 #include <ctype.h>
  17 #include <strings.h>
  18 #ifdef HAVE_GLOB_H
  19 # include <glob.h>
  20 #endif
  21
  22 #include "util/config_file.h"
  23 #include "util/configparser.h"
  24 void ub_c_error(const char *message);
  25
  26 #if 0
  27 #define LEXOUT(s)  printf s /* used ONLY when debugging */
  28 #else
  29 #define LEXOUT(s)
  30 #endif
  31
  32 /** avoid warning in about fwrite return value */
  33 #define ECHO ub_c_error_msg("syntax error at text: %s", yytext)
  34
  35 /** A parser variable, this is a statement in the config file which is
  36  * of the form variable: value1 value2 ...  nargs is the number of values. */
  37 #define YDVAR(nargs, var) \
  38         num_args=(nargs); \
  39         LEXOUT(("v(%s%d) ", yytext, num_args)); \
  40         if(num_args > 0) { BEGIN(val); } \
  41         return (var);
  42
  43 struct inc_state {
  44         char* filename;
  45         int line;
  46         YY_BUFFER_STATE buffer;
  47         struct inc_state* next;
  48         int inc_toplevel;
  49 };
  50 static struct inc_state* config_include_stack = NULL;
  51 static int inc_depth = 0;
  52 static int inc_prev = 0;
  53 static int num_args = 0;
  54 static int inc_toplevel = 0;
  55
  56 void init_cfg_parse(void)
  57 {
  58         config_include_stack = NULL;
  59         inc_depth = 0;
  60         inc_prev = 0;
  61         num_args = 0;
  62         inc_toplevel = 0;
  63 }
  64
  65 static void config_start_include(const char* filename, int toplevel)
  66 {
  67         FILE *input;
  68         struct inc_state* s;
  69         char* nm;
  70         if(inc_depth+1 > 100000) {
  71                 ub_c_error_msg("too many include files");
  72                 return;
  73         }
  74         if(*filename == '\0') {
  75                 ub_c_error_msg("empty include file name");
  76                 return;
  77         }
  78         s = (struct inc_state*)malloc(sizeof(*s));
  79         if(!s) {
  80                 ub_c_error_msg("include %s: malloc failure", filename);
  81                 return;
  82         }
  83         if(cfg_parser->chroot && strncmp(filename, cfg_parser->chroot,
  84                 strlen(cfg_parser->chroot)) == 0) {
  85                 filename += strlen(cfg_parser->chroot);
  86         }
  87         nm = strdup(filename);
  88         if(!nm) {
  89                 ub_c_error_msg("include %s: strdup failure", filename);
  90                 free(s);
  91                 return;
  92         }
  93         input = fopen(filename, "r");
  94         if(!input) {
  95                 ub_c_error_msg("cannot open include file '%s': %s",
  96                         filename, strerror(errno));
  97                 free(s);
  98                 free(nm);
  99                 return;
 100         }
 101         LEXOUT(("switch_to_include_file(%s)\n", filename));
 102         inc_depth++;
 103         s->filename = cfg_parser->filename;
 104         s->line = cfg_parser->line;
 105         s->buffer = YY_CURRENT_BUFFER;
 106         s->inc_toplevel = inc_toplevel;
 107         s->next = config_include_stack;
 108         config_include_stack = s;
 109         cfg_parser->filename = nm;
 110         cfg_parser->line = 1;
 111         inc_toplevel = toplevel;
 112         yy_switch_to_buffer(yy_create_buffer(input, YY_BUF_SIZE));
 113 }
 114
 115 static void config_start_include_glob(const char* filename, int toplevel)
 116 {
 117
 118         /* check for wildcards */
 119 #ifdef HAVE_GLOB
 120         glob_t g;
 121         int i, r, flags;
 122         if(!(!strchr(filename, '*') && !strchr(filename, '?') && !strchr(filename, '[') &&
 123                 !strchr(filename, '{') && !strchr(filename, '~'))) {
 124                 flags = 0
 125 #ifdef GLOB_ERR
 126                         | GLOB_ERR
 127 #endif
 128                          /* do not set GLOB_NOSORT so the results are sorted
 129                             and in a predictable order. */
 130 #ifdef GLOB_BRACE
 131                         | GLOB_BRACE
 132 #endif
 133 #ifdef GLOB_TILDE
 134                         | GLOB_TILDE
 135 #endif
 136                 ;
 137                 memset(&g, 0, sizeof(g));
 138                 if(cfg_parser->chroot && strncmp(filename, cfg_parser->chroot,
 139                         strlen(cfg_parser->chroot)) == 0) {
 140                         filename += strlen(cfg_parser->chroot);
 141                 }
 142                 r = glob(filename, flags, NULL, &g);
 143                 if(r) {
 144                         /* some error */
 145                         globfree(&g);
 146                         if(r == GLOB_NOMATCH)
 147                                 return; /* no matches for pattern */
 148                         config_start_include(filename, toplevel); /* let original deal with it */
 149                         return;
 150                 }
 151                 /* process files found, if any */
 152                 for(i=(int)g.gl_pathc-1; i>=0; i--) {
 153                         config_start_include(g.gl_pathv[i], toplevel);
 154                 }
 155                 globfree(&g);
 156                 return;
 157         }
 158 #endif /* HAVE_GLOB */
 159
 160         config_start_include(filename, toplevel);
 161 }
 162
 163 static void config_end_include(void)
 164 {
 165         struct inc_state* s = config_include_stack;
 166         --inc_depth;
 167         if(!s) return;
 168         free(cfg_parser->filename);
 169         cfg_parser->filename = s->filename;
 170         cfg_parser->line = s->line;
 171         yy_delete_buffer(YY_CURRENT_BUFFER);
 172         yy_switch_to_buffer(s->buffer);
 173         config_include_stack = s->next;
 174         inc_toplevel = s->inc_toplevel;
 175         free(s);
 176 }
 177
 178 #ifndef yy_set_bol /* compat definition, for flex 2.4.6 */
 179 #define yy_set_bol(at_bol) \
 180         { \
 181                 if ( ! yy_current_buffer ) \
 182                         yy_current_buffer = yy_create_buffer( yyin, YY_BUF_SIZE ); \
 183                 yy_current_buffer->yy_ch_buf[0] = ((at_bol)?'\n':' '); \
 184         }
 185 #endif
 186
 187 %}
 188 %option noinput
 189 %option nounput
 190 %{
 191 #ifndef YY_NO_UNPUT
 192 #define YY_NO_UNPUT 1
 193 #endif
 194 #ifndef YY_NO_INPUT
 195 #define YY_NO_INPUT 1
 196 #endif
 197 %}
 198
 199 SPACE   [ \t]
 200 LETTER  [a-zA-Z]
 201 UNQUOTEDLETTER [^\'\"\n\r \t\\]|\\.
 202 UNQUOTEDLETTER_NOCOLON [^\:\'\"\n\r \t\\]|\\.
 203 NEWLINE [\r\n]
 204 COMMENT \#
 205 COLON   \:
 206 DQANY     [^\"\n\r\\]|\\.
 207 SQANY     [^\'\n\r\\]|\\.
 208
 209 %x      quotedstring singlequotedstr include include_quoted val include_toplevel include_toplevel_quoted
 210
 211 %%
 212 <INITIAL,val>{SPACE}*   {
 213         LEXOUT(("SP ")); /* ignore */ }
 214 <INITIAL,val>{SPACE}*{COMMENT}.*        {
 215         /* note that flex makes the longest match and '.' is any but not nl */
 216         LEXOUT(("comment(%s) ", yytext)); /* ignore */ }
 217 server{COLON}                   { YDVAR(0, VAR_SERVER) }
 218 qname-minimisation{COLON}       { YDVAR(1, VAR_QNAME_MINIMISATION) }
 219 qname-minimisation-strict{COLON} { YDVAR(1, VAR_QNAME_MINIMISATION_STRICT) }
 220 num-threads{COLON}              { YDVAR(1, VAR_NUM_THREADS) }
 221 verbosity{COLON}                { YDVAR(1, VAR_VERBOSITY) }
 222 port{COLON}                     { YDVAR(1, VAR_PORT) }
 223 outgoing-range{COLON}           { YDVAR(1, VAR_OUTGOING_RANGE) }
 224 outgoing-port-permit{COLON}     { YDVAR(1, VAR_OUTGOING_PORT_PERMIT) }
 225 outgoing-port-avoid{COLON}      { YDVAR(1, VAR_OUTGOING_PORT_AVOID) }
 226 outgoing-num-tcp{COLON}         { YDVAR(1, VAR_OUTGOING_NUM_TCP) }
 227 incoming-num-tcp{COLON}         { YDVAR(1, VAR_INCOMING_NUM_TCP) }
 228 do-ip4{COLON}                   { YDVAR(1, VAR_DO_IP4) }
 229 do-ip6{COLON}                   { YDVAR(1, VAR_DO_IP6) }
 230 do-nat64{COLON}                 { YDVAR(1, VAR_DO_NAT64) }
 231 prefer-ip4{COLON}               { YDVAR(1, VAR_PREFER_IP4) }
 232 prefer-ip6{COLON}               { YDVAR(1, VAR_PREFER_IP6) }
 233 do-udp{COLON}                   { YDVAR(1, VAR_DO_UDP) }
 234 do-tcp{COLON}                   { YDVAR(1, VAR_DO_TCP) }
 235 tcp-upstream{COLON}             { YDVAR(1, VAR_TCP_UPSTREAM) }
 236 tcp-mss{COLON}                  { YDVAR(1, VAR_TCP_MSS) }
 237 outgoing-tcp-mss{COLON}         { YDVAR(1, VAR_OUTGOING_TCP_MSS) }
 238 tcp-idle-timeout{COLON}         { YDVAR(1, VAR_TCP_IDLE_TIMEOUT) }
 239 max-reuse-tcp-queries{COLON}    { YDVAR(1, VAR_MAX_REUSE_TCP_QUERIES) }
 240 tcp-reuse-timeout{COLON}        { YDVAR(1, VAR_TCP_REUSE_TIMEOUT) }
 241 tcp-auth-query-timeout{COLON}   { YDVAR(1, VAR_TCP_AUTH_QUERY_TIMEOUT) }
 242 edns-tcp-keepalive{COLON}       { YDVAR(1, VAR_EDNS_TCP_KEEPALIVE) }
 243 edns-tcp-keepalive-timeout{COLON} { YDVAR(1, VAR_EDNS_TCP_KEEPALIVE_TIMEOUT) }
 244 sock-queue-timeout{COLON} { YDVAR(1, VAR_SOCK_QUEUE_TIMEOUT) }
 245 ssl-upstream{COLON}             { YDVAR(1, VAR_SSL_UPSTREAM) }
 246 tls-upstream{COLON}             { YDVAR(1, VAR_SSL_UPSTREAM) }
 247 ssl-service-key{COLON}          { YDVAR(1, VAR_SSL_SERVICE_KEY) }
 248 tls-service-key{COLON}          { YDVAR(1, VAR_SSL_SERVICE_KEY) }
 249 ssl-service-pem{COLON}          { YDVAR(1, VAR_SSL_SERVICE_PEM) }
 250 tls-service-pem{COLON}          { YDVAR(1, VAR_SSL_SERVICE_PEM) }
 251 ssl-port{COLON}                 { YDVAR(1, VAR_SSL_PORT) }
 252 tls-port{COLON}                 { YDVAR(1, VAR_SSL_PORT) }
 253 ssl-cert-bundle{COLON}          { YDVAR(1, VAR_TLS_CERT_BUNDLE) }
 254 tls-cert-bundle{COLON}          { YDVAR(1, VAR_TLS_CERT_BUNDLE) }
 255 tls-win-cert{COLON}             { YDVAR(1, VAR_TLS_WIN_CERT) }
 256 tls-system-cert{COLON}          { YDVAR(1, VAR_TLS_WIN_CERT) }
 257 additional-ssl-port{COLON}      { YDVAR(1, VAR_TLS_ADDITIONAL_PORT) }
 258 additional-tls-port{COLON}      { YDVAR(1, VAR_TLS_ADDITIONAL_PORT) }
 259 tls-additional-ports{COLON}     { YDVAR(1, VAR_TLS_ADDITIONAL_PORT) }
 260 tls-additional-port{COLON}      { YDVAR(1, VAR_TLS_ADDITIONAL_PORT) }
 261 tls-session-ticket-keys{COLON}  { YDVAR(1, VAR_TLS_SESSION_TICKET_KEYS) }
 262 tls-ciphers{COLON}              { YDVAR(1, VAR_TLS_CIPHERS) }
 263 tls-ciphersuites{COLON}         { YDVAR(1, VAR_TLS_CIPHERSUITES) }
 264 tls-use-sni{COLON}              { YDVAR(1, VAR_TLS_USE_SNI) }
 265 https-port{COLON}               { YDVAR(1, VAR_HTTPS_PORT) }
 266 http-endpoint{COLON}            { YDVAR(1, VAR_HTTP_ENDPOINT) }
 267 http-max-streams{COLON}         { YDVAR(1, VAR_HTTP_MAX_STREAMS) }
 268 http-query-buffer-size{COLON}   { YDVAR(1, VAR_HTTP_QUERY_BUFFER_SIZE) }
 269 http-response-buffer-size{COLON} { YDVAR(1, VAR_HTTP_RESPONSE_BUFFER_SIZE) }
 270 http-nodelay{COLON}             { YDVAR(1, VAR_HTTP_NODELAY) }
 271 http-notls-downstream{COLON}    { YDVAR(1, VAR_HTTP_NOTLS_DOWNSTREAM) }
 272 use-systemd{COLON}              { YDVAR(1, VAR_USE_SYSTEMD) }
 273 do-daemonize{COLON}             { YDVAR(1, VAR_DO_DAEMONIZE) }
 274 interface{COLON}                { YDVAR(1, VAR_INTERFACE) }
 275 ip-address{COLON}               { YDVAR(1, VAR_INTERFACE) }
 276 outgoing-interface{COLON}       { YDVAR(1, VAR_OUTGOING_INTERFACE) }
 277 interface-automatic{COLON}      { YDVAR(1, VAR_INTERFACE_AUTOMATIC) }
 278 interface-automatic-ports{COLON} { YDVAR(1, VAR_INTERFACE_AUTOMATIC_PORTS) }
 279 so-rcvbuf{COLON}                { YDVAR(1, VAR_SO_RCVBUF) }
 280 so-sndbuf{COLON}                { YDVAR(1, VAR_SO_SNDBUF) }
 281 so-reuseport{COLON}             { YDVAR(1, VAR_SO_REUSEPORT) }
 282 ip-transparent{COLON}           { YDVAR(1, VAR_IP_TRANSPARENT) }
 283 ip-freebind{COLON}              { YDVAR(1, VAR_IP_FREEBIND) }
 284 ip-dscp{COLON}          { YDVAR(1, VAR_IP_DSCP) }
 285 chroot{COLON}                   { YDVAR(1, VAR_CHROOT) }
 286 username{COLON}                 { YDVAR(1, VAR_USERNAME) }
 287 directory{COLON}                { YDVAR(1, VAR_DIRECTORY) }
 288 logfile{COLON}                  { YDVAR(1, VAR_LOGFILE) }
 289 pidfile{COLON}                  { YDVAR(1, VAR_PIDFILE) }
 290 root-hints{COLON}               { YDVAR(1, VAR_ROOT_HINTS) }
 291 stream-wait-size{COLON}         { YDVAR(1, VAR_STREAM_WAIT_SIZE) }
 292 edns-buffer-size{COLON}         { YDVAR(1, VAR_EDNS_BUFFER_SIZE) }
 293 msg-buffer-size{COLON}          { YDVAR(1, VAR_MSG_BUFFER_SIZE) }
 294 msg-cache-size{COLON}           { YDVAR(1, VAR_MSG_CACHE_SIZE) }
 295 msg-cache-slabs{COLON}          { YDVAR(1, VAR_MSG_CACHE_SLABS) }
 296 rrset-cache-size{COLON}         { YDVAR(1, VAR_RRSET_CACHE_SIZE) }
 297 rrset-cache-slabs{COLON}        { YDVAR(1, VAR_RRSET_CACHE_SLABS) }
 298 cache-max-ttl{COLON}            { YDVAR(1, VAR_CACHE_MAX_TTL) }
 299 cache-max-negative-ttl{COLON}   { YDVAR(1, VAR_CACHE_MAX_NEGATIVE_TTL) }
 300 cache-min-ttl{COLON}            { YDVAR(1, VAR_CACHE_MIN_TTL) }
 301 infra-host-ttl{COLON}           { YDVAR(1, VAR_INFRA_HOST_TTL) }
 302 infra-lame-ttl{COLON}           { YDVAR(1, VAR_INFRA_LAME_TTL) }
 303 infra-cache-slabs{COLON}        { YDVAR(1, VAR_INFRA_CACHE_SLABS) }
 304 infra-cache-numhosts{COLON}     { YDVAR(1, VAR_INFRA_CACHE_NUMHOSTS) }
 305 infra-cache-lame-size{COLON}    { YDVAR(1, VAR_INFRA_CACHE_LAME_SIZE) }
 306 infra-cache-min-rtt{COLON}      { YDVAR(1, VAR_INFRA_CACHE_MIN_RTT) }
 307 infra-cache-max-rtt{COLON}      { YDVAR(1, VAR_INFRA_CACHE_MAX_RTT) }
 308 infra-keep-probing{COLON}       { YDVAR(1, VAR_INFRA_KEEP_PROBING) }
 309 num-queries-per-thread{COLON}   { YDVAR(1, VAR_NUM_QUERIES_PER_THREAD) }
 310 jostle-timeout{COLON}           { YDVAR(1, VAR_JOSTLE_TIMEOUT) }
 311 delay-close{COLON}              { YDVAR(1, VAR_DELAY_CLOSE) }
 312 udp-connect{COLON}              { YDVAR(1, VAR_UDP_CONNECT) }
 313 target-fetch-policy{COLON}      { YDVAR(1, VAR_TARGET_FETCH_POLICY) }
 314 harden-short-bufsize{COLON}     { YDVAR(1, VAR_HARDEN_SHORT_BUFSIZE) }
 315 harden-large-queries{COLON}     { YDVAR(1, VAR_HARDEN_LARGE_QUERIES) }
 316 harden-glue{COLON}              { YDVAR(1, VAR_HARDEN_GLUE) }
 317 harden-dnssec-stripped{COLON}   { YDVAR(1, VAR_HARDEN_DNSSEC_STRIPPED) }
 318 harden-below-nxdomain{COLON}    { YDVAR(1, VAR_HARDEN_BELOW_NXDOMAIN) }
 319 harden-referral-path{COLON}     { YDVAR(1, VAR_HARDEN_REFERRAL_PATH) }
 320 harden-algo-downgrade{COLON}    { YDVAR(1, VAR_HARDEN_ALGO_DOWNGRADE) }
 321 harden-unknown-additional{COLON}        { YDVAR(1, VAR_HARDEN_UNKNOWN_ADDITIONAL) }
 322 use-caps-for-id{COLON}          { YDVAR(1, VAR_USE_CAPS_FOR_ID) }
 323 caps-whitelist{COLON}           { YDVAR(1, VAR_CAPS_WHITELIST) }
 324 caps-exempt{COLON}              { YDVAR(1, VAR_CAPS_WHITELIST) }
 325 unwanted-reply-threshold{COLON} { YDVAR(1, VAR_UNWANTED_REPLY_THRESHOLD) }
 326 private-address{COLON}          { YDVAR(1, VAR_PRIVATE_ADDRESS) }
 327 private-domain{COLON}           { YDVAR(1, VAR_PRIVATE_DOMAIN) }
 328 prefetch-key{COLON}             { YDVAR(1, VAR_PREFETCH_KEY) }
 329 prefetch{COLON}                 { YDVAR(1, VAR_PREFETCH) }
 330 deny-any{COLON}                 { YDVAR(1, VAR_DENY_ANY) }
 331 stub-zone{COLON}                { YDVAR(0, VAR_STUB_ZONE) }
 332 name{COLON}                     { YDVAR(1, VAR_NAME) }
 333 stub-addr{COLON}                { YDVAR(1, VAR_STUB_ADDR) }
 334 stub-host{COLON}                { YDVAR(1, VAR_STUB_HOST) }
 335 stub-prime{COLON}               { YDVAR(1, VAR_STUB_PRIME) }
 336 stub-first{COLON}               { YDVAR(1, VAR_STUB_FIRST) }
 337 stub-no-cache{COLON}            { YDVAR(1, VAR_STUB_NO_CACHE) }
 338 stub-ssl-upstream{COLON}        { YDVAR(1, VAR_STUB_SSL_UPSTREAM) }
 339 stub-tls-upstream{COLON}        { YDVAR(1, VAR_STUB_SSL_UPSTREAM) }
 340 stub-tcp-upstream{COLON}        { YDVAR(1, VAR_STUB_TCP_UPSTREAM) }
 341 forward-zone{COLON}             { YDVAR(0, VAR_FORWARD_ZONE) }
 342 forward-addr{COLON}             { YDVAR(1, VAR_FORWARD_ADDR) }
 343 forward-host{COLON}             { YDVAR(1, VAR_FORWARD_HOST) }
 344 forward-first{COLON}            { YDVAR(1, VAR_FORWARD_FIRST) }
 345 forward-no-cache{COLON}         { YDVAR(1, VAR_FORWARD_NO_CACHE) }
 346 forward-ssl-upstream{COLON}     { YDVAR(1, VAR_FORWARD_SSL_UPSTREAM) }
 347 forward-tls-upstream{COLON}     { YDVAR(1, VAR_FORWARD_SSL_UPSTREAM) }
 348 forward-tcp-upstream{COLON}     { YDVAR(1, VAR_FORWARD_TCP_UPSTREAM) }
 349 auth-zone{COLON}                { YDVAR(0, VAR_AUTH_ZONE) }
 350 rpz{COLON}                      { YDVAR(0, VAR_RPZ) }
 351 tags{COLON}                     { YDVAR(1, VAR_TAGS) }
 352 rpz-action-override{COLON}      { YDVAR(1, VAR_RPZ_ACTION_OVERRIDE) }
 353 rpz-cname-override{COLON}       { YDVAR(1, VAR_RPZ_CNAME_OVERRIDE) }
 354 rpz-log{COLON}                  { YDVAR(1, VAR_RPZ_LOG) }
 355 rpz-log-name{COLON}             { YDVAR(1, VAR_RPZ_LOG_NAME) }
 356 rpz-signal-nxdomain-ra{COLON}   { YDVAR(1, VAR_RPZ_SIGNAL_NXDOMAIN_RA) }
 357 zonefile{COLON}                 { YDVAR(1, VAR_ZONEFILE) }
 358 master{COLON}                   { YDVAR(1, VAR_MASTER) }
 359 primary{COLON}                  { YDVAR(1, VAR_MASTER) }
 360 url{COLON}                      { YDVAR(1, VAR_URL) }
 361 allow-notify{COLON}             { YDVAR(1, VAR_ALLOW_NOTIFY) }
 362 for-downstream{COLON}           { YDVAR(1, VAR_FOR_DOWNSTREAM) }
 363 for-upstream{COLON}             { YDVAR(1, VAR_FOR_UPSTREAM) }
 364 fallback-enabled{COLON}         { YDVAR(1, VAR_FALLBACK_ENABLED) }
 365 view{COLON}                     { YDVAR(0, VAR_VIEW) }
 366 view-first{COLON}               { YDVAR(1, VAR_VIEW_FIRST) }
 367 do-not-query-address{COLON}     { YDVAR(1, VAR_DO_NOT_QUERY_ADDRESS) }
 368 do-not-query-localhost{COLON}   { YDVAR(1, VAR_DO_NOT_QUERY_LOCALHOST) }
 369 access-control{COLON}           { YDVAR(2, VAR_ACCESS_CONTROL) }
 370 interface-action{COLON}         { YDVAR(2, VAR_INTERFACE_ACTION) }
 371 send-client-subnet{COLON}       { YDVAR(1, VAR_SEND_CLIENT_SUBNET) }
 372 client-subnet-zone{COLON}       { YDVAR(1, VAR_CLIENT_SUBNET_ZONE) }
 373 client-subnet-always-forward{COLON} { YDVAR(1, VAR_CLIENT_SUBNET_ALWAYS_FORWARD) }
 374 client-subnet-opcode{COLON}     { YDVAR(1, VAR_CLIENT_SUBNET_OPCODE) }
 375 max-client-subnet-ipv4{COLON}   { YDVAR(1, VAR_MAX_CLIENT_SUBNET_IPV4) }
 376 max-client-subnet-ipv6{COLON}   { YDVAR(1, VAR_MAX_CLIENT_SUBNET_IPV6) }
 377 min-client-subnet-ipv4{COLON}   { YDVAR(1, VAR_MIN_CLIENT_SUBNET_IPV4) }
 378 min-client-subnet-ipv6{COLON}   { YDVAR(1, VAR_MIN_CLIENT_SUBNET_IPV6) }
 379 max-ecs-tree-size-ipv4{COLON}   { YDVAR(1, VAR_MAX_ECS_TREE_SIZE_IPV4) }
 380 max-ecs-tree-size-ipv6{COLON}   { YDVAR(1, VAR_MAX_ECS_TREE_SIZE_IPV6) }
 381 hide-identity{COLON}            { YDVAR(1, VAR_HIDE_IDENTITY) }
 382 hide-version{COLON}             { YDVAR(1, VAR_HIDE_VERSION) }
 383 hide-trustanchor{COLON}         { YDVAR(1, VAR_HIDE_TRUSTANCHOR) }
 384 hide-http-user-agent{COLON}             { YDVAR(1, VAR_HIDE_HTTP_USER_AGENT) }
 385 identity{COLON}                 { YDVAR(1, VAR_IDENTITY) }
 386 version{COLON}                  { YDVAR(1, VAR_VERSION) }
 387 http-user-agent{COLON}                  { YDVAR(1, VAR_HTTP_USER_AGENT) }
 388 module-config{COLON}            { YDVAR(1, VAR_MODULE_CONF) }
 389 dlv-anchor{COLON}               { YDVAR(1, VAR_DLV_ANCHOR) }
 390 dlv-anchor-file{COLON}          { YDVAR(1, VAR_DLV_ANCHOR_FILE) }
 391 trust-anchor-file{COLON}        { YDVAR(1, VAR_TRUST_ANCHOR_FILE) }
 392 auto-trust-anchor-file{COLON}   { YDVAR(1, VAR_AUTO_TRUST_ANCHOR_FILE) }
 393 trusted-keys-file{COLON}        { YDVAR(1, VAR_TRUSTED_KEYS_FILE) }
 394 trust-anchor{COLON}             { YDVAR(1, VAR_TRUST_ANCHOR) }
 395 trust-anchor-signaling{COLON}   { YDVAR(1, VAR_TRUST_ANCHOR_SIGNALING) }
 396 root-key-sentinel{COLON}        { YDVAR(1, VAR_ROOT_KEY_SENTINEL) }
 397 val-override-date{COLON}        { YDVAR(1, VAR_VAL_OVERRIDE_DATE) }
 398 val-sig-skew-min{COLON}         { YDVAR(1, VAR_VAL_SIG_SKEW_MIN) }
 399 val-sig-skew-max{COLON}         { YDVAR(1, VAR_VAL_SIG_SKEW_MAX) }
 400 val-max-restart{COLON}          { YDVAR(1, VAR_VAL_MAX_RESTART) }
 401 val-bogus-ttl{COLON}            { YDVAR(1, VAR_BOGUS_TTL) }
 402 val-clean-additional{COLON}     { YDVAR(1, VAR_VAL_CLEAN_ADDITIONAL) }
 403 val-permissive-mode{COLON}      { YDVAR(1, VAR_VAL_PERMISSIVE_MODE) }
 404 aggressive-nsec{COLON}          { YDVAR(1, VAR_AGGRESSIVE_NSEC) }
 405 ignore-cd-flag{COLON}           { YDVAR(1, VAR_IGNORE_CD_FLAG) }
 406 disable-edns-do{COLON}          { YDVAR(1, VAR_DISABLE_EDNS_DO) }
 407 serve-expired{COLON}            { YDVAR(1, VAR_SERVE_EXPIRED) }
 408 serve-expired-ttl{COLON}        { YDVAR(1, VAR_SERVE_EXPIRED_TTL) }
 409 serve-expired-ttl-reset{COLON}  { YDVAR(1, VAR_SERVE_EXPIRED_TTL_RESET) }
 410 serve-expired-reply-ttl{COLON}  { YDVAR(1, VAR_SERVE_EXPIRED_REPLY_TTL) }
 411 serve-expired-client-timeout{COLON}     { YDVAR(1, VAR_SERVE_EXPIRED_CLIENT_TIMEOUT) }
 412 ede-serve-expired{COLON}        { YDVAR(1, VAR_EDE_SERVE_EXPIRED) }
 413 serve-original-ttl{COLON}       { YDVAR(1, VAR_SERVE_ORIGINAL_TTL) }
 414 fake-dsa{COLON}                 { YDVAR(1, VAR_FAKE_DSA) }
 415 fake-sha1{COLON}                { YDVAR(1, VAR_FAKE_SHA1) }
 416 val-log-level{COLON}            { YDVAR(1, VAR_VAL_LOG_LEVEL) }
 417 key-cache-size{COLON}           { YDVAR(1, VAR_KEY_CACHE_SIZE) }
 418 key-cache-slabs{COLON}          { YDVAR(1, VAR_KEY_CACHE_SLABS) }
 419 neg-cache-size{COLON}           { YDVAR(1, VAR_NEG_CACHE_SIZE) }
 420 val-nsec3-keysize-iterations{COLON}     {
 421                                   YDVAR(1, VAR_VAL_NSEC3_KEYSIZE_ITERATIONS) }
 422 zonemd-permissive-mode{COLON}   { YDVAR(1, VAR_ZONEMD_PERMISSIVE_MODE) }
 423 zonemd-check{COLON}             { YDVAR(1, VAR_ZONEMD_CHECK) }
 424 zonemd-reject-absence{COLON}    { YDVAR(1, VAR_ZONEMD_REJECT_ABSENCE) }
 425 add-holddown{COLON}             { YDVAR(1, VAR_ADD_HOLDDOWN) }
 426 del-holddown{COLON}             { YDVAR(1, VAR_DEL_HOLDDOWN) }
 427 keep-missing{COLON}             { YDVAR(1, VAR_KEEP_MISSING) }
 428 permit-small-holddown{COLON}    { YDVAR(1, VAR_PERMIT_SMALL_HOLDDOWN) }
 429 use-syslog{COLON}               { YDVAR(1, VAR_USE_SYSLOG) }
 430 log-identity{COLON}             { YDVAR(1, VAR_LOG_IDENTITY) }
 431 log-time-ascii{COLON}           { YDVAR(1, VAR_LOG_TIME_ASCII) }
 432 log-queries{COLON}              { YDVAR(1, VAR_LOG_QUERIES) }
 433 log-replies{COLON}              { YDVAR(1, VAR_LOG_REPLIES) }
 434 log-tag-queryreply{COLON}       { YDVAR(1, VAR_LOG_TAG_QUERYREPLY) }
 435 log-local-actions{COLON}       { YDVAR(1, VAR_LOG_LOCAL_ACTIONS) }
 436 log-servfail{COLON}             { YDVAR(1, VAR_LOG_SERVFAIL) }
 437 local-zone{COLON}               { YDVAR(2, VAR_LOCAL_ZONE) }
 438 local-data{COLON}               { YDVAR(1, VAR_LOCAL_DATA) }
 439 local-data-ptr{COLON}           { YDVAR(1, VAR_LOCAL_DATA_PTR) }
 440 unblock-lan-zones{COLON}        { YDVAR(1, VAR_UNBLOCK_LAN_ZONES) }
 441 insecure-lan-zones{COLON}       { YDVAR(1, VAR_INSECURE_LAN_ZONES) }
 442 statistics-interval{COLON}      { YDVAR(1, VAR_STATISTICS_INTERVAL) }
 443 statistics-cumulative{COLON}    { YDVAR(1, VAR_STATISTICS_CUMULATIVE) }
 444 extended-statistics{COLON}      { YDVAR(1, VAR_EXTENDED_STATISTICS) }
 445 statistics-inhibit-zero{COLON}  { YDVAR(1, VAR_STATISTICS_INHIBIT_ZERO) }
 446 shm-enable{COLON}               { YDVAR(1, VAR_SHM_ENABLE) }
 447 shm-key{COLON}                  { YDVAR(1, VAR_SHM_KEY) }
 448 remote-control{COLON}           { YDVAR(0, VAR_REMOTE_CONTROL) }
 449 control-enable{COLON}           { YDVAR(1, VAR_CONTROL_ENABLE) }
 450 control-interface{COLON}        { YDVAR(1, VAR_CONTROL_INTERFACE) }
 451 control-port{COLON}             { YDVAR(1, VAR_CONTROL_PORT) }
 452 control-use-cert{COLON}         { YDVAR(1, VAR_CONTROL_USE_CERT) }
 453 server-key-file{COLON}          { YDVAR(1, VAR_SERVER_KEY_FILE) }
 454 server-cert-file{COLON}         { YDVAR(1, VAR_SERVER_CERT_FILE) }
 455 control-key-file{COLON}         { YDVAR(1, VAR_CONTROL_KEY_FILE) }
 456 control-cert-file{COLON}        { YDVAR(1, VAR_CONTROL_CERT_FILE) }
 457 python-script{COLON}            { YDVAR(1, VAR_PYTHON_SCRIPT) }
 458 python{COLON}                   { YDVAR(0, VAR_PYTHON) }
 459 dynlib-file{COLON}              { YDVAR(1, VAR_DYNLIB_FILE) }
 460 dynlib{COLON}                   { YDVAR(0, VAR_DYNLIB) }
 461 domain-insecure{COLON}          { YDVAR(1, VAR_DOMAIN_INSECURE) }
 462 minimal-responses{COLON}        { YDVAR(1, VAR_MINIMAL_RESPONSES) }
 463 rrset-roundrobin{COLON}         { YDVAR(1, VAR_RRSET_ROUNDROBIN) }
 464 unknown-server-time-limit{COLON} { YDVAR(1, VAR_UNKNOWN_SERVER_TIME_LIMIT) }
 465 max-udp-size{COLON}             { YDVAR(1, VAR_MAX_UDP_SIZE) }
 466 dns64-prefix{COLON}             { YDVAR(1, VAR_DNS64_PREFIX) }
 467 dns64-synthall{COLON}           { YDVAR(1, VAR_DNS64_SYNTHALL) }
 468 dns64-ignore-aaaa{COLON}        { YDVAR(1, VAR_DNS64_IGNORE_AAAA) }
 469 nat64-prefix{COLON}             { YDVAR(1, VAR_NAT64_PREFIX) }
 470 define-tag{COLON}               { YDVAR(1, VAR_DEFINE_TAG) }
 471 local-zone-tag{COLON}           { YDVAR(2, VAR_LOCAL_ZONE_TAG) }
 472 access-control-tag{COLON}       { YDVAR(2, VAR_ACCESS_CONTROL_TAG) }
 473 access-control-tag-action{COLON} { YDVAR(3, VAR_ACCESS_CONTROL_TAG_ACTION) }
 474 access-control-tag-data{COLON}  { YDVAR(3, VAR_ACCESS_CONTROL_TAG_DATA) }
 475 access-control-view{COLON}      { YDVAR(2, VAR_ACCESS_CONTROL_VIEW) }
 476 interface-tag{COLON}            { YDVAR(2, VAR_INTERFACE_TAG) }
 477 interface-tag-action{COLON}     { YDVAR(3, VAR_INTERFACE_TAG_ACTION) }
 478 interface-tag-data{COLON}       { YDVAR(3, VAR_INTERFACE_TAG_DATA) }
 479 interface-view{COLON}           { YDVAR(2, VAR_INTERFACE_VIEW) }
 480 local-zone-override{COLON}      { YDVAR(3, VAR_LOCAL_ZONE_OVERRIDE) }
 481 dnstap{COLON}                   { YDVAR(0, VAR_DNSTAP) }
 482 dnstap-enable{COLON}            { YDVAR(1, VAR_DNSTAP_ENABLE) }
 483 dnstap-bidirectional{COLON}     { YDVAR(1, VAR_DNSTAP_BIDIRECTIONAL) }
 484 dnstap-socket-path{COLON}       { YDVAR(1, VAR_DNSTAP_SOCKET_PATH) }
 485 dnstap-ip{COLON}                { YDVAR(1, VAR_DNSTAP_IP) }
 486 dnstap-tls{COLON}               { YDVAR(1, VAR_DNSTAP_TLS) }
 487 dnstap-tls-server-name{COLON}   { YDVAR(1, VAR_DNSTAP_TLS_SERVER_NAME) }
 488 dnstap-tls-cert-bundle{COLON}   { YDVAR(1, VAR_DNSTAP_TLS_CERT_BUNDLE) }
 489 dnstap-tls-client-key-file{COLON}       {
 490                 YDVAR(1, VAR_DNSTAP_TLS_CLIENT_KEY_FILE) }
 491 dnstap-tls-client-cert-file{COLON}      {
 492                 YDVAR(1, VAR_DNSTAP_TLS_CLIENT_CERT_FILE) }
 493 dnstap-send-identity{COLON}     { YDVAR(1, VAR_DNSTAP_SEND_IDENTITY) }
 494 dnstap-send-version{COLON}      { YDVAR(1, VAR_DNSTAP_SEND_VERSION) }
 495 dnstap-identity{COLON}          { YDVAR(1, VAR_DNSTAP_IDENTITY) }
 496 dnstap-version{COLON}           { YDVAR(1, VAR_DNSTAP_VERSION) }
 497 dnstap-log-resolver-query-messages{COLON}       {
 498                 YDVAR(1, VAR_DNSTAP_LOG_RESOLVER_QUERY_MESSAGES) }
 499 dnstap-log-resolver-response-messages{COLON}    {
 500                 YDVAR(1, VAR_DNSTAP_LOG_RESOLVER_RESPONSE_MESSAGES) }
 501 dnstap-log-client-query-messages{COLON}         {
 502                 YDVAR(1, VAR_DNSTAP_LOG_CLIENT_QUERY_MESSAGES) }
 503 dnstap-log-client-response-messages{COLON}      {
 504                 YDVAR(1, VAR_DNSTAP_LOG_CLIENT_RESPONSE_MESSAGES) }
 505 dnstap-log-forwarder-query-messages{COLON}      {
 506                 YDVAR(1, VAR_DNSTAP_LOG_FORWARDER_QUERY_MESSAGES) }
 507 dnstap-log-forwarder-response-messages{COLON}   {
 508                 YDVAR(1, VAR_DNSTAP_LOG_FORWARDER_RESPONSE_MESSAGES) }
 509 disable-dnssec-lame-check{COLON} { YDVAR(1, VAR_DISABLE_DNSSEC_LAME_CHECK) }
 510 ip-ratelimit{COLON}             { YDVAR(1, VAR_IP_RATELIMIT) }
 511 ip-ratelimit-cookie{COLON}      { YDVAR(1, VAR_IP_RATELIMIT_COOKIE) }
 512 ratelimit{COLON}                { YDVAR(1, VAR_RATELIMIT) }
 513 ip-ratelimit-slabs{COLON}               { YDVAR(1, VAR_IP_RATELIMIT_SLABS) }
 514 ratelimit-slabs{COLON}          { YDVAR(1, VAR_RATELIMIT_SLABS) }
 515 ip-ratelimit-size{COLON}                { YDVAR(1, VAR_IP_RATELIMIT_SIZE) }
 516 ratelimit-size{COLON}           { YDVAR(1, VAR_RATELIMIT_SIZE) }
 517 ratelimit-for-domain{COLON}     { YDVAR(2, VAR_RATELIMIT_FOR_DOMAIN) }
 518 ratelimit-below-domain{COLON}   { YDVAR(2, VAR_RATELIMIT_BELOW_DOMAIN) }
 519 ip-ratelimit-factor{COLON}              { YDVAR(1, VAR_IP_RATELIMIT_FACTOR) }
 520 ratelimit-factor{COLON}         { YDVAR(1, VAR_RATELIMIT_FACTOR) }
 521 ip-ratelimit-backoff{COLON}             { YDVAR(1, VAR_IP_RATELIMIT_BACKOFF) }
 522 ratelimit-backoff{COLON}                { YDVAR(1, VAR_RATELIMIT_BACKOFF) }
 523 outbound-msg-retry{COLON}               { YDVAR(1, VAR_OUTBOUND_MSG_RETRY) }
 524 max-sent-count{COLON}           { YDVAR(1, VAR_MAX_SENT_COUNT) }
 525 max-query-restarts{COLON}       { YDVAR(1, VAR_MAX_QUERY_RESTARTS) }
 526 low-rtt{COLON}                  { YDVAR(1, VAR_LOW_RTT) }
 527 fast-server-num{COLON}          { YDVAR(1, VAR_FAST_SERVER_NUM) }
 528 low-rtt-pct{COLON}              { YDVAR(1, VAR_FAST_SERVER_PERMIL) }
 529 low-rtt-permil{COLON}           { YDVAR(1, VAR_FAST_SERVER_PERMIL) }
 530 fast-server-permil{COLON}       { YDVAR(1, VAR_FAST_SERVER_PERMIL) }
 531 response-ip-tag{COLON}          { YDVAR(2, VAR_RESPONSE_IP_TAG) }
 532 response-ip{COLON}              { YDVAR(2, VAR_RESPONSE_IP) }
 533 response-ip-data{COLON}         { YDVAR(2, VAR_RESPONSE_IP_DATA) }
 534 dnscrypt{COLON}                 { YDVAR(0, VAR_DNSCRYPT) }
 535 dnscrypt-enable{COLON}          { YDVAR(1, VAR_DNSCRYPT_ENABLE) }
 536 dnscrypt-port{COLON}            { YDVAR(1, VAR_DNSCRYPT_PORT) }
 537 dnscrypt-provider{COLON}        { YDVAR(1, VAR_DNSCRYPT_PROVIDER) }
 538 dnscrypt-secret-key{COLON}      { YDVAR(1, VAR_DNSCRYPT_SECRET_KEY) }
 539 dnscrypt-provider-cert{COLON}   { YDVAR(1, VAR_DNSCRYPT_PROVIDER_CERT) }
 540 dnscrypt-provider-cert-rotated{COLON}   { YDVAR(1, VAR_DNSCRYPT_PROVIDER_CERT_ROTATED) }
 541 dnscrypt-shared-secret-cache-size{COLON}        {
 542                 YDVAR(1, VAR_DNSCRYPT_SHARED_SECRET_CACHE_SIZE) }
 543 dnscrypt-shared-secret-cache-slabs{COLON}       {
 544                 YDVAR(1, VAR_DNSCRYPT_SHARED_SECRET_CACHE_SLABS) }
 545 dnscrypt-nonce-cache-size{COLON}        { YDVAR(1, VAR_DNSCRYPT_NONCE_CACHE_SIZE) }
 546 dnscrypt-nonce-cache-slabs{COLON}       { YDVAR(1, VAR_DNSCRYPT_NONCE_CACHE_SLABS) }
 547 pad-responses{COLON}            { YDVAR(1, VAR_PAD_RESPONSES) }
 548 pad-responses-block-size{COLON} { YDVAR(1, VAR_PAD_RESPONSES_BLOCK_SIZE) }
 549 pad-queries{COLON}              { YDVAR(1, VAR_PAD_QUERIES) }
 550 pad-queries-block-size{COLON}   { YDVAR(1, VAR_PAD_QUERIES_BLOCK_SIZE) }
 551 ipsecmod-enabled{COLON}         { YDVAR(1, VAR_IPSECMOD_ENABLED) }
 552 ipsecmod-ignore-bogus{COLON}    { YDVAR(1, VAR_IPSECMOD_IGNORE_BOGUS) }
 553 ipsecmod-hook{COLON}            { YDVAR(1, VAR_IPSECMOD_HOOK) }
 554 ipsecmod-max-ttl{COLON}         { YDVAR(1, VAR_IPSECMOD_MAX_TTL) }
 555 ipsecmod-whitelist{COLON}       { YDVAR(1, VAR_IPSECMOD_WHITELIST) }
 556 ipsecmod-allow{COLON}           { YDVAR(1, VAR_IPSECMOD_WHITELIST) }
 557 ipsecmod-strict{COLON}          { YDVAR(1, VAR_IPSECMOD_STRICT) }
 558 cachedb{COLON}                  { YDVAR(0, VAR_CACHEDB) }
 559 backend{COLON}                  { YDVAR(1, VAR_CACHEDB_BACKEND) }
 560 secret-seed{COLON}              { YDVAR(1, VAR_CACHEDB_SECRETSEED) }
 561 cachedb-no-store{COLON}         { YDVAR(1, VAR_CACHEDB_NO_STORE) }
 562 redis-server-host{COLON}        { YDVAR(1, VAR_CACHEDB_REDISHOST) }
 563 redis-server-port{COLON}        { YDVAR(1, VAR_CACHEDB_REDISPORT) }
 564 redis-server-path{COLON}        { YDVAR(1, VAR_CACHEDB_REDISPATH) }
 565 redis-server-password{COLON}    { YDVAR(1, VAR_CACHEDB_REDISPASSWORD) }
 566 redis-timeout{COLON}            { YDVAR(1, VAR_CACHEDB_REDISTIMEOUT) }
 567 redis-expire-records{COLON}     { YDVAR(1, VAR_CACHEDB_REDISEXPIRERECORDS) }
 568 redis-logical-db{COLON}         { YDVAR(1, VAR_CACHEDB_REDISLOGICALDB) }
 569 ipset{COLON}                    { YDVAR(0, VAR_IPSET) }
 570 name-v4{COLON}                  { YDVAR(1, VAR_IPSET_NAME_V4) }
 571 name-v6{COLON}                  { YDVAR(1, VAR_IPSET_NAME_V6) }
 572 udp-upstream-without-downstream{COLON} { YDVAR(1, VAR_UDP_UPSTREAM_WITHOUT_DOWNSTREAM) }
 573 tcp-connection-limit{COLON}     { YDVAR(2, VAR_TCP_CONNECTION_LIMIT) }
 574 answer-cookie{COLON}            { YDVAR(1, VAR_ANSWER_COOKIE ) }
 575 cookie-secret{COLON}            { YDVAR(1, VAR_COOKIE_SECRET) }
 576 edns-client-string{COLON}       { YDVAR(2, VAR_EDNS_CLIENT_STRING) }
 577 edns-client-string-opcode{COLON} { YDVAR(1, VAR_EDNS_CLIENT_STRING_OPCODE) }
 578 nsid{COLON}                     { YDVAR(1, VAR_NSID ) }
 579 ede{COLON}                      { YDVAR(1, VAR_EDE ) }
 580 proxy-protocol-port{COLON}      { YDVAR(1, VAR_PROXY_PROTOCOL_PORT) }
 581 <INITIAL,val>{NEWLINE}          { LEXOUT(("NL\n")); cfg_parser->line++; }
 582
 583         /* Quoted strings. Strip leading and ending quotes */
 584 <val>\"                 { BEGIN(quotedstring); LEXOUT(("QS ")); }
 585 <quotedstring><<EOF>>   {
 586         yyerror("EOF inside quoted string");
 587         if(--num_args == 0) { BEGIN(INITIAL); }
 588         else                { BEGIN(val); }
 589 }
 590 <quotedstring>{DQANY}*  { LEXOUT(("STR(%s) ", yytext)); yymore(); }
 591 <quotedstring>{NEWLINE} { yyerror("newline inside quoted string, no end \"");
 592                           cfg_parser->line++; BEGIN(INITIAL); }
 593 <quotedstring>\" {
 594         LEXOUT(("QE "));
 595         if(--num_args == 0) { BEGIN(INITIAL); }
 596         else                { BEGIN(val); }
 597         yytext[yyleng - 1] = '\0';
 598         yylval.str = strdup(yytext);
 599         if(!yylval.str)
 600                 yyerror("out of memory");
 601         return STRING_ARG;
 602 }
 603
 604         /* Single Quoted strings. Strip leading and ending quotes */
 605 <val>\'                 { BEGIN(singlequotedstr); LEXOUT(("SQS ")); }
 606 <singlequotedstr><<EOF>>   {
 607         yyerror("EOF inside quoted string");
 608         if(--num_args == 0) { BEGIN(INITIAL); }
 609         else                { BEGIN(val); }
 610 }
 611 <singlequotedstr>{SQANY}*  { LEXOUT(("STR(%s) ", yytext)); yymore(); }
 612 <singlequotedstr>{NEWLINE} { yyerror("newline inside quoted string, no end '");
 613                              cfg_parser->line++; BEGIN(INITIAL); }
 614 <singlequotedstr>\' {
 615         LEXOUT(("SQE "));
 616         if(--num_args == 0) { BEGIN(INITIAL); }
 617         else                { BEGIN(val); }
 618         yytext[yyleng - 1] = '\0';
 619         yylval.str = strdup(yytext);
 620         if(!yylval.str)
 621                 yyerror("out of memory");
 622         return STRING_ARG;
 623 }
 624
 625         /* include: directive */
 626 <INITIAL,val>include{COLON}     {
 627         LEXOUT(("v(%s) ", yytext)); inc_prev = YYSTATE; BEGIN(include); }
 628 <include><<EOF>>        {
 629         yyerror("EOF inside include directive");
 630         BEGIN(inc_prev);
 631 }
 632 <include>{SPACE}*       { LEXOUT(("ISP ")); /* ignore */ }
 633 <include>{NEWLINE}      { LEXOUT(("NL\n")); cfg_parser->line++;}
 634 <include>\"             { LEXOUT(("IQS ")); BEGIN(include_quoted); }
 635 <include>{UNQUOTEDLETTER}*      {
 636         LEXOUT(("Iunquotedstr(%s) ", yytext));
 637         config_start_include_glob(yytext, 0);
 638         BEGIN(inc_prev);
 639 }
 640 <include_quoted><<EOF>> {
 641         yyerror("EOF inside quoted string");
 642         BEGIN(inc_prev);
 643 }
 644 <include_quoted>{DQANY}*        { LEXOUT(("ISTR(%s) ", yytext)); yymore(); }
 645 <include_quoted>{NEWLINE}       { yyerror("newline before \" in include name");
 646                                   cfg_parser->line++; BEGIN(inc_prev); }
 647 <include_quoted>\"      {
 648         LEXOUT(("IQE "));
 649         yytext[yyleng - 1] = '\0';
 650         config_start_include_glob(yytext, 0);
 651         BEGIN(inc_prev);
 652 }
 653 <INITIAL,val><<EOF>>    {
 654         LEXOUT(("LEXEOF "));
 655         yy_set_bol(1); /* Set beginning of line, so "^" rules match.  */
 656         if (!config_include_stack) {
 657                 yyterminate();
 658         } else {
 659                 int prev_toplevel = inc_toplevel;
 660                 fclose(yyin);
 661                 config_end_include();
 662                 if(prev_toplevel) return (VAR_FORCE_TOPLEVEL);
 663         }
 664 }
 665
 666         /* include-toplevel: directive */
 667 <INITIAL,val>include-toplevel{COLON} {
 668         LEXOUT(("v(%s) ", yytext)); inc_prev = YYSTATE; BEGIN(include_toplevel);
 669 }
 670 <include_toplevel><<EOF>> {
 671         yyerror("EOF inside include_toplevel directive");
 672         BEGIN(inc_prev);
 673 }
 674 <include_toplevel>{SPACE}* { LEXOUT(("ITSP ")); /* ignore */ }
 675 <include_toplevel>{NEWLINE} { LEXOUT(("NL\n")); cfg_parser->line++; }
 676 <include_toplevel>\" { LEXOUT(("ITQS ")); BEGIN(include_toplevel_quoted); }
 677 <include_toplevel>{UNQUOTEDLETTER}* {
 678         LEXOUT(("ITunquotedstr(%s) ", yytext));
 679         config_start_include_glob(yytext, 1);
 680         BEGIN(inc_prev);
 681         return (VAR_FORCE_TOPLEVEL);
 682 }
 683 <include_toplevel_quoted><<EOF>> {
 684         yyerror("EOF inside quoted string");
 685         BEGIN(inc_prev);
 686 }
 687 <include_toplevel_quoted>{DQANY}* { LEXOUT(("ITSTR(%s) ", yytext)); yymore(); }
 688 <include_toplevel_quoted>{NEWLINE} {
 689         yyerror("newline before \" in include name");
 690         cfg_parser->line++; BEGIN(inc_prev);
 691 }
 692 <include_toplevel_quoted>\" {
 693         LEXOUT(("ITQE "));
 694         yytext[yyleng - 1] = '\0';
 695         config_start_include_glob(yytext, 1);
 696         BEGIN(inc_prev);
 697         return (VAR_FORCE_TOPLEVEL);
 698 }
 699
 700 <val>{UNQUOTEDLETTER}*  { LEXOUT(("unquotedstr(%s) ", yytext));
 701                         if(--num_args == 0) { BEGIN(INITIAL); }
 702                         yylval.str = strdup(yytext); return STRING_ARG; }
 703
 704 {UNQUOTEDLETTER_NOCOLON}*       {
 705         ub_c_error_msg("unknown keyword '%s'", yytext);
 706         }
 707
 708 <*>.    {
 709         ub_c_error_msg("stray '%s'", yytext);
 710         }
 711
 712 %%