lib/libc/arm/aeabi/aeabi_asm_float.S

   1 /*
   2  * Copyright (C) 2014 Andrew Turner
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  */
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 #define PCR_Z   (1 << 30)
  32 #define PCR_C   (1 << 29)
  33
  34 /*
  35  * These functions return the result in the CPSR register.
  36  *
  37  * For __aeabi_cfcmple:
  38  *      Z C
  39  *   LT 0 0
  40  *   EQ 1 1
  41  * else 0 1
  42  *
  43  * __aeabi_cfrcmple is the same as __aeabi_cfcmple, however the arguments
  44  * have been swapped.
  45  */
  46 ENTRY(__aeabi_cfcmple)
  47         push    {r4, r5, ip, lr}
  48
  49         /* Backup the input registers */
  50         mov     r4, r0
  51         mov     r5, r1
  52         /* Is it less than? */
  53         bl      __aeabi_fcmplt
  54         cmp     r0, #1
  55         bne     1f
  56         /* Yes, clear Z and C */
  57         msr     cpsr_c, #(0)
  58         b       99f
  59
  60 1:
  61         /* Restore the input regsters for the next function call */
  62         mov     r0, r4
  63         mov     r1, r5
  64         /* Is it equal? */
  65         bl      __aeabi_fcmpeq
  66         cmp     r0, #1
  67         bne     2f
  68         /* Yes, set Z and C */
  69         msr     cpsr_c, #(PCR_Z | PCR_C)
  70         b 99f
  71
  72 2:
  73         /* Not less than or equal, set C and clear Z */
  74         msr     cpsr_c, #(PCR_C)
  75
  76 99:
  77         pop     {r4, r5, ip, pc}
  78 END(__aeabi_cfcmple)
  79
  80 ENTRY(__aeabi_cfrcmple)
  81         /* Swap the arguments */
  82         mov     ip, r0
  83         mov     r0, r1
  84         mov     r1, ip
  85
  86         b       __aeabi_cfcmple
  87 END(__aeabi_cfrcmple)
  88
  89 /*
  90  * This is just like __aeabi_cfcmple except it will not throw an exception
  91  * in the presence of a quiet NaN. If either argument is a signalling NaN we
  92  * will still signal.
  93  */
  94 ENTRY(__aeabi_cfcmpeq)
  95         /* Check if we can call __aeabi_cfcmple safely */
  96         push    {r0, r1, r2, lr}
  97         bl      __aeabi_cfcmpeq_helper
  98         cmp     r0, #1
  99         pop     {r0, r1, r2, lr}
 100         beq     1f
 101
 102         bl      __aeabi_cfcmple
 103         RET
 104
 105 1:
 106         msreq   cpsr_c, #(PCR_C)
 107         RET
 108 END(__aeabi_cfcmpeq)