lib/libc/arm/string/memset.S

   1 /*      $NetBSD: memset.S,v 1.4 2003/10/14 07:51:45 scw Exp $   */
   2
   3 /*
   4  * Copyright 2003 Wasabi Systems, Inc.
   5  * All rights reserved.
   6  *
   7  * Written by Steve C. Woodford for Wasabi Systems, Inc.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed for the NetBSD Project by
  20  *      Wasabi Systems, Inc.
  21  * 4. The name of Wasabi Systems, Inc. may not be used to endorse
  22  *    or promote products derived from this software without specific prior
  23  *    written permission.
  24  *
  25  * THIS SOFTWARE IS PROVIDED BY WASABI SYSTEMS, INC. ``AS IS'' AND
  26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  27  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  28  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL WASABI SYSTEMS, INC
  29  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  30  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  31  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  33  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  34  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  35  * POSSIBILITY OF SUCH DAMAGE.
  36  */
  37 /*
  38  * Copyright (c) 1995 Mark Brinicombe.
  39  * All rights reserved.
  40  *
  41  * Redistribution and use in source and binary forms, with or without
  42  * modification, are permitted provided that the following conditions
  43  * are met:
  44  * 1. Redistributions of source code must retain the above copyright
  45  *    notice, this list of conditions and the following disclaimer.
  46  * 2. Redistributions in binary form must reproduce the above copyright
  47  *    notice, this list of conditions and the following disclaimer in the
  48  *    documentation and/or other materials provided with the distribution.
  49  * 3. All advertising materials mentioning features or use of this software
  50  *    must display the following acknowledgement:
  51  *      This product includes software developed by Mark Brinicombe.
  52  * 4. The name of the company nor the name of the author may be used to
  53  *    endorse or promote products derived from this software without specific
  54  *    prior written permission.
  55  *
  56  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR IMPLIED
  57  * WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
  58  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  59  * IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
  60  * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  61  * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  62  * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  63  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  64  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  65  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  66  * SUCH DAMAGE.
  67  */
  68
  69 #include <machine/asm.h>
  70 __FBSDID("$FreeBSD$");
  71
  72 .syntax unified
  73
  74 /*
  75  * memset: Sets a block of memory to the specified value
  76  *
  77  * On entry:
  78  *   r0 - dest address
  79  *   r1 - byte to write
  80  *   r2 - number of bytes to write
  81  *
  82  * On exit:
  83  *   r0 - dest address
  84  */
  85 #ifdef _BZERO
  86 /* LINTSTUB: Func: void bzero(void *, size_t) */
  87 ENTRY(bzero)
  88         mov     r3, #0x00
  89 #else
  90 /* LINTSTUB: Func: void *memset(void *, int, size_t) */
  91 ENTRY(memset)
  92         and     r3, r1, #0xff           /* We deal with bytes */
  93         mov     r1, r2
  94 #endif
  95         cmp     r1, #0x04               /* Do we have less than 4 bytes */
  96         mov     ip, r0
  97         blt     .Lmemset_lessthanfour
  98
  99         /* Ok first we will word align the address */
 100         ands    r2, ip, #0x03           /* Get the bottom two bits */
 101         bne     .Lmemset_wordunaligned  /* The address is not word aligned */
 102
 103         /* We are now word aligned */
 104 .Lmemset_wordaligned:
 105 #ifndef _BZERO
 106         orr     r3, r3, r3, lsl #8      /* Extend value to 16-bits */
 107 #endif
 108 #ifdef _ARM_ARCH_5E
 109         tst     ip, #0x04               /* Quad-align for armv5e */
 110 #else
 111         cmp     r1, #0x10
 112 #endif
 113 #ifndef _BZERO
 114         orr     r3, r3, r3, lsl #16     /* Extend value to 32-bits */
 115 #endif
 116 #ifdef _ARM_ARCH_5E
 117         subne   r1, r1, #0x04           /* Quad-align if necessary */
 118         strne   r3, [ip], #0x04
 119         cmp     r1, #0x10
 120 #endif
 121         blt     .Lmemset_loop4          /* If less than 16 then use words */
 122         mov     r2, r3                  /* Duplicate data */
 123         cmp     r1, #0x80               /* If < 128 then skip the big loop */
 124         blt     .Lmemset_loop32
 125
 126         /* Do 128 bytes at a time */
 127 .Lmemset_loop128:
 128         subs    r1, r1, #0x80
 129 #ifdef _ARM_ARCH_5E
 130         strdge  r2, [ip], #0x08
 131         strdge  r2, [ip], #0x08
 132         strdge  r2, [ip], #0x08
 133         strdge  r2, [ip], #0x08
 134         strdge  r2, [ip], #0x08
 135         strdge  r2, [ip], #0x08
 136         strdge  r2, [ip], #0x08
 137         strdge  r2, [ip], #0x08
 138         strdge  r2, [ip], #0x08
 139         strdge  r2, [ip], #0x08
 140         strdge  r2, [ip], #0x08
 141         strdge  r2, [ip], #0x08
 142         strdge  r2, [ip], #0x08
 143         strdge  r2, [ip], #0x08
 144         strdge  r2, [ip], #0x08
 145         strdge  r2, [ip], #0x08
 146 #else
 147         stmiage ip!, {r2-r3}
 148         stmiage ip!, {r2-r3}
 149         stmiage ip!, {r2-r3}
 150         stmiage ip!, {r2-r3}
 151         stmiage ip!, {r2-r3}
 152         stmiage ip!, {r2-r3}
 153         stmiage ip!, {r2-r3}
 154         stmiage ip!, {r2-r3}
 155         stmiage ip!, {r2-r3}
 156         stmiage ip!, {r2-r3}
 157         stmiage ip!, {r2-r3}
 158         stmiage ip!, {r2-r3}
 159         stmiage ip!, {r2-r3}
 160         stmiage ip!, {r2-r3}
 161         stmiage ip!, {r2-r3}
 162         stmiage ip!, {r2-r3}
 163 #endif
 164         bgt     .Lmemset_loop128
 165         RETeq                   /* Zero length so just exit */
 166
 167         add     r1, r1, #0x80           /* Adjust for extra sub */
 168
 169         /* Do 32 bytes at a time */
 170 .Lmemset_loop32:
 171         subs    r1, r1, #0x20
 172 #ifdef _ARM_ARCH_5E
 173         strdge  r2, [ip], #0x08
 174         strdge  r2, [ip], #0x08
 175         strdge  r2, [ip], #0x08
 176         strdge  r2, [ip], #0x08
 177 #else
 178         stmiage ip!, {r2-r3}
 179         stmiage ip!, {r2-r3}
 180         stmiage ip!, {r2-r3}
 181         stmiage ip!, {r2-r3}
 182 #endif
 183         bgt     .Lmemset_loop32
 184         RETeq                   /* Zero length so just exit */
 185
 186         adds    r1, r1, #0x10           /* Partially adjust for extra sub */
 187
 188         /* Deal with 16 bytes or more */
 189 #ifdef _ARM_ARCH_5E
 190         strdge  r2, [ip], #0x08
 191         strdge  r2, [ip], #0x08
 192 #else
 193         stmiage ip!, {r2-r3}
 194         stmiage ip!, {r2-r3}
 195 #endif
 196         RETeq                   /* Zero length so just exit */
 197
 198         addlt   r1, r1, #0x10           /* Possibly adjust for extra sub */
 199
 200         /* We have at least 4 bytes so copy as words */
 201 .Lmemset_loop4:
 202         subs    r1, r1, #0x04
 203         strge   r3, [ip], #0x04
 204         bgt     .Lmemset_loop4
 205         RETeq                   /* Zero length so just exit */
 206
 207 #ifdef _ARM_ARCH_5E
 208         /* Compensate for 64-bit alignment check */
 209         adds    r1, r1, #0x04
 210         RETeq
 211         cmp     r1, #2
 212 #else
 213         cmp     r1, #-2
 214 #endif
 215
 216         strb    r3, [ip], #0x01         /* Set 1 byte */
 217         strbge  r3, [ip], #0x01         /* Set another byte */
 218         strbgt  r3, [ip]                /* and a third */
 219         RET                     /* Exit */
 220
 221 .Lmemset_wordunaligned:
 222         rsb     r2, r2, #0x004
 223         strb    r3, [ip], #0x01         /* Set 1 byte */
 224         cmp     r2, #0x02
 225         strbge  r3, [ip], #0x01         /* Set another byte */
 226         sub     r1, r1, r2
 227         strbgt  r3, [ip], #0x01         /* and a third */
 228         cmp     r1, #0x04               /* More than 4 bytes left? */
 229         bge     .Lmemset_wordaligned    /* Yup */
 230
 231 .Lmemset_lessthanfour:
 232         cmp     r1, #0x00
 233         RETeq                   /* Zero length so exit */
 234         strb    r3, [ip], #0x01         /* Set 1 byte */
 235         cmp     r1, #0x02
 236         strbge  r3, [ip], #0x01         /* Set another byte */
 237         strbgt  r3, [ip]                /* and a third */
 238         RET                     /* Exit */
 239 #ifdef _BZERO
 240 END(bzero)
 241 #else
 242 END(memset)
 243 #endif