contrib/bmake/configure.in

   1 dnl
   2 dnl RCSid:
   3 dnl     $Id: configure.in,v 1.52 2014/02/15 22:27:59 sjg Exp $
   4 dnl
   5 dnl Process this file with autoconf to produce a configure script
   6 dnl
   7 AC_PREREQ(2.50)
   8 AC_INIT([bmake], [20140214], [sjg@NetBSD.org])
   9 AC_CONFIG_HEADERS(config.h)
  10
  11 dnl make srcdir absolute
  12 case "$srcdir" in
  13 /*) ;;
  14 *) srcdir=`cd $srcdir && pwd`;;
  15 esac
  16
  17 dnl
  18 AC_ARG_WITH(defshell,
  19 [  --with-defshell=SHELL  use SHELL by default - must be sh compatible, use sh or ksh to pick the internal definitions],
  20 [case "${withval}" in
  21 yes)   AC_MSG_ERROR(bad value ${withval} given for bmake DEFSHELL) ;;
  22 no)    ;;
  23 *)     case "$with_defshell" in
  24        sh)  DEFSHELL_INDEX=DEFSHELL_INDEX_SH;;  # it's the default anyway
  25        ksh) DEFSHELL_INDEX=DEFSHELL_INDEX_KSH;;
  26        csh) DEFSHELL_INDEX=DEFSHELL_INDEX_CSH;; # kidding right?
  27        *)   defshell_path=$with_defshell;;      # better be sh compatible!
  28        esac
  29        ;;
  30        esac])
  31 dnl
  32 use_meta=yes
  33 AC_ARG_WITH(meta,
  34 [ --without-meta dissable use of meta-mode],
  35 [case "${withval}" in
  36 yes|no) use_meta=${withval};;
  37 *) AC_MSG_ERROR(bad value ${withval} given for meta) ;;
  38 esac])
  39 dnl
  40 AC_ARG_WITH(filemon,
  41 [ --with-filemon=path/filemon.h indicate path to filemon.h for meta-mode],
  42 [ case "/${withval}" in
  43 /no|*/filemon.h) filemon_h="${withval}";;
  44 */filemon*) filemon_h="${withval}/filemon.h";;
  45 *) AC_MSG_ERROR(bad value ${withval} given for filemon) ;;
  46 esac],
  47 [
  48 OS=`uname -s`
  49 for d in "/usr/include/dev/filemon" "$prefix/include/dev/filemon" "$srcdir/filemon" "$srcdir/../filemon" "$srcdir/../../sys/dev/filemon"
  50 do
  51         for x in "/$OS" ""
  52         do
  53                 filemon_h="$d$x/filemon.h"
  54                 test -s "$filemon_h" && break
  55         done
  56         test -s "$filemon_h" && break
  57 done
  58 test -s "${filemon_h:-/dev/null}" || filemon_h=no
  59 ])
  60 dnl echo "Note: use_meta=$use_meta filemon_h=$filemon_h" >&6
  61 case "$use_meta" in
  62 yes)
  63         case "$filemon_h" in
  64         *.h) echo "Using: filemon=$filemon_h" >&6;;
  65         esac
  66         ;;
  67 esac
  68 dnl
  69 dnl Check for OS problems
  70 dnl Solaris's signal.h only privides sigset_t etc if one of
  71 dnl _EXTENSIONS_ _POSIX_C_SOURCE or _XOPEN_SOURCE are defined.
  72 dnl The later two seem to cause more problems than they solve so if we
  73 dnl see _EXTENSIONS_ we use it.
  74 AC_USE_SYSTEM_EXTENSIONS
  75 dnl Checks for programs.
  76 AC_PROG_CC
  77 AC_PROG_GCC_TRADITIONAL
  78 AC_PROG_INSTALL
  79 dnl Executable suffix - normally empty; .exe on os2.
  80 AC_SUBST(ac_exe_suffix)dnl
  81 dnl
  82 dnl Hurd refuses to define PATH_MAX or MAXPATHLEN
  83 if test -x /usr/bin/getconf; then
  84    bmake_path_max=`getconf PATH_MAX / 2> /dev/null`
  85 fi
  86 bmake_path_max=${bmake_path_max:-1024}
  87 if test $bmake_path_max -gt 1024; then
  88    # this is all we expect
  89    bmake_path_max=1024
  90 fi
  91 echo "Using: BMAKE_PATH_MAX=$bmake_path_max" >&6
  92 AC_SUBST(bmake_path_max)dnl
  93 dnl
  94 dnl AC_C_CROSS
  95 dnl
  96
  97 dnl Checks for header files.
  98 AC_HEADER_STDC
  99 AC_HEADER_SYS_WAIT
 100 AC_HEADER_DIRENT
 101 dnl Keep this list sorted
 102 AC_CHECK_HEADERS( \
 103         ar.h \
 104         err.h \
 105         fcntl.h \
 106         paths.h \
 107         poll.h \
 108         ranlib.h \
 109         string.h \
 110         sys/mman.h \
 111         sys/select.h \
 112         sys/socket.h \
 113         sys/sysctl.h \
 114         sys/time.h \
 115         sys/uio.h \
 116         unistd.h \
 117         utime.h \
 118         )
 119
 120 dnl Both *BSD and Linux have sys/cdefs.h, most do not.
 121 dnl If it is missing, we add -I${srcdir}/missing to CFLAGS
 122 dnl also if sys/cdefs.h does not have __RCSID we need to use ours
 123 dnl but we need to include the host's one too *sigh*
 124 AC_CHECK_HEADER(sys/cdefs.h,
 125 echo $ECHO_N "checking whether sys/cdefs.h is compatible... $ECHO_C" >&6
 126 AC_EGREP_CPP(yes,
 127 [#include <sys/cdefs.h>
 128 #ifdef __RCSID
 129 yes
 130 #endif
 131 ],
 132 echo yes  >&6,
 133 echo no  >&6; CPPFLAGS="${CPPFLAGS} -I`cd ${srcdir}/missing && pwd` -DNEED_HOST_CDEFS_H"),
 134 CPPFLAGS="${CPPFLAGS} -I`cd ${srcdir}/missing && pwd`")
 135
 136 dnl Checks for typedefs, structures, and compiler characteristics.
 137 AC_C___ATTRIBUTE__
 138 AC_C_BIGENDIAN
 139 AC_C_CONST
 140 AC_TYPE_OFF_T
 141 AC_TYPE_PID_T
 142 AC_TYPE_SIZE_T
 143 AC_DECL_SYS_SIGLIST
 144 AC_HEADER_TIME
 145 AC_STRUCT_TM
 146
 147 dnl Checks for library functions.
 148 AC_TYPE_SIGNAL
 149 AC_FUNC_VFORK
 150 AC_FUNC_VPRINTF
 151 AC_FUNC_WAIT3
 152 dnl Keep this list sorted
 153 AC_CHECK_FUNCS( \
 154         err \
 155         errx \
 156         getcwd \
 157         getenv \
 158         getopt \
 159         getwd \
 160         killpg \
 161         mmap \
 162         putenv \
 163         select \
 164         setenv \
 165         setpgid \
 166         setsid \
 167         sigaction \
 168         sigvec \
 169         snprintf \
 170         strerror \
 171         strftime \
 172         strsep \
 173         strtod \
 174         strtol \
 175         sysctl \
 176         unsetenv \
 177         vsnprintf \
 178         wait3 \
 179         wait4 \
 180         waitpid \
 181         warn \
 182         warnx \
 183         )
 184
 185 dnl functions which we may need to provide
 186 AC_REPLACE_FUNCS( \
 187         realpath \
 188         dirname \
 189         stresep \
 190         strlcpy \
 191         )
 192
 193 AC_CHECK_LIB([util], [emalloc],
 194     [ AC_CHECK_LIB([util], [erealloc],
 195       [ AC_CHECK_LIB([util], [estrdup],
 196         [ AC_CHECK_LIB([util], [estrndup],
 197           [ LIBS="$LIBS -lutil"
 198             CPPFLAGS="$CPPFLAGS -DUSE_EMALLOC" ])])])])
 199
 200 dnl
 201 dnl Structures
 202 dnl
 203 AC_HEADER_STAT
 204 AC_STRUCT_ST_RDEV
 205 dnl
 206 echo "checking if compiler supports __func__" >&6
 207 AC_LANG(C)
 208 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[[const char *func = __func__;]])],,
 209         AC_DEFINE(__func__, __FUNCTION__, C99 function name))
 210 dnl
 211 dnl we want this for unit-tests/Makefile
 212 echo $ECHO_N "checking if diff -u works... $ECHO_C" >&6
 213 if diff -u /dev/null /dev/null > /dev/null 2>&1; then
 214    diff_u=-u
 215    echo yes >&6
 216 else
 217    diff_u=
 218    echo no >&6
 219 fi
 220 dnl
 221 dnl AC_* don't quite cut it.
 222 dnl
 223 echo "checking for MACHINE & MACHINE_ARCH..." >&6
 224 cat > conftest.$ac_ext <<EOF
 225 #include "confdefs.h"
 226 #include <sys/param.h>
 227 #ifdef MACHINE
 228 machine=MACHINE
 229 #endif
 230 #ifdef MACHINE_ARCH
 231 machine_arch=MACHINE_ARCH
 232 #endif
 233 EOF
 234
 235 default_machine=`(eval "$ac_cpp conftest.$ac_ext") 2>&5 |
 236         egrep machine= | tr -d ' "'`
 237 rm -rf conftest*
 238 if test "$default_machine"; then
 239         eval "$default_machine"
 240 fi
 241 machine=${machine:-`$srcdir/machine.sh`}
 242 machine_arch=${machine_arch:-`$srcdir/machine.sh arch`}
 243 echo "defaults: MACHINE=$machine, MACHINE_ARCH=$machine_arch" 1>&6
 244 dnl
 245 dnl now allow overrides
 246 dnl
 247 AC_ARG_WITH(machine,
 248 [  --with-machine=MACHINE  explicitly set MACHINE],
 249 [case "${withval}" in
 250 yes)   AC_MSG_ERROR(bad value ${withval} given for bmake MACHINE) ;;
 251 no)    ;;
 252 generic) machine=`$srcdir/machine.sh`;;
 253 *)     machine=$with_machine;;
 254 esac])
 255 force_machine=
 256 AC_ARG_WITH(force_machine,
 257 [  --with-force-machine=MACHINE  set FORCE_MACHINE],
 258 [case "${withval}" in
 259 yes)   force_machine=FORCE_;;
 260 no)    ;;
 261 *)     force_machine=FORCE_; machine=$with_force_machine;;
 262 esac])
 263 dnl
 264 force_machine_arch=
 265 AC_ARG_WITH(force_machine_arch,
 266 [  --with-force-machine-arch=MACHINE  set FORCE_MACHINE_ARCH],
 267 [case "${withval}" in
 268 yes)   force_machine_arch=FORCE_;;
 269 no)    ;;
 270 *)     force_machine_arch=FORCE_; machine_arch=$with_force_machine;;
 271 esac])
 272 dnl
 273 AC_ARG_WITH(machine_arch,
 274 [  --with-machine_arch=MACHINE_ARCH  explicitly set MACHINE_ARCH],
 275 [case "${withval}" in
 276 yes)   AC_MSG_ERROR(bad value ${withval} given for bmake MACHINE_ARCH) ;;
 277 no)    ;;
 278 *)     machine_arch=$with_machine_arch;;
 279 esac])
 280 dnl
 281 dnl Tell them what we ended up with
 282 dnl
 283 echo "Using: ${force_machine}MACHINE=$machine, MACHINE_ARCH=$machine_arch" 1>&6
 284 dnl
 285 dnl Allow folk to control _PATH_DEFSYSPATH
 286 dnl
 287 default_sys_path=\${prefix}/share/mk
 288 AC_ARG_WITH(default-sys-path,
 289 [  --with-default-sys-path=PATH:DIR:LIST  use an explicit _PATH_DEFSYSPATH
 290         MAKESYSPATH is a ':' separated list of directories
 291         that bmake will search for system .mk files.
 292         _PATH_DEFSYSPATH is its default value.],
 293 [case "${withval}" in
 294 yes)    AC_MSG_ERROR(bad value ${withval} given for bmake _PATH_DEFSYSPATH) ;;
 295 no)     ;;
 296 *)      default_sys_path="$with_default_sys_path"
 297         ;;
 298 esac])
 299 dnl
 300 dnl Some folk don't like this one
 301 dnl
 302 AC_ARG_WITH(path-objdirprefix,
 303 [  --with-path-objdirprefix=PATH  override _PATH_OBJDIRPREFIX],
 304 [case "${withval}" in
 305 yes)   AC_MSG_ERROR(bad value ${withval} given for bmake _PATH_OBJDIRPREFIX) ;;
 306 no)    CPPFLAGS="$CPPFLAGS -DNO_PATH_OBJDIRPREFIX" ;;
 307 *)     CPPFLAGS="$CPPFLAGS \"-D_PATH_OBJDIRPREFIX=\\\"$with_path-objdir\\\"\"" ;;
 308 esac])
 309 dnl
 310 dnl And this can be handy to do with out.
 311 dnl
 312 AC_ARG_ENABLE(pwd-override,
 313 [  --disable-pwd-override  disable \$PWD overriding getcwd()],
 314 [case "${enableval}" in
 315 yes)   ;;
 316 no)    CPPFLAGS="$CPPFLAGS -DNO_PWD_OVERRIDE" ;;
 317 *)     AC_MSG_ERROR(bad value ${enableval} given for pwd-override option) ;;
 318 esac])
 319 dnl
 320 dnl Just for grins
 321 dnl
 322 AC_ARG_ENABLE(check-make-chdir,
 323 [  --disable-check-make-chdir disable make trying to guess
 324         when it should automatically cd \${.CURDIR}],
 325 [case "${enableval}" in
 326 yes)   ;;
 327 no)    CPPFLAGS="$CPPFLAGS -DNO_CHECK_MAKE_CHDIR" ;;
 328 *)     AC_MSG_ERROR(bad value ${enableval} given for check-make-chdir option) ;;
 329 esac])
 330 dnl
 331 dnl On non-BSD systems, bootstrap won't work without mk
 332 dnl
 333 AC_ARG_WITH(mksrc,
 334 [  --with-mksrc=PATH tell makefile.boot where to find mk src],
 335 [case "${withval}" in
 336 ""|yes|no) ;;
 337 *) test -s $withval/install-mk && mksrc=$withval ||
 338 AC_MSG_ERROR(bad value ${withval} given for mksrc cannot find install-mk)
 339 ;;
 340 esac
 341 ])
 342 dnl
 343 dnl Now make sure we have a value
 344 dnl
 345 srcdir=`cd $srcdir && pwd`
 346 for mksrc in $mksrc $srcdir/mk $srcdir/../mk mk
 347 do
 348         test -s $mksrc/install-mk || continue
 349         mksrc=`cd $mksrc && pwd`
 350         break
 351 done
 352 mksrc=`echo $mksrc | sed "s,$srcdir,\\\${srcdir},"`
 353 echo "Using: MKSRC=$mksrc" 1>&6
 354 dnl On some systems we want a different default shell by default
 355 if test -x /usr/xpg4/bin/sh; then
 356         defshell_path=${defshell_path:-/usr/xpg4/bin/sh}
 357 fi
 358 if test -n "$defshell_path"; then
 359         echo "Using: SHELL=$defshell_path"  >&6
 360         AC_DEFINE_UNQUOTED(DEFSHELL_CUSTOM, "$defshell_path", Path of default shell)
 361 fi
 362 if test -n "$DEFSHELL_INDEX"; then
 363        AC_DEFINE_UNQUOTED(DEFSHELL_INDEX, $DEFSHELL_INDEX, Shell spec to use by default)
 364 fi
 365 dnl
 366 AC_SUBST(machine)
 367 AC_SUBST(force_machine)
 368 AC_SUBST(machine_arch)
 369 AC_SUBST(mksrc)
 370 AC_SUBST(default_sys_path)
 371 AC_SUBST(INSTALL)
 372 AC_SUBST(GCC)
 373 AC_SUBST(diff_u)
 374 AC_SUBST(use_meta)
 375 AC_SUBST(filemon_h)
 376 AC_OUTPUT(makefile Makefile.config make-bootstrap.sh unit-tests/Makefile)
 377
 378 cat <<EOF
 379
 380 You can now run
 381
 382         sh ./make-bootstrap.sh
 383
 384 to produce a fully functional bmake.
 385
 386 EOF