lib/libc/amd64/gen/sigsetjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 4. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  *
  32  *      @(#)setjmp.s    5.1 (Berkeley) 4/23/90"
  33  */
  34
  35 #if defined(LIBC_SCCS) && !defined(lint)
  36         .text
  37         .asciz "$Id: sigsetjmp.S,v 1.1 1993/12/05 13:01:05 ats Exp $"
  38 #endif /* LIBC_SCCS and not lint */
  39 #include <machine/asm.h>
  40 __FBSDID("$FreeBSD$");
  41
  42 #include "SYS.h"
  43
  44 /*-
  45  * TODO:
  46  *      Rename sigsetjmp to __sigsetjmp and siglongjmp to __siglongjmp,
  47  *      remove the other *jmp functions and define everything in terms
  48  *      of the renamed functions.  This requires compiler support for
  49  *      the renamed functions (introduced in gcc-2.5.3; previous versions
  50  *      only supported *jmp with 0 or 1 leading underscores).
  51  *
  52  *      Restore _all_ the registers and the signal mask atomically.  Can
  53  *      use sigreturn() if sigreturn() works.
  54  */
  55
  56 ENTRY(sigsetjmp)
  57         movl    %esi,88(%rdi)           /* 11; savemask */
  58         testl   %esi,%esi
  59         jz      2f
  60         pushq   %rdi
  61         movq    %rdi,%rcx
  62         movq    $1,%rdi                 /* SIG_BLOCK       */
  63         movq    $0,%rsi                 /* (sigset_t*)set  */
  64         leaq    72(%rcx),%rdx           /* 9,10 (sigset_t*)oset */
  65         /* stack is 16-byte aligned */
  66         call    __libc_sigprocmask
  67         popq    %rdi
  68 2:      movq    %rdi,%rcx
  69         movq    0(%rsp),%rdx            /* retval */
  70         movq    %rdx, 0(%rcx)           /* 0; retval */
  71         movq    %rbx, 8(%rcx)           /* 1; rbx */
  72         movq    %rsp,16(%rcx)           /* 2; rsp */
  73         movq    %rbp,24(%rcx)           /* 3; rbp */
  74         movq    %r12,32(%rcx)           /* 4; r12 */
  75         movq    %r13,40(%rcx)           /* 5; r13 */
  76         movq    %r14,48(%rcx)           /* 6; r14 */
  77         movq    %r15,56(%rcx)           /* 7; r15 */
  78         fnstcw  64(%rcx)                /* 8; fpu cw */
  79         xorq    %rax,%rax
  80         ret
  81 END(sigsetjmp)
  82
  83         .weak CNAME(siglongjmp)
  84         .set CNAME(siglongjmp),CNAME(__siglongjmp)
  85 ENTRY(__siglongjmp)
  86         cmpl    $0,88(%rdi)
  87         jz      2f
  88         movq    %rdi,%rdx
  89         pushq   %rdi
  90         pushq   %rsi
  91         movq    $3,%rdi                 /* SIG_SETMASK     */
  92         leaq    72(%rdx),%rsi           /* (sigset_t*)set  */
  93         movq    $0,%rdx                 /* (sigset_t*)oset */
  94         subq    $0x8,%rsp               /* make the stack 16-byte aligned */
  95         call    __libc_sigprocmask
  96         addq    $0x8,%rsp
  97         popq    %rsi
  98         popq    %rdi                    /* jmpbuf */
  99 2:      movq    %rdi,%rdx
 100         movq    %rsi,%rax               /* retval */
 101         movq    0(%rdx),%rcx
 102         movq    8(%rdx),%rbx
 103         movq    16(%rdx),%rsp
 104         movq    24(%rdx),%rbp
 105         movq    32(%rdx),%r12
 106         movq    40(%rdx),%r13
 107         movq    48(%rdx),%r14
 108         movq    56(%rdx),%r15
 109         fninit
 110         fldcw   64(%rdx)
 111         testq   %rax,%rax
 112         jnz     1f
 113         incq    %rax
 114 1:      movq    %rcx,0(%rsp)
 115         ret
 116 END(__siglongjmp)
 117
 118         .section .note.GNU-stack,"",%progbits