contrib/ntp/sntp/m4/ntp_googletest.m4

   1 dnl ######################################################################
   2 dnl NTP_GOOGLETEST gtest support shared by top-level and sntp/configure.ac
   3 AC_DEFUN([NTP_GOOGLETEST], [
   4 gta=false
   5 AC_ARG_WITH(
   6     [gtest],
   7     [AS_HELP_STRING(
   8         [--with-gtest],
   9         [Use the gtest framework (Default: if it's available)]
  10     )],
  11     [try_gtest=$withval],
  12     [try_gtest=yes]
  13 )
  14 case "$try_gtest" in
  15  yes)
  16     AC_PATH_PROG([GTEST_CONFIG], [gtest-config])
  17     AS_UNSET([ac_cv_path_GTEST_CONFIG])
  18     case x${GTEST_CONFIG} in
  19      x) ;;
  20      *)
  21         AC_MSG_CHECKING([gtest version])
  22         gtest_version_test=`$GTEST_CONFIG --min-version=1.5 || echo toolow`
  23         case "$gtest_version_test" in
  24          toolow*)
  25             ;;
  26          *)
  27             GTEST_LDFLAGS=`$GTEST_CONFIG --ldflags`
  28             GTEST_LIBS=`$GTEST_CONFIG --libs`
  29             GTEST_CXXFLAGS=`$GTEST_CONFIG --cxxflags`
  30             GTEST_CPPFLAGS=`$GTEST_CONFIG --cppflags`
  31             AC_SUBST([GTEST_LDFLAGS])
  32             AC_SUBST([GTEST_LIBS])
  33             AC_SUBST([GTEST_CXXFLAGS])
  34             AC_SUBST([GTEST_CPPFLAGS])
  35             gta=true
  36             ;;
  37         esac
  38         gtest_version=`$GTEST_CONFIG --version`
  39         case "$gta" in
  40          true)
  41             AC_MSG_RESULT([($gtest_version) ok])
  42             ;;
  43          *) AC_MSG_RESULT([($gtest_version) not ok])
  44             ;;
  45         esac
  46         AS_UNSET([gtest_version_test])
  47         AS_UNSET([gtest_version])
  48     esac
  49 esac
  50 AM_CONDITIONAL([GTEST_AVAILABLE], [$gta])
  51
  52 ])
  53 dnl ======================================================================