contrib/ntp/sntp/m4/define_dir.m4

   1 dnl @synopsis AC_DEFINE_DIR(VARNAME, DIR [, DESCRIPTION])
   2 dnl
   3 dnl This macro sets VARNAME to the expansion of the DIR variable,
   4 dnl taking care of fixing up ${prefix} and such.
   5 dnl
   6 dnl VARNAME is then offered as both an output variable and a C
   7 dnl preprocessor symbol.
   8 dnl
   9 dnl Example:
  10 dnl
  11 dnl    AC_DEFINE_DIR([DATADIR], [datadir], [Where data are placed to.])
  12 dnl
  13 dnl @category Misc
  14 dnl @author Stepan Kasal <kasal@ucw.cz>
  15 dnl @author Andreas Schwab <schwab@suse.de>
  16 dnl @author Guido U. Draheim <guidod@gmx.de>
  17 dnl @author Alexandre Oliva
  18 dnl @version 2006-10-13
  19 dnl @license AllPermissive
  20
  21 AC_DEFUN([AC_DEFINE_DIR], [
  22   prefix_NONE=
  23   exec_prefix_NONE=
  24   test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
  25   test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
  26 dnl In Autoconf 2.60, ${datadir} refers to ${datarootdir}, which in turn
  27 dnl refers to ${prefix}.  Thus we have to use `eval' twice.
  28   eval ac_define_dir="\"[$]$2\""
  29   eval ac_define_dir="\"$ac_define_dir\""
  30   AC_SUBST($1, "$ac_define_dir")
  31   AC_DEFINE_UNQUOTED($1, "$ac_define_dir", [$3])
  32   test "$prefix_NONE" && prefix=NONE
  33   test "$exec_prefix_NONE" && exec_prefix=NONE
  34 ])
  35