contrib/gcclibs/libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([GNU OpenMP Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 # We would like our source tree to be readonly. However when releases or
  19 # pre-releases are generated, the flex/bison generated files as well as the
  20 # various formats of manuals need to be included along with the rest of the
  21 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  22 # just that.
  23 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  24 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  25    [put copies of generated files in source dir intended for creating source
  26     tarballs for users without texinfo bison or flex.],
  27    permit yes|no)
  28 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  29 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  30
  31
  32 # -------
  33 # -------
  34
  35 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  36 #
  37 # You will slowly go insane if you do not grok the following fact:  when
  38 # building this library, the top-level /target/ becomes the library's /host/.
  39 #
  40 # configure then causes --target to default to --host, exactly like any
  41 # other package using autoconf.  Therefore, 'target' and 'host' will
  42 # always be the same.  This makes sense both for native and cross compilers
  43 # just think about it for a little while.  :-)
  44 #
  45 # Also, if this library is being configured as part of a cross compiler, the
  46 # top-level configure script will pass the "real" host as $with_cross_host.
  47 #
  48 # Do not delete or change the following two lines.  For why, see
  49 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  50 AC_CANONICAL_SYSTEM
  51 target_alias=${target_alias-$host_alias}
  52
  53 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  54 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  55 #  1.9.0:  minimum required version
  56 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  57 #              of other PACKAGE_* variables will, however, and there's nothing
  58 #              we can do about that; they come from AC_INIT).
  59 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  60 #            file in the top srcdir, etc, etc), so stop complaining.
  61 #  no-dist:  we don't want 'dist' and related rules.
  62 #  -Wall:  turns on all automake warnings...
  63 #  -Wno-portability:  ...except this one, since GNU make is required.
  64 #  -Wno-override: ... and this one, since we do want this in testsuite.
  65 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  66 AM_ENABLE_MULTILIB(, ..)
  67
  68 # Calculate toolexeclibdir
  69 # Also toolexecdir, though it's only used in toolexeclibdir
  70 case ${enable_version_specific_runtime_libs} in
  71   yes)
  72     # Need the gcc compiler version to know where to install libraries
  73     # and header files if --enable-version-specific-runtime-libs option
  74     # is selected.
  75     toolexecdir='$(libdir)/gcc/$(target_alias)'
  76     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  77     ;;
  78   no)
  79     if test -n "$with_cross_host" &&
  80        test x"$with_cross_host" != x"no"; then
  81       # Install a library built with a cross compiler in tooldir, not libdir.
  82       toolexecdir='$(exec_prefix)/$(target_alias)'
  83       toolexeclibdir='$(toolexecdir)/lib'
  84     else
  85       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  86       toolexeclibdir='$(libdir)'
  87     fi
  88     multi_os_directory=`$CC -print-multi-os-directory`
  89     case $multi_os_directory in
  90       .) ;; # Avoid trailing /.
  91       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  92     esac
  93     ;;
  94 esac
  95 AC_SUBST(toolexecdir)
  96 AC_SUBST(toolexeclibdir)
  97
  98 # Check the compiler.
  99 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 100 # We must force CC to /not/ be precious variables; otherwise
 101 # the wrong, non-multilib-adjusted value will be used in multilibs.
 102 # As a side effect, we have to subst CFLAGS ourselves.
 103
 104 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 105 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 106 AC_PROG_CC
 107 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 108
 109 AC_SUBST(CFLAGS)
 110
 111 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 112 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 113 # in both places for now and restore CFLAGS at the end of config.
 114 save_CFLAGS="$CFLAGS"
 115
 116 # Add -Wall -Werror if we are using GCC.
 117 if test "x$GCC" = "xyes"; then
 118   XCFLAGS="$XCFLAGS -Wall -Werror"
 119 fi
 120
 121 # Find other programs we need.
 122 AC_CHECK_TOOL(AR, ar)
 123 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 124 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 125 AC_PROG_MAKE_SET
 126 AC_PROG_INSTALL
 127
 128 # See if makeinfo has been installed and is modern enough
 129 # that we can use it.
 130 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 131                    [GNU texinfo.* \([0-9][0-9.]*\)],
 132                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 133 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 134
 135
 136 # Configure libtool
 137 AM_PROG_LIBTOOL
 138 AC_SUBST(enable_shared)
 139 AC_SUBST(enable_static)
 140
 141 AM_MAINTAINER_MODE
 142
 143 # We need gfortran to compile parts of the library
 144 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 145 #AC_PROG_FC(gfortran)
 146 FC="$GFORTRAN"
 147 AC_PROG_FC(gfortran)
 148 FCFLAGS="$FCFLAGS -Wall"
 149
 150 # For libtool versioning info, format is CURRENT:REVISION:AGE
 151 libtool_VERSION=1:0:0
 152 AC_SUBST(libtool_VERSION)
 153
 154 # Check header files.
 155 AC_STDC_HEADERS
 156 AC_HEADER_TIME
 157 AC_CHECK_HEADERS(unistd.h semaphore.h sys/loadavg.h sys/sysctl.h sys/time.h)
 158
 159 GCC_HEADER_STDINT(gstdint.h)
 160
 161 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 162 # In case the pthread.h system header is not found, this test will fail.
 163 XPCFLAGS=""
 164 CFLAGS="$CFLAGS -pthread"
 165 AC_LINK_IFELSE(
 166  [AC_LANG_PROGRAM(
 167   [#include <pthread.h>
 168    void *g(void *d) { return NULL; }],
 169   [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 170  [XPCFLAGS=" -Wc,-pthread"],
 171  [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 172   AC_LINK_IFELSE(
 173    [AC_LANG_PROGRAM(
 174     [#include <pthread.h>
 175      void *g(void *d) { return NULL; }],
 176     [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 177    [],
 178    [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 179
 180 # Check for functions needed.
 181 AC_CHECK_FUNCS(getloadavg clock_gettime)
 182
 183 # Check for broken semaphore implementation on darwin.
 184 # sem_init returns: sem_init error: Function not implemented.
 185 case "$host" in
 186   *-darwin*)
 187     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 188         Define if the POSIX Semaphores do not work on your system.)
 189     ;;
 190 esac
 191
 192 GCC_LINUX_FUTEX(:)
 193
 194 # Check for pthread_{,attr_}[sg]etaffinity_np.
 195 AC_LINK_IFELSE(
 196  [AC_LANG_PROGRAM(
 197   [#define _GNU_SOURCE
 198    #include <pthread.h>],
 199   [cpu_set_t cpuset;
 200    pthread_attr_t attr;
 201    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 202    if (CPU_ISSET (0, &cpuset))
 203      CPU_SET (1, &cpuset);
 204    else
 205      CPU_ZERO (&cpuset);
 206    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 207    pthread_attr_init (&attr);
 208    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 209    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 210   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 211 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 212
 213 # At least for glibc, clock_gettime is in librt.  But don't pull that
 214 # in if it still doesn't give us the function we want.
 215 if test $ac_cv_func_clock_gettime = no; then
 216   AC_CHECK_LIB(rt, clock_gettime,
 217     [LIBS="-lrt $LIBS"
 218      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 219                [Define to 1 if you have the `clock_gettime' function.])])
 220 fi
 221
 222 # See if we support thread-local storage.
 223 GCC_CHECK_TLS
 224
 225 # See what sort of export controls are availible.
 226 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 227 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 228 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 229 LIBGOMP_ENABLE_SYMVERS
 230
 231 # Get target configury.
 232 . ${srcdir}/configure.tgt
 233 CFLAGS="$save_CFLAGS $XCFLAGS"
 234
 235 # Check for __sync_val_compare_and_swap, but only after the target has
 236 # had a chance to set XCFLAGS.
 237 LIBGOMP_CHECK_SYNC_BUILTINS
 238
 239 XCFLAGS="$XCFLAGS$XPCFLAGS"
 240
 241 AC_SUBST(config_path)
 242 AC_SUBST(XCFLAGS)
 243 AC_SUBST(XLDFLAGS)
 244
 245 # Cleanup and exit.
 246 CFLAGS="$save_CFLAGS"
 247 AC_CACHE_SAVE
 248
 249 if test ${multilib} = yes; then
 250   multilib_arg="--enable-multilib"
 251 else
 252   multilib_arg=
 253 fi
 254
 255 # Set up the set of libraries that we need to link against for libgomp.
 256 # Note that the GOMP_SELF_SPEC in gcc.c will force -pthread for -fopenmp,
 257 # which will force linkage against -lpthread (or equivalent for the system).
 258 # That's not 100% ideal, but about the best we can do easily.
 259 if test $enable_shared = yes; then
 260   link_gomp="-lgomp %{static: $LIBS}"
 261 else
 262   link_gomp="-lgomp $LIBS"
 263 fi
 264 AC_SUBST(link_gomp)
 265
 266 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 267
 268 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 269 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 270 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 271 # need to copy this macro to our acinclude.m4.
 272 save_CFLAGS="$CFLAGS"
 273 for i in $config_path; do
 274   if test -f $srcdir/config/$i/omp-lock.h; then
 275     CFLAGS="$CFLAGS -include $srcdir/config/$i/omp-lock.h"
 276     break
 277   fi
 278 done
 279
 280 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 281   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 282 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 283 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 284 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 285
 286 # If the lock fits in an integer, then arrange for Fortran to use that
 287 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 288 # Except that we don't have a way at present to multi-lib the installed
 289 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 290 # actual target.
 291 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 292 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 293 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 294   OMP_LOCK_KIND=8
 295 fi
 296 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 297   OMP_NEST_LOCK_KIND=8
 298 fi
 299
 300 AC_SUBST(OMP_LOCK_SIZE)
 301 AC_SUBST(OMP_LOCK_ALIGN)
 302 AC_SUBST(OMP_NEST_LOCK_SIZE)
 303 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 304 AC_SUBST(OMP_LOCK_KIND)
 305 AC_SUBST(OMP_NEST_LOCK_KIND)
 306 CFLAGS="$save_CFLAGS"
 307
 308 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 309 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 310 AC_OUTPUT