contrib/gcc/config/arm/libunwind.S

   1 /* Support functions for the unwinder.
   2    Copyright (C) 2003, 2004, 2005  Free Software Foundation, Inc.
   3    Contributed by Paul Brook
   4
   5    This file is free software; you can redistribute it and/or modify it
   6    under the terms of the GNU General Public License as published by the
   7    Free Software Foundation; either version 2, or (at your option) any
   8    later version.
   9
  10    In addition to the permissions in the GNU General Public License, the
  11    Free Software Foundation gives you unlimited permission to link the
  12    compiled version of this file into combinations with other programs,
  13    and to distribute those combinations without any restriction coming
  14    from the use of this file.  (The General Public License restrictions
  15    do apply in other respects; for example, they cover modification of
  16    the file, and distribution when not linked into a combine
  17    executable.)
  18
  19    This file is distributed in the hope that it will be useful, but
  20    WITHOUT ANY WARRANTY; without even the implied warranty of
  21    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22    General Public License for more details.
  23
  24    You should have received a copy of the GNU General Public License
  25    along with this program; see the file COPYING.  If not, write to
  26    the Free Software Foundation, 51 Franklin Street, Fifth Floor,
  27    Boston, MA 02110-1301, USA.  */
  28
  29 #include <machine/acle-compat.h>
  30
  31 /* Allow the use of VFP instructions */
  32 #if __ARM_ARCH >= 7
  33 .fpu    vfp
  34 #endif
  35
  36 #ifndef __symbian__
  37
  38 #include "lib1funcs.asm"
  39
  40 .macro UNPREFIX name
  41         .global SYM (\name)
  42         EQUIV SYM (\name), SYM (__\name)
  43 .endm
  44
  45 /* r0 points to a 16-word block.  Upload these values to the actual core
  46    state.  */
  47 ARM_FUNC_START restore_core_regs
  48         /* We must use sp as the base register when restoring sp.  Push the
  49            last 3 registers onto the top of the current stack to achieve
  50            this.  */
  51         add r1, r0, #52
  52         ldmia r1, {r3, r4, r5}  /* {sp, lr, pc}.  */
  53 #ifdef __INTERWORKING__
  54         /* Restore pc into ip.  */
  55         mov r2, r5
  56         stmfd sp!, {r2, r3, r4}
  57 #else
  58         stmfd sp!, {r3, r4, r5}
  59 #endif
  60         /* Don't bother restoring ip.  */
  61         ldmia r0, {r0, r1, r2, r3, r4, r5, r6, r7, r8, r9, sl, fp}
  62         /* Pop the three registers we pushed earlier.  */
  63 #ifdef __INTERWORKING__
  64         ldmfd sp, {ip, sp, lr}
  65         bx ip
  66 #else
  67         ldmfd sp, {sp, lr, pc}
  68 #endif
  69         FUNC_END restore_core_regs
  70         UNPREFIX restore_core_regs
  71
  72 /* Load VFP registers d0-d15 from the address in r0.  */
  73 ARM_FUNC_START gnu_Unwind_Restore_VFP
  74         /* Use the generic coprocessor form so that gas doesn't complain
  75            on soft-float targets.  */
  76 #if __ARM_ARCH >= 7
  77         fldmiax r0, {d0-d15}
  78 #else
  79         ldc   p11,cr0,[r0],{0x21} /* fldmiax r0, {d0-d15} */
  80 #endif
  81         RET
  82
  83 /* Store VFR regsters d0-d15 to the address in r0.  */
  84 ARM_FUNC_START gnu_Unwind_Save_VFP
  85         /* Use the generic coprocessor form so that gas doesn't complain
  86            on soft-float targets.  */
  87 #if __ARM_ARCH >= 7
  88         fstmiax r0, {d0-d15}
  89 #else
  90         stc   p11,cr0,[r0],{0x21} /* fstmiax r0, {d0-d15} */
  91 #endif
  92         RET
  93
  94 /* Wrappers to save core registers, then call the real routine.   */
  95
  96 .macro  UNWIND_WRAPPER name nargs
  97         ARM_FUNC_START \name
  98         /* Create a phase2_vrs structure.  */
  99         /* Split reg push in two to ensure the correct value for sp.  */
 100         stmfd sp!, {sp, lr, pc}
 101         stmfd sp!, {r0, r1, r2, r3, r4, r5, r6, r7, r8, r9, sl, fp, ip}
 102
 103         /* Demand-save flags, plus an extra word for alignment.  */
 104         mov r3, #0
 105         stmfd sp!, {r2, r3}
 106
 107         /* Point r1 at the block.  Pass r[0..nargs) unchanged.  */
 108         add r\nargs, sp, #4
 109 #if defined(__thumb__)
 110         /* Switch back to thumb mode to avoid interworking hassle.  */
 111         adr ip, .L1_\name
 112         orr ip, ip, #1
 113         bx ip
 114         .thumb
 115 .L1_\name:
 116         bl SYM (__gnu\name) __PLT__
 117         ldr r3, [sp, #64]
 118         add sp, #72
 119         bx r3
 120 #else
 121         bl SYM (__gnu\name) __PLT__
 122         ldr lr, [sp, #64]
 123         add sp, sp, #72
 124         RET
 125 #endif
 126         FUNC_END \name
 127         UNPREFIX \name
 128 .endm
 129
 130 UNWIND_WRAPPER _Unwind_RaiseException 1
 131 UNWIND_WRAPPER _Unwind_Resume 1
 132 UNWIND_WRAPPER _Unwind_Resume_or_Rethrow 1
 133 UNWIND_WRAPPER _Unwind_ForcedUnwind 3
 134 UNWIND_WRAPPER _Unwind_Backtrace 2
 135
 136 #endif  /* ndef __symbian__ */