sys/amd64/ia32/ia32_sigtramp.S

   1 /*-
   2  * Copyright (c) 2003 Peter Wemm
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  * $FreeBSD$
  27  */
  28
  29 #include "opt_compat.h"
  30
  31 #include <machine/asmacros.h>
  32 #include <sys/syscall.h>
  33
  34 #include "ia32_assym.h"
  35
  36         .text
  37         .code32
  38 /*
  39  * Signal trampoline, copied to top of user stack
  40  * XXX may need to be MD to match backend sendsig handoff protocol
  41  */
  42         ALIGN_TEXT
  43         .globl  ia32_sigcode
  44 ia32_sigcode:
  45         calll   *IA32_SIGF_HANDLER(%esp)
  46         leal    IA32_SIGF_UC(%esp),%eax /* get ucontext */
  47         pushl   %eax
  48         movl    $SYS_sigreturn,%eax
  49         pushl   %eax                    /* junk to fake return addr. */
  50         int     $0x80                   /* enter kernel with args */
  51                                         /* on stack */
  52 1:
  53         jmp     1b
  54
  55 #ifdef COMPAT_FREEBSD4
  56         ALIGN_TEXT
  57 freebsd4_ia32_sigcode:
  58         calll   *IA32_SIGF_HANDLER(%esp)
  59         leal    IA32_SIGF_UC4(%esp),%eax/* get ucontext */
  60         pushl   %eax
  61         movl    $344,%eax               /* 4.x SYS_sigreturn */
  62         pushl   %eax                    /* junk to fake return addr. */
  63         int     $0x80                   /* enter kernel with args */
  64                                         /* on stack */
  65 1:
  66         jmp     1b
  67 #endif
  68
  69 #ifdef COMPAT_43
  70         ALIGN_TEXT
  71 ia32_osigcode:
  72         calll   *IA32_SIGF_HANDLER(%esp)/* call signal handler */
  73         leal    IA32_SIGF_SC(%esp),%eax /* get sigcontext */
  74         pushl   %eax
  75         movl    $103,%eax               /* 3.x SYS_sigreturn */
  76         pushl   %eax                    /* junk to fake return addr. */
  77         int     $0x80                   /* enter kernel with args */
  78 1:
  79         jmp     1b
  80
  81
  82 /*
  83  * The lcall $7,$0 emulator cannot use the call gate that does an
  84  * inter-privilege transition. The reason is that the call gate
  85  * does not disable interrupts, and, before the swapgs is
  86  * executed, we would have a window where the ring 0 code is
  87  * executed with the wrong gsbase.
  88  *
  89  * Instead, set LDT descriptor 0 as code segment, which reflects
  90  * the lcall $7,$0 back to ring 3 trampoline.  The trampoline sets up
  91  * the frame for int $0x80.
  92  */
  93         ALIGN_TEXT
  94 lcall_tramp:
  95         cmpl    $SYS_vfork,%eax
  96         je      1f
  97         pushl   %ebp
  98         movl    %esp,%ebp
  99         pushl   0x24(%ebp) /* arg 6 */
 100         pushl   0x20(%ebp)
 101         pushl   0x1c(%ebp)
 102         pushl   0x18(%ebp)
 103         pushl   0x14(%ebp)
 104         pushl   0x10(%ebp) /* arg 1 */
 105         subl    $4,%esp   /* gap */
 106         int     $0x80
 107         leavel
 108         lretl
 109 1:
 110         /*
 111          * vfork handling is special and relies on the libc stub saving
 112          * the return ip in %ecx.  Also, we assume that the call was done
 113          * with ucode32 selector in %cs.
 114          */
 115         int     $0x80
 116         movl    $0x33,4(%esp)   /* GUCODE32_SEL | SEL_UPL */
 117         movl    %ecx,(%esp)
 118         lretl
 119 #endif
 120
 121         ALIGN_TEXT
 122 esigcode:
 123
 124         .data
 125         .globl  sz_ia32_sigcode
 126 sz_ia32_sigcode:
 127         .long   esigcode-ia32_sigcode
 128 #ifdef COMPAT_FREEBSD4
 129         .globl  sz_freebsd4_ia32_sigcode
 130 sz_freebsd4_ia32_sigcode:
 131         .long   esigcode-freebsd4_ia32_sigcode
 132 #endif
 133 #ifdef COMPAT_43
 134         .globl  sz_ia32_osigcode
 135 sz_ia32_osigcode:
 136         .long   esigcode-ia32_osigcode
 137         .globl  sz_lcall_tramp
 138 sz_lcall_tramp:
 139         .long   esigcode-lcall_tramp
 140 #endif