crypto/heimdal/lib/hx509/sel-gram.y

   1 /*
   2  * Copyright (c) 2008 Kungliga Tekniska Högskolan
   3  * (Royal Institute of Technology, Stockholm, Sweden).
   4  * All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  *
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  *
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * 3. Neither the name of the Institute nor the names of its contributors
  18  *    may be used to endorse or promote products derived from this software
  19  *    without specific prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE INSTITUTE AND CONTRIBUTORS ``AS IS'' AND
  22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE INSTITUTE OR CONTRIBUTORS BE LIABLE
  25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  31  * SUCH DAMAGE.
  32  */
  33
  34 %{
  35 #ifdef HAVE_CONFIG_H
  36 #include <config.h>
  37 #endif
  38 #include <stdio.h>
  39 #include <stdlib.h>
  40 #include <hx_locl.h>
  41
  42
  43 %}
  44
  45 %union {
  46     char *string;
  47     struct hx_expr *expr;
  48 }
  49
  50 %token kw_TRUE
  51 %token kw_FALSE
  52 %token kw_AND
  53 %token kw_OR
  54 %token kw_IN
  55 %token kw_TAILMATCH
  56
  57 %type <expr> expr
  58 %type <expr> comp
  59 %type <expr> word words
  60 %type <expr> number
  61 %type <expr> string
  62 %type <expr> function
  63 %type <expr> variable variables
  64
  65 %token <string> NUMBER
  66 %token <string> STRING
  67 %token <string> IDENTIFIER
  68
  69 %start start
  70
  71 %%
  72
  73 start:  expr                    { _hx509_expr_input.expr = $1; }
  74
  75 expr    : kw_TRUE               { $$ = _hx509_make_expr(op_TRUE, NULL, NULL); }
  76         | kw_FALSE              { $$ = _hx509_make_expr(op_FALSE, NULL, NULL); }
  77         | '!' expr              { $$ = _hx509_make_expr(op_NOT, $2, NULL); }
  78         | expr kw_AND expr      { $$ = _hx509_make_expr(op_AND, $1, $3); }
  79         | expr kw_OR expr       { $$ = _hx509_make_expr(op_OR, $1, $3); }
  80         | '(' expr ')'          { $$ = $2; }
  81         | comp                  { $$ = _hx509_make_expr(op_COMP, $1, NULL); }
  82         ;
  83
  84 words   : word                  { $$ = _hx509_make_expr(expr_WORDS, $1, NULL); }
  85         | word ',' words        { $$ = _hx509_make_expr(expr_WORDS, $1, $3); }
  86         ;
  87
  88 comp    : word '=' '=' word     { $$ = _hx509_make_expr(comp_EQ, $1, $4); }
  89         | word '!' '=' word     { $$ = _hx509_make_expr(comp_NE, $1, $4); }
  90         | word kw_TAILMATCH word { $$ = _hx509_make_expr(comp_TAILEQ, $1, $3); }
  91         | word kw_IN '(' words ')' { $$ = _hx509_make_expr(comp_IN, $1, $4); }
  92         | word kw_IN variable   { $$ = _hx509_make_expr(comp_IN, $1, $3); }
  93         ;
  94
  95 word    : number                { $$ = $1; }
  96         | string                { $$ = $1; }
  97         | function              { $$ = $1; }
  98         | variable              { $$ = $1; }
  99         ;
 100
 101 number  : NUMBER        { $$ = _hx509_make_expr(expr_NUMBER, $1, NULL); };
 102 string  : STRING        { $$ = _hx509_make_expr(expr_STRING, $1, NULL); };
 103
 104 function: IDENTIFIER '(' words ')' {
 105                         $$ = _hx509_make_expr(expr_FUNCTION, $1, $3); }
 106         ;
 107 variable: '%' '{' variables '}' { $$ = $3; }
 108         ;
 109
 110 variables: IDENTIFIER '.' variables     {
 111                         $$ = _hx509_make_expr(expr_VAR, $1, $3); }
 112         | IDENTIFIER                    {
 113                         $$ = _hx509_make_expr(expr_VAR, $1, NULL); }
 114         ;