lib/libc/mips/gen/setjmp.S

   1 /*      $NetBSD: setjmp.S,v 1.17 2005/09/17 11:49:39 tsutsui Exp $      */
   2
   3 /*-
   4  * Copyright (c) 1991, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * Ralph Campbell.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/asm.h>
  36 __FBSDID("$FreeBSD$");
  37 #include <machine/regnum.h>
  38
  39 #if defined(LIBC_SCCS) && !defined(lint)
  40         ASMSTR("from: @(#)setjmp.s      8.1 (Berkeley) 6/4/93")
  41         ASMSTR("$NetBSD: setjmp.S,v 1.17 2005/09/17 11:49:39 tsutsui Exp $")
  42 #endif /* LIBC_SCCS and not lint */
  43
  44 #include "SYS.h"
  45
  46 #ifdef __ABICALLS__
  47         .abicalls
  48 #endif
  49
  50 /*
  51  * C library -- setjmp, longjmp
  52  *
  53  *      longjmp(a,v)
  54  * will generate a "return(v)" from
  55  * the last call to
  56  *      setjmp(a)
  57  * by restoring registers from the stack,
  58  * and a struct sigcontext, see <signal.h>
  59  */
  60
  61 #define SETJMP_FRAME_SIZE       (CALLFRAME_SIZ + (SZREG * 2))
  62
  63
  64 NESTED(setjmp, SETJMP_FRAME_SIZE, ra)
  65         .mask   0x80000000, (CALLFRAME_RA - CALLFRAME_SIZ)
  66         SETUP_GP
  67         PTR_SUBU sp, sp, SETJMP_FRAME_SIZE      # allocate stack frame
  68         SAVE_GP(CALLFRAME_GP)
  69         SETUP_GP64(CALLFRAME_GP, setjmp)
  70
  71         REG_S   ra, CALLFRAME_RA(sp)            # save RA
  72         REG_S   a0, CALLFRAME_SIZ(sp)           # store env
  73
  74         /* Get the signal mask. */
  75         PTR_ADDU a2, a0, _JB_SIGMASK * SZREG    # &oenv
  76         li      a0, 1                           # SIG_SETBLOCK
  77         move    a1, zero                        # &env == 0
  78         PTR_LA  t9, _C_LABEL(sigprocmask)       # get current signal mask
  79         jalr    t9
  80
  81         RESTORE_GP64
  82         REG_L   a0, CALLFRAME_SIZ(sp)           # restore env pointer
  83         REG_L   ra, CALLFRAME_RA(sp)            # restore RA
  84         PTR_ADDU sp, sp, SETJMP_FRAME_SIZE      # pop stack frame
  85
  86         REG_LI  v0, _JB_MAGIC_SETJMP
  87         REG_S   v0, (_JB_MAGIC  * SZREG)(a0)
  88         REG_S   ra, (_JB_REG_RA * SZREG)(a0)
  89         /*
  90          * From "MIPSpro N32 ABI Handbook", Table 2-1:
  91          * Registers s0..s7 are callee-saved.
  92          * The sp register is callee-saved.
  93          * The fp (or s8) register is callee-saved.
  94          * The gp register is callee-saved (for n32/n64).
  95          */
  96         REG_S   s0, (_JB_REG_S0 * SZREG)(a0)
  97         REG_S   s1, (_JB_REG_S1 * SZREG)(a0)
  98         REG_S   s2, (_JB_REG_S2 * SZREG)(a0)
  99         REG_S   s3, (_JB_REG_S3 * SZREG)(a0)
 100         REG_S   s4, (_JB_REG_S4 * SZREG)(a0)
 101         REG_S   s5, (_JB_REG_S5 * SZREG)(a0)
 102         REG_S   s6, (_JB_REG_S6 * SZREG)(a0)
 103         REG_S   s7, (_JB_REG_S7 * SZREG)(a0)
 104         REG_S   sp, (_JB_REG_SP * SZREG)(a0)
 105         REG_S   s8, (_JB_REG_S8 * SZREG)(a0)
 106 #if defined(__mips_n32) || defined(__mips_n64)
 107         REG_S   gp, (_JB_REG_GP * SZREG)(a0)
 108 #endif
 109 #ifndef SOFTFLOAT
 110         /*
 111          * From "MIPSpro N32 ABI Handbook", Table 2-1:
 112          * In N32, FP registers F20, F22, F24, F26, F28, F30 are callee-saved.
 113          * In N64, FP registers F24 .. F31 are callee-saved.
 114          * In O32, FP registers F20 .. F23 are callee-saved.
 115          */
 116         cfc1    v0, $31
 117         INT_S   v0, (_JB_FPREG_FCSR * SZREG)(a0)
 118 #if defined(__mips_o32) || defined(__mips_o64) || defined(__mips_n32)
 119         FP_S    $f20, (_JB_FPREG_F20 * SZREG)(a0)
 120         FP_S    $f22, (_JB_FPREG_F22 * SZREG)(a0)
 121 #endif
 122 #if defined(__mips_o32) || defined(__mips_o64)
 123         FP_S    $f21, (_JB_FPREG_F21 * SZREG)(a0)
 124         FP_S    $f23, (_JB_FPREG_F23 * SZREG)(a0)
 125 #endif
 126 #if defined(__mips_n32) || defined(__mips_n64)
 127         FP_S    $f24, (_JB_FPREG_F24 * SZREG)(a0)
 128         FP_S    $f26, (_JB_FPREG_F26 * SZREG)(a0)
 129         FP_S    $f28, (_JB_FPREG_F28 * SZREG)(a0)
 130         FP_S    $f30, (_JB_FPREG_F30 * SZREG)(a0)
 131 #endif
 132 #if defined(__mips_n64)
 133         FP_S    $f25, (_JB_FPREG_F25 * SZREG)(a0)
 134         FP_S    $f27, (_JB_FPREG_F27 * SZREG)(a0)
 135         FP_S    $f29, (_JB_FPREG_F29 * SZREG)(a0)
 136         FP_S    $f31, (_JB_FPREG_F31 * SZREG)(a0)
 137 #endif
 138 #endif  /* ! SOFTFLOAT */
 139
 140         move    v0, zero
 141         jr      ra
 142 END(setjmp)
 143
 144 #define LONGJMP_FRAME_SIZE      (CALLFRAME_SIZ + (SZREG * 2))
 145
 146 NESTED(longjmp, LONGJMP_FRAME_SIZE, ra)
 147         .mask   0x80000000, (CALLFRAME_RA - CALLFRAME_SIZ)
 148         PIC_PROLOGUE(longjmp)
 149         PTR_SUBU sp, sp, LONGJMP_FRAME_SIZE     # allocate stack frame
 150         SAVE_GP(CALLFRAME_GP)
 151
 152         REG_S   ra, CALLFRAME_RA(sp)            # save RA
 153         REG_L   v0, (_JB_MAGIC  * SZREG)(a0)
 154         REG_LI  t0, _JB_MAGIC_SETJMP
 155         bne     v0, t0, botch           # jump if error
 156         nop
 157
 158         REG_S   a0, CALLFRAME_SIZ(sp)           # save env
 159         REG_S   a1, (CALLFRAME_SIZ + SZREG)(sp) # save return value
 160
 161         # set sigmask
 162         PTR_ADDU a1, a0, _JB_SIGMASK * SZREG    # &set
 163         move    a2, zero                        # &oset == NULL
 164         li      a0, 3                           # SIG_SETMASK
 165         PTR_LA  t9,_C_LABEL(sigprocmask)        # set current signal mask
 166         jal     t9
 167         nop
 168
 169         REG_L   a0, CALLFRAME_SIZ(sp)           # restore env
 170         REG_L   a1, (CALLFRAME_SIZ + SZREG)(sp) # restore return value
 171
 172         REG_L   ra, (_JB_REG_RA * SZREG)(a0)
 173         /*
 174          * From "MIPSpro N32 ABI Handbook", Table 2-1:
 175          * Registers s0..s7 are callee-saved.
 176          * The sp register is callee-saved.
 177          * The fp (or s8) register is callee-saved.
 178          * The gp register is callee-saved (for n32/n64).
 179          */
 180         REG_L   s0, (_JB_REG_S0 * SZREG)(a0)
 181         REG_L   s1, (_JB_REG_S1 * SZREG)(a0)
 182         REG_L   s2, (_JB_REG_S2 * SZREG)(a0)
 183         REG_L   s3, (_JB_REG_S3 * SZREG)(a0)
 184         REG_L   s4, (_JB_REG_S4 * SZREG)(a0)
 185         REG_L   s5, (_JB_REG_S5 * SZREG)(a0)
 186         REG_L   s6, (_JB_REG_S6 * SZREG)(a0)
 187         REG_L   s7, (_JB_REG_S7 * SZREG)(a0)
 188         REG_L   sp, (_JB_REG_SP * SZREG)(a0)
 189         REG_L   s8, (_JB_REG_S8 * SZREG)(a0)
 190 #if defined(__mips_n32) || defined(__mips_n64)
 191         REG_L   gp, (_JB_REG_GP * SZREG)(a0)
 192 #endif
 193 #ifndef SOFTFLOAT
 194         /*
 195          * From "MIPSpro N32 ABI Handbook", Table 2-1:
 196          * In N32, FP registers F20, F22, F24, F26, F28, F30 are callee-saved.
 197          * In N64, FP registers F23 .. F31 are callee-saved.
 198          * In O32, FP registers F20 .. F23 are callee-saved.
 199          */
 200         INT_L           v0, (_JB_FPREG_FCSR * SZREG)(a0)
 201         ctc1            v0, $31
 202 #if defined(__mips_n64) || defined(__mips_n32)
 203         FP_L    $f30, (_JB_FPREG_F30 * SZREG)(a0)
 204         FP_L    $f28, (_JB_FPREG_F28 * SZREG)(a0)
 205         FP_L    $f26, (_JB_FPREG_F26 * SZREG)(a0)
 206         FP_L    $f24, (_JB_FPREG_F24 * SZREG)(a0)
 207 #endif
 208 #if defined(__mips_n32) || defined(__mips_o32) || defined(__mips_o64)
 209         FP_L    $f22, (_JB_FPREG_F22 * SZREG)(a0)
 210         FP_L    $f20, (_JB_FPREG_F20 * SZREG)(a0)
 211 #endif
 212 #if defined(__mips_o32) || defined(__mips_o64)
 213         FP_L    $f21, (_JB_FPREG_F21 * SZREG)(a0)
 214         FP_L    $f23, (_JB_FPREG_F23 * SZREG)(a0)
 215 #endif
 216 #if defined(__mips_n64)
 217         FP_L    $f25, (_JB_FPREG_F25 * SZREG)(a0)
 218         FP_L    $f27, (_JB_FPREG_F27 * SZREG)(a0)
 219         FP_L    $f29, (_JB_FPREG_F29 * SZREG)(a0)
 220         FP_L    $f31, (_JB_FPREG_F31 * SZREG)(a0)
 221 #endif
 222 #endif  /* ! SOFTFLOAT */
 223
 224         move    v0, a1
 225         j       ra
 226         nop
 227
 228 botch:
 229         /*
 230          * We know we aren't returning so we don't care about restoring
 231          * our caller's GP.
 232          */
 233         PTR_LA  t9, _C_LABEL(longjmperror)
 234         jalr    t9
 235         nop
 236
 237         PIC_TAILCALL(abort)
 238 END(longjmp)