sys/powerpc/aim/trap_subr32.S

   1 /* $FreeBSD$ */
   2 /* $NetBSD: trap_subr.S,v 1.20 2002/04/22 23:20:08 kleink Exp $ */
   3
   4 /*-
   5  * Copyright (C) 1995, 1996 Wolfgang Solfrank.
   6  * Copyright (C) 1995, 1996 TooLs GmbH.
   7  * All rights reserved.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed by TooLs GmbH.
  20  * 4. The name of TooLs GmbH may not be used to endorse or promote products
  21  *    derived from this software without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY TOOLS GMBH ``AS IS'' AND ANY EXPRESS OR
  24  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  25  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  26  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  27  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  28  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  29  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  30  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  31  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  32  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  33  */
  34
  35 /*
  36  * NOTICE: This is not a standalone file.  to use it, #include it in
  37  * your port's locore.S, like so:
  38  *
  39  *      #include <powerpc/aim/trap_subr.S>
  40  */
  41
  42 /*
  43  * Save/restore segment registers
  44  */
  45 #define RESTORE_SRS(pmap,sr)    mtsr    0,sr; \
  46         lwz     sr,1*4(pmap);   mtsr    1,sr; \
  47         lwz     sr,2*4(pmap);   mtsr    2,sr; \
  48         lwz     sr,3*4(pmap);   mtsr    3,sr; \
  49         lwz     sr,4*4(pmap);   mtsr    4,sr; \
  50         lwz     sr,5*4(pmap);   mtsr    5,sr; \
  51         lwz     sr,6*4(pmap);   mtsr    6,sr; \
  52         lwz     sr,7*4(pmap);   mtsr    7,sr; \
  53         lwz     sr,8*4(pmap);   mtsr    8,sr; \
  54         lwz     sr,9*4(pmap);   mtsr    9,sr; \
  55         lwz     sr,10*4(pmap);  mtsr    10,sr; \
  56         lwz     sr,11*4(pmap);  mtsr    11,sr; \
  57         /* Skip segment 12 (USER_SR), which is restored differently */ \
  58         lwz     sr,13*4(pmap);  mtsr    13,sr; \
  59         lwz     sr,14*4(pmap);  mtsr    14,sr; \
  60         lwz     sr,15*4(pmap);  mtsr    15,sr; isync;
  61
  62 /*
  63  * User SRs are loaded through a pointer to the current pmap.
  64  */
  65 #define RESTORE_USER_SRS(pmap,sr) \
  66         GET_CPUINFO(pmap); \
  67         lwz     pmap,PC_CURPMAP(pmap); \
  68         lwzu    sr,PM_SR(pmap); \
  69         RESTORE_SRS(pmap,sr) \
  70         /* Restore SR 12 */ \
  71         lwz     sr,12*4(pmap);  mtsr    12,sr
  72
  73 /*
  74  * Kernel SRs are loaded directly from kernel_pmap_
  75  */
  76 #define RESTORE_KERN_SRS(pmap,sr) \
  77         lis     pmap,CNAME(kernel_pmap_store)@ha; \
  78         lwzu    sr,CNAME(kernel_pmap_store)+PM_SR@l(pmap); \
  79         RESTORE_SRS(pmap,sr)
  80
  81 /*
  82  * FRAME_SETUP assumes:
  83  *      SPRG1           SP (1)
  84  *      SPRG3           trap type
  85  *      savearea        r28-r31,DAR,DSISR   (DAR & DSISR only for DSI traps)
  86  *      r28             LR
  87  *      r29             CR
  88  *      r30             scratch
  89  *      r31             scratch
  90  *      r1              kernel stack
  91  *      SRR0/1          as at start of trap
  92  */
  93 #define FRAME_SETUP(savearea)                                           \
  94 /* Have to enable translation to allow access of kernel stack: */       \
  95         GET_CPUINFO(%r31);                                              \
  96         mfsrr0  %r30;                                                   \
  97         stw     %r30,(savearea+CPUSAVE_SRR0)(%r31);     /* save SRR0 */ \
  98         mfsrr1  %r30;                                                   \
  99         stw     %r30,(savearea+CPUSAVE_SRR1)(%r31);     /* save SRR1 */ \
 100         mfmsr   %r30;                                                   \
 101         ori     %r30,%r30,(PSL_DR|PSL_IR|PSL_RI)@l; /* relocation on */ \
 102         mtmsr   %r30;                   /* stack can now be accessed */ \
 103         isync;                                                          \
 104         mfsprg1 %r31;                   /* get saved SP */              \
 105         stwu    %r31,-FRAMELEN(%r1);    /* save it in the callframe */  \
 106         stw     %r0, FRAME_0+8(%r1);    /* save r0 in the trapframe */  \
 107         stw     %r31,FRAME_1+8(%r1);    /* save SP   "      "       */  \
 108         stw     %r2, FRAME_2+8(%r1);    /* save r2   "      "       */  \
 109         stw     %r28,FRAME_LR+8(%r1);   /* save LR   "      "       */  \
 110         stw     %r29,FRAME_CR+8(%r1);   /* save CR   "      "       */  \
 111         GET_CPUINFO(%r2);                                               \
 112         lwz     %r28,(savearea+CPUSAVE_R28)(%r2); /* get saved r28 */   \
 113         lwz     %r29,(savearea+CPUSAVE_R29)(%r2); /* get saved r29 */   \
 114         lwz     %r30,(savearea+CPUSAVE_R30)(%r2); /* get saved r30 */   \
 115         lwz     %r31,(savearea+CPUSAVE_R31)(%r2); /* get saved r31 */   \
 116         stw     %r3,  FRAME_3+8(%r1);   /* save r3-r31 */               \
 117         stw     %r4,  FRAME_4+8(%r1);                                   \
 118         stw     %r5,  FRAME_5+8(%r1);                                   \
 119         stw     %r6,  FRAME_6+8(%r1);                                   \
 120         stw     %r7,  FRAME_7+8(%r1);                                   \
 121         stw     %r8,  FRAME_8+8(%r1);                                   \
 122         stw     %r9,  FRAME_9+8(%r1);                                   \
 123         stw     %r10, FRAME_10+8(%r1);                                  \
 124         stw     %r11, FRAME_11+8(%r1);                                  \
 125         stw     %r12, FRAME_12+8(%r1);                                  \
 126         stw     %r13, FRAME_13+8(%r1);                                  \
 127         stw     %r14, FRAME_14+8(%r1);                                  \
 128         stw     %r15, FRAME_15+8(%r1);                                  \
 129         stw     %r16, FRAME_16+8(%r1);                                  \
 130         stw     %r17, FRAME_17+8(%r1);                                  \
 131         stw     %r18, FRAME_18+8(%r1);                                  \
 132         stw     %r19, FRAME_19+8(%r1);                                  \
 133         stw     %r20, FRAME_20+8(%r1);                                  \
 134         stw     %r21, FRAME_21+8(%r1);                                  \
 135         stw     %r22, FRAME_22+8(%r1);                                  \
 136         stw     %r23, FRAME_23+8(%r1);                                  \
 137         stw     %r24, FRAME_24+8(%r1);                                  \
 138         stw     %r25, FRAME_25+8(%r1);                                  \
 139         stw     %r26, FRAME_26+8(%r1);                                  \
 140         stw     %r27, FRAME_27+8(%r1);                                  \
 141         stw     %r28, FRAME_28+8(%r1);                                  \
 142         stw     %r29, FRAME_29+8(%r1);                                  \
 143         stw     %r30, FRAME_30+8(%r1);                                  \
 144         stw     %r31, FRAME_31+8(%r1);                                  \
 145         lwz     %r28,(savearea+CPUSAVE_AIM_DAR)(%r2);  /* saved DAR */  \
 146         lwz     %r29,(savearea+CPUSAVE_AIM_DSISR)(%r2);/* saved DSISR */\
 147         lwz     %r30,(savearea+CPUSAVE_SRR0)(%r2); /* saved SRR0 */     \
 148         lwz     %r31,(savearea+CPUSAVE_SRR1)(%r2); /* saved SRR1 */     \
 149         mfxer   %r3;                                                    \
 150         mfctr   %r4;                                                    \
 151         mfsprg3 %r5;                                                    \
 152         stw     %r3, FRAME_XER+8(1);    /* save xer/ctr/exc */          \
 153         stw     %r4, FRAME_CTR+8(1);                                    \
 154         stw     %r5, FRAME_EXC+8(1);                                    \
 155         stw     %r28,FRAME_AIM_DAR+8(1);                                \
 156         stw     %r29,FRAME_AIM_DSISR+8(1); /* save dsisr/srr0/srr1 */   \
 157         stw     %r30,FRAME_SRR0+8(1);                                   \
 158         stw     %r31,FRAME_SRR1+8(1);                                   \
 159         lwz     %r2,PC_CURTHREAD(%r2)   /* set curthread pointer */
 160
 161 #define FRAME_LEAVE(savearea)                                           \
 162 /* Disable exceptions: */                                               \
 163         mfmsr   %r2;                                                    \
 164         andi.   %r2,%r2,~PSL_EE@l;                                      \
 165         mtmsr   %r2;                                                    \
 166         isync;                                                          \
 167 /* Now restore regs: */                                                 \
 168         lwz     %r2,FRAME_SRR0+8(%r1);                                  \
 169         lwz     %r3,FRAME_SRR1+8(%r1);                                  \
 170         lwz     %r4,FRAME_CTR+8(%r1);                                   \
 171         lwz     %r5,FRAME_XER+8(%r1);                                   \
 172         lwz     %r6,FRAME_LR+8(%r1);                                    \
 173         GET_CPUINFO(%r7);                                               \
 174         stw     %r2,(savearea+CPUSAVE_SRR0)(%r7); /* save SRR0 */       \
 175         stw     %r3,(savearea+CPUSAVE_SRR1)(%r7); /* save SRR1 */       \
 176         lwz     %r7,FRAME_CR+8(%r1);                                    \
 177         mtctr   %r4;                                                    \
 178         mtxer   %r5;                                                    \
 179         mtlr    %r6;                                                    \
 180         mtsprg1 %r7;                    /* save cr */                   \
 181         lwz     %r31,FRAME_31+8(%r1);   /* restore r0-31 */             \
 182         lwz     %r30,FRAME_30+8(%r1);                                   \
 183         lwz     %r29,FRAME_29+8(%r1);                                   \
 184         lwz     %r28,FRAME_28+8(%r1);                                   \
 185         lwz     %r27,FRAME_27+8(%r1);                                   \
 186         lwz     %r26,FRAME_26+8(%r1);                                   \
 187         lwz     %r25,FRAME_25+8(%r1);                                   \
 188         lwz     %r24,FRAME_24+8(%r1);                                   \
 189         lwz     %r23,FRAME_23+8(%r1);                                   \
 190         lwz     %r22,FRAME_22+8(%r1);                                   \
 191         lwz     %r21,FRAME_21+8(%r1);                                   \
 192         lwz     %r20,FRAME_20+8(%r1);                                   \
 193         lwz     %r19,FRAME_19+8(%r1);                                   \
 194         lwz     %r18,FRAME_18+8(%r1);                                   \
 195         lwz     %r17,FRAME_17+8(%r1);                                   \
 196         lwz     %r16,FRAME_16+8(%r1);                                   \
 197         lwz     %r15,FRAME_15+8(%r1);                                   \
 198         lwz     %r14,FRAME_14+8(%r1);                                   \
 199         lwz     %r13,FRAME_13+8(%r1);                                   \
 200         lwz     %r12,FRAME_12+8(%r1);                                   \
 201         lwz     %r11,FRAME_11+8(%r1);                                   \
 202         lwz     %r10,FRAME_10+8(%r1);                                   \
 203         lwz     %r9, FRAME_9+8(%r1);                                    \
 204         lwz     %r8, FRAME_8+8(%r1);                                    \
 205         lwz     %r7, FRAME_7+8(%r1);                                    \
 206         lwz     %r6, FRAME_6+8(%r1);                                    \
 207         lwz     %r5, FRAME_5+8(%r1);                                    \
 208         lwz     %r4, FRAME_4+8(%r1);                                    \
 209         lwz     %r3, FRAME_3+8(%r1);                                    \
 210         lwz     %r2, FRAME_2+8(%r1);                                    \
 211         lwz     %r0, FRAME_0+8(%r1);                                    \
 212         lwz     %r1, FRAME_1+8(%r1);                                    \
 213 /* Can't touch %r1 from here on */                                      \
 214         mtsprg2 %r2;                    /* save r2 & r3 */              \
 215         mtsprg3 %r3;                                                    \
 216 /* Disable translation, machine check and recoverability: */            \
 217         mfmsr   %r2;                                                    \
 218         andi.   %r2,%r2,~(PSL_DR|PSL_IR|PSL_ME|PSL_RI)@l;       \
 219         mtmsr   %r2;                                                    \
 220         isync;                                                          \
 221 /* Decide whether we return to user mode: */                            \
 222         GET_CPUINFO(%r2);                                               \
 223         lwz     %r3,(savearea+CPUSAVE_SRR1)(%r2);                       \
 224         mtcr    %r3;                                                    \
 225         bf      17,1f;                  /* branch if PSL_PR is false */ \
 226 /* Restore user SRs */                                                  \
 227         RESTORE_USER_SRS(%r2,%r3);                                      \
 228 1:      mfsprg1 %r2;                    /* restore cr */                \
 229         mtcr    %r2;                                                    \
 230         GET_CPUINFO(%r2);                                               \
 231         lwz     %r3,(savearea+CPUSAVE_SRR0)(%r2); /* restore srr0 */    \
 232         mtsrr0  %r3;                                                    \
 233         lwz     %r3,(savearea+CPUSAVE_SRR1)(%r2); /* restore srr1 */    \
 234                                                                         \
 235         /* Make sure HV bit of MSR propagated to SRR1 */                \
 236         mfmsr   %r2;                                                    \
 237         or      %r3,%r2,%r3;                                            \
 238                                                                         \
 239         mtsrr1  %r3;                                                    \
 240         mfsprg2 %r2;                    /* restore r2 & r3 */           \
 241         mfsprg3 %r3
 242
 243 #ifdef KDTRACE_HOOKS
 244         .data
 245         .globl  dtrace_invop_calltrap_addr
 246         .align  4
 247         .type   dtrace_invop_calltrap_addr, @object
 248         .size   dtrace_invop_calltrap_addr, 4
 249 dtrace_invop_calltrap_addr:
 250         .word   0
 251         .word   0
 252
 253         .text
 254 #endif
 255
 256 /*
 257  * The next two routines are 64-bit glue code. The first is used to test if
 258  * we are on a 64-bit system. By copying it to the illegal instruction
 259  * handler, we can test for 64-bit mode by trying to execute a 64-bit
 260  * instruction and seeing what happens. The second gets copied in front
 261  * of all the other handlers to restore 32-bit bridge mode when traps
 262  * are taken.
 263  */
 264
 265 /* 64-bit test code. Sets SPRG2 to 0 if an illegal instruction is executed */
 266
 267         .globl  CNAME(testppc64),CNAME(testppc64size)
 268 CNAME(testppc64):
 269         mtsprg1 %r31
 270         mfsrr0  %r31
 271         addi    %r31, %r31, 4
 272         mtsrr0  %r31
 273
 274         li      %r31, 0
 275         mtsprg2 %r31
 276         mfsprg1 %r31
 277
 278         rfi
 279 CNAME(testppc64size) = .-CNAME(testppc64)
 280
 281
 282 /* 64-bit bridge mode restore snippet. Gets copied in front of everything else
 283  * on 64-bit systems. */
 284
 285         .globl  CNAME(restorebridge),CNAME(restorebridgesize)
 286 CNAME(restorebridge):
 287         mtsprg1 %r31
 288         mfmsr   %r31
 289         clrldi  %r31,%r31,1
 290         mtmsrd  %r31
 291         mfsprg1 %r31
 292         isync
 293 CNAME(restorebridgesize) = .-CNAME(restorebridge)
 294
 295 /*
 296  * Processor reset exception handler. These are typically
 297  * the first instructions the processor executes after a
 298  * software reset. We do this in two bits so that we are
 299  * not still hanging around in the trap handling region
 300  * once the MMU is turned on.
 301  */
 302         .globl  CNAME(rstcode), CNAME(rstsize)
 303 CNAME(rstcode):
 304         ba      cpu_reset
 305 CNAME(rstsize) = . - CNAME(rstcode)
 306
 307 cpu_reset:
 308         bl      1f
 309
 310         .space  124
 311
 312 1:
 313         mflr    %r1
 314         addi    %r1,%r1,(124-16)@l
 315
 316         lis     %r3,1@l
 317         bla     CNAME(cpudep_ap_early_bootstrap)
 318         lis     %r3,1@l
 319         bla     CNAME(pmap_cpu_bootstrap)
 320         bla     CNAME(cpudep_ap_bootstrap)
 321         mr      %r1,%r3
 322         bla     CNAME(cpudep_ap_setup)
 323         GET_CPUINFO(%r5)
 324         lwz     %r3,(PC_RESTORE)(%r5)
 325         cmplwi  %cr0,%r3,0
 326         beq     %cr0,2f
 327         li      %r4, 1
 328         b       CNAME(longjmp)
 329 2:
 330 #ifdef SMP
 331         bla     CNAME(machdep_ap_bootstrap)
 332 #endif
 333
 334         /* Should not be reached */
 335 9:
 336         b       9b
 337
 338 /*
 339  * This code gets copied to all the trap vectors
 340  * (except ISI/DSI, ALI, and the interrupts)
 341  */
 342
 343         .globl  CNAME(trapcode),CNAME(trapsize)
 344 CNAME(trapcode):
 345         mtsprg1 %r1                     /* save SP */
 346         mflr    %r1                     /* Save the old LR in r1 */
 347         mtsprg2 %r1                     /* And then in SPRG2 */
 348         li      %r1, 0x20               /* How to get the vector from LR */
 349         bla     generictrap             /* LR & SPRG3 is exception # */
 350 CNAME(trapsize) = .-CNAME(trapcode)
 351
 352 /*
 353  * 64-bit version of trapcode. Identical, except it calls generictrap64.
 354  */
 355         .globl  CNAME(trapcode64)
 356 CNAME(trapcode64):
 357         mtsprg1 %r1                     /* save SP */
 358         mflr    %r1                     /* Save the old LR in r1 */
 359         mtsprg2 %r1                     /* And then in SPRG2 */
 360         li      %r1, 0x20               /* How to get the vector from LR */
 361         bla     generictrap64           /* LR & SPRG3 is exception # */
 362
 363 /*
 364  * For ALI: has to save DSISR and DAR
 365  */
 366         .globl  CNAME(alitrap),CNAME(alisize)
 367 CNAME(alitrap):
 368         mtsprg1 %r1                     /* save SP */
 369         GET_CPUINFO(%r1)
 370         stw     %r28,(PC_TEMPSAVE+CPUSAVE_R28)(%r1)     /* free r28-r31 */
 371         stw     %r29,(PC_TEMPSAVE+CPUSAVE_R29)(%r1)
 372         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R30)(%r1)
 373         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R31)(%r1)
 374         mfdar   %r30
 375         mfdsisr %r31
 376         stw     %r30,(PC_TEMPSAVE+CPUSAVE_AIM_DAR)(%r1)
 377         stw     %r31,(PC_TEMPSAVE+CPUSAVE_AIM_DSISR)(%r1)
 378         mfsprg1 %r1                     /* restore SP, in case of branch */
 379         mflr    %r28                    /* save LR */
 380         mfcr    %r29                    /* save CR */
 381
 382         /* Put our exception vector in SPRG3 */
 383         li      %r31, EXC_ALI
 384         mtsprg3 %r31
 385
 386         /* Test whether we already had PR set */
 387         mfsrr1  %r31
 388         mtcr    %r31
 389         bla     s_trap
 390 CNAME(alisize) = .-CNAME(alitrap)
 391
 392 /*
 393  * G2 specific: instuction TLB miss.
 394  */
 395         .globl  CNAME(imisstrap),CNAME(imisssize)
 396 CNAME(imisstrap):
 397         mfspr %r2, SPR_HASH1            /* get first pointer */
 398         addi %r1, 0, 8                  /* load 8 for counter */
 399         mfctr %r0                       /* save counter */
 400         mfspr %r3, SPR_ICMP             /* get first compare value */
 401         addi %r2, %r2, -8               /* pre dec the pointer */
 402 im0:
 403         mtctr %r1                       /* load counter */
 404 im1:
 405         lwzu %r1, 8(%r2)                /* get next pte */
 406         cmp 0, %r1, %r3                 /* see if found pte */
 407         bdnzf 2, im1                    /* dec count br if cmp ne and if
 408                                          * count not zero */
 409         bne instr_sec_hash              /* if not found set up second hash
 410                                          * or exit */
 411         lwz %r1, +4(%r2)                /* load tlb entry lower-word */
 412         andi. %r3, %r1, 8               /* check G bit */
 413         bne do_isi_prot                 /* if guarded, take an ISI */
 414         mtctr %r0                       /* restore counter */
 415         mfspr %r0, SPR_IMISS            /* get the miss address for the tlbli */
 416         mfspr %r3, SPR_SRR1             /* get the saved cr0 bits */
 417         mtcrf 0x80, %r3                 /* restore CR0 */
 418         mtspr SPR_RPA, %r1              /* set the pte */
 419         ori %r1, %r1, 0x100             /* set reference bit */
 420         srwi %r1, %r1, 8                /* get byte 7 of pte */
 421         tlbli %r0                       /* load the itlb */
 422         stb %r1, +6(%r2)                /* update page table */
 423         rfi                             /* return to executing program */
 424
 425 instr_sec_hash:
 426         andi. %r1, %r3, 0x0040          /* see if we have done second hash */
 427         bne do_isi                      /* if so, go to ISI interrupt */
 428         mfspr %r2, SPR_HASH2            /* get the second pointer */
 429         ori %r3, %r3, 0x0040            /* change the compare value */
 430         addi %r1, %r0, 8                /* load 8 for counter */
 431         addi %r2, %r2, -8               /* pre dec for update on load */
 432         b im0                           /* try second hash */
 433
 434 /* Create a faked ISI interrupt as the address was not found */
 435 do_isi_prot:
 436         mfspr %r3, SPR_SRR1             /* get srr1 */
 437         andi. %r2, %r3, 0xffff          /* clean upper srr1 */
 438         addis %r2, %r2, 0x0800          /* or in srr<4> = 1 to flag prot
 439                                          * violation */
 440         b isi1
 441 do_isi:
 442         mfspr %r3, SPR_SRR1             /* get srr1 */
 443         andi. %r2, %r3, 0xffff          /* clean srr1 */
 444         addis %r2, %r2, 0x4000          /* or in srr1<1> = 1 to flag pte
 445                                          * not found */
 446 isi1:
 447         mtctr %r0                       /* restore counter */
 448         mtspr SPR_SRR1, %r2             /* set srr1 */
 449         mfmsr %r0                       /* get msr */
 450         xoris %r0, %r0, 0x2             /* flip the msr<tgpr> bit */
 451         mtcrf 0x80, %r3                 /* restore CR0 */
 452         mtmsr %r0                       /* flip back to the native gprs */
 453         ba EXC_ISI                      /* go to instr. access interrupt */
 454
 455 CNAME(imisssize) = .-CNAME(imisstrap)
 456
 457 /*
 458  * G2 specific: data load TLB miss.
 459  */
 460         .globl  CNAME(dlmisstrap),CNAME(dlmisssize)
 461 CNAME(dlmisstrap):
 462         mfspr %r2, SPR_HASH1            /* get first pointer */
 463         addi %r1, 0, 8                  /* load 8 for counter */
 464         mfctr %r0                       /* save counter */
 465         mfspr %r3, SPR_DCMP             /* get first compare value */
 466         addi %r2, %r2, -8               /* pre dec the pointer */
 467 dm0:
 468         mtctr %r1                       /* load counter */
 469 dm1:
 470         lwzu %r1, 8(%r2)                /* get next pte */
 471         cmp 0, 0, %r1, %r3              /* see if found pte */
 472         bdnzf 2, dm1                    /* dec count br if cmp ne and if
 473                                          * count not zero */
 474         bne data_sec_hash               /* if not found set up second hash
 475                                          * or exit */
 476         lwz %r1, +4(%r2)                /* load tlb entry lower-word */
 477         mtctr %r0                       /* restore counter */
 478         mfspr %r0, SPR_DMISS            /* get the miss address for the tlbld */
 479         mfspr %r3, SPR_SRR1             /* get the saved cr0 bits */
 480         mtcrf 0x80, %r3                 /* restore CR0 */
 481         mtspr SPR_RPA, %r1              /* set the pte */
 482         ori %r1, %r1, 0x100             /* set reference bit */
 483         srwi %r1, %r1, 8                /* get byte 7 of pte */
 484         tlbld %r0                       /* load the dtlb */
 485         stb %r1, +6(%r2)                /* update page table */
 486         rfi                             /* return to executing program */
 487
 488 data_sec_hash:
 489         andi. %r1, %r3, 0x0040          /* see if we have done second hash */
 490         bne do_dsi                      /* if so, go to DSI interrupt */
 491         mfspr %r2, SPR_HASH2            /* get the second pointer */
 492         ori %r3, %r3, 0x0040            /* change the compare value */
 493         addi %r1, 0, 8                  /* load 8 for counter */
 494         addi %r2, %r2, -8               /* pre dec for update on load */
 495         b dm0                           /* try second hash */
 496
 497 CNAME(dlmisssize) = .-CNAME(dlmisstrap)
 498
 499 /*
 500  *  G2 specific: data store TLB miss.
 501  */
 502         .globl  CNAME(dsmisstrap),CNAME(dsmisssize)
 503 CNAME(dsmisstrap):
 504         mfspr %r2, SPR_HASH1            /* get first pointer */
 505         addi %r1, 0, 8                  /* load 8 for counter */
 506         mfctr %r0                       /* save counter */
 507         mfspr %r3, SPR_DCMP             /* get first compare value */
 508         addi %r2, %r2, -8               /* pre dec the pointer */
 509 ds0:
 510         mtctr %r1                       /* load counter */
 511 ds1:
 512         lwzu %r1, 8(%r2)                /* get next pte */
 513         cmp 0, 0, %r1, %r3              /* see if found pte */
 514         bdnzf 2, ds1                    /* dec count br if cmp ne and if
 515                                          * count not zero */
 516         bne data_store_sec_hash         /* if not found set up second hash
 517                                          * or exit */
 518         lwz %r1, +4(%r2)                /* load tlb entry lower-word */
 519         andi. %r3, %r1, 0x80            /* check the C-bit */
 520         beq data_store_chk_prot         /* if (C==0)
 521                                          *     go check protection modes */
 522 ds2:
 523         mtctr %r0                       /* restore counter */
 524         mfspr %r0, SPR_DMISS            /* get the miss address for the tlbld */
 525         mfspr %r3, SPR_SRR1             /* get the saved cr0 bits */
 526         mtcrf 0x80, %r3                 /* restore CR0 */
 527         mtspr SPR_RPA, %r1              /* set the pte */
 528         tlbld %r0                       /* load the dtlb */
 529         rfi                             /* return to executing program */
 530
 531 data_store_sec_hash:
 532         andi. %r1, %r3, 0x0040          /* see if we have done second hash */
 533         bne do_dsi                      /* if so, go to DSI interrupt */
 534         mfspr %r2, SPR_HASH2            /* get the second pointer */
 535         ori %r3, %r3, 0x0040            /* change the compare value */
 536         addi %r1, 0, 8                  /* load 8 for counter */
 537         addi %r2, %r2, -8               /* pre dec for update on load */
 538         b ds0                           /* try second hash */
 539
 540 /* Check the protection before setting PTE(c-bit) */
 541 data_store_chk_prot:
 542         rlwinm. %r3,%r1,30,0,1          /* test PP */
 543         bge- chk0                       /* if (PP == 00 or PP == 01)
 544                                          *     goto chk0: */
 545         andi. %r3, %r1, 1               /* test PP[0] */
 546         beq+ chk2                       /* return if PP[0] == 0 */
 547         b do_dsi_prot                   /* else DSIp */
 548 chk0:
 549         mfspr %r3,SPR_SRR1              /* get old msr */
 550         andis. %r3,%r3,0x0008           /* test the KEY bit (SRR1-bit 12) */
 551         beq chk2                        /* if (KEY==0) goto chk2: */
 552         b do_dsi_prot                   /* else do_dsi_prot */
 553 chk2:
 554         ori %r1, %r1, 0x180             /* set reference and change bit */
 555         sth %r1, 6(%r2)                 /* update page table */
 556         b ds2                           /* and back we go */
 557
 558 /* Create a faked DSI interrupt as the address was not found */
 559 do_dsi:
 560         mfspr %r3, SPR_SRR1             /* get srr1 */
 561         rlwinm %r1,%r3,9,6,6            /* get srr1<flag> to bit 6 for
 562                                          * load/store, zero rest */
 563         addis %r1, %r1, 0x4000          /* or in dsisr<1> = 1 to flag pte
 564                                          * not found */
 565         b dsi1
 566
 567 do_dsi_prot:
 568         mfspr %r3, SPR_SRR1             /* get srr1 */
 569         rlwinm %r1,%r3,9,6,6            /* get srr1<flag> to bit 6 for
 570                                            *load/store, zero rest */
 571         addis %r1, %r1, 0x0800          /* or in dsisr<4> = 1 to flag prot
 572                                          * violation */
 573
 574 dsi1:
 575         mtctr %r0                       /* restore counter */
 576         andi. %r2, %r3, 0xffff          /* clear upper bits of srr1 */
 577         mtspr SPR_SRR1, %r2             /* set srr1 */
 578         mtspr SPR_DSISR, %r1            /* load the dsisr */
 579         mfspr %r1, SPR_DMISS            /* get miss address */
 580         rlwinm. %r2,%r2,0,31,31         /* test LE bit */
 581         beq dsi2                        /* if little endian then: */
 582         xor %r1, %r1, 0x07              /* de-mung the data address */
 583 dsi2:
 584         mtspr SPR_DAR, %r1              /* put in dar */
 585         mfmsr %r0                       /* get msr */
 586         xoris %r0, %r0, 0x2             /* flip the msr<tgpr> bit */
 587         mtcrf 0x80, %r3                 /* restore CR0 */
 588         mtmsr %r0                       /* flip back to the native gprs */
 589         ba EXC_DSI                      /* branch to DSI interrupt */
 590
 591 CNAME(dsmisssize) = .-CNAME(dsmisstrap)
 592
 593 /*
 594  * Similar to the above for DSI
 595  * Has to handle BAT spills
 596  * and standard pagetable spills
 597  */
 598         .globl  CNAME(dsitrap),CNAME(dsisize)
 599 CNAME(dsitrap):
 600         mtsprg1 %r1                     /* save SP */
 601         GET_CPUINFO(%r1)
 602         stw     %r28,(PC_DISISAVE+CPUSAVE_R28)(%r1)     /* free r28-r31 */
 603         stw     %r29,(PC_DISISAVE+CPUSAVE_R29)(%r1)
 604         stw     %r30,(PC_DISISAVE+CPUSAVE_R30)(%r1)
 605         stw     %r31,(PC_DISISAVE+CPUSAVE_R31)(%r1)
 606         mfsprg1 %r1                     /* restore SP */
 607         mfcr    %r29                    /* save CR */
 608         mfxer   %r30                    /* save XER */
 609         mtsprg2 %r30                    /* in SPRG2 */
 610         mfsrr1  %r31                    /* test kernel mode */
 611         mtcr    %r31
 612         bt      17,1f                   /* branch if PSL_PR is set */
 613         mfdar   %r31                    /* get fault address */
 614         rlwinm  %r31,%r31,7,25,28       /* get segment * 8 */
 615
 616         /* get batu */
 617         addis   %r31,%r31,CNAME(battable)@ha
 618         lwz     %r30,CNAME(battable)@l(31)
 619         mtcr    %r30
 620         bf      30,1f                   /* branch if supervisor valid is
 621                                            false */
 622         /* get batl */
 623         lwz     %r31,CNAME(battable)+4@l(31)
 624 /* We randomly use the highest two bat registers here */
 625         mftb    %r28
 626         andi.   %r28,%r28,1
 627         bne     2f
 628         mtdbatu 2,%r30
 629         mtdbatl 2,%r31
 630         b       3f
 631 2:
 632         mtdbatu 3,%r30
 633         mtdbatl 3,%r31
 634 3:
 635         mfsprg2 %r30                    /* restore XER */
 636         mtxer   %r30
 637         mtcr    %r29                    /* restore CR */
 638         mtsprg1 %r1
 639         GET_CPUINFO(%r1)
 640         lwz     %r28,(PC_DISISAVE+CPUSAVE_R28)(%r1)     /* restore r28-r31 */
 641         lwz     %r29,(PC_DISISAVE+CPUSAVE_R29)(%r1)
 642         lwz     %r30,(PC_DISISAVE+CPUSAVE_R30)(%r1)
 643         lwz     %r31,(PC_DISISAVE+CPUSAVE_R31)(%r1)
 644         mfsprg1 %r1
 645         rfi                             /* return to trapped code */
 646 1:
 647         mflr    %r28                    /* save LR (SP already saved) */
 648         bla     disitrap
 649 CNAME(dsisize) = .-CNAME(dsitrap)
 650
 651 /*
 652  * Preamble code for DSI/ISI traps
 653  */
 654 disitrap:
 655         /* Write the trap vector to SPRG3 by computing LR & 0xff00 */
 656         mflr    %r1
 657         andi.   %r1,%r1,0xff00
 658         mtsprg3 %r1
 659
 660         GET_CPUINFO(%r1)
 661         lwz     %r30,(PC_DISISAVE+CPUSAVE_R28)(%r1)
 662         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R28)(%r1)
 663         lwz     %r31,(PC_DISISAVE+CPUSAVE_R29)(%r1)
 664         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R29)(%r1)
 665         lwz     %r30,(PC_DISISAVE+CPUSAVE_R30)(%r1)
 666         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R30)(%r1)
 667         lwz     %r31,(PC_DISISAVE+CPUSAVE_R31)(%r1)
 668         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R31)(%r1)
 669         mfdar   %r30
 670         mfdsisr %r31
 671         stw     %r30,(PC_TEMPSAVE+CPUSAVE_AIM_DAR)(%r1)
 672         stw     %r31,(PC_TEMPSAVE+CPUSAVE_AIM_DSISR)(%r1)
 673
 674 #ifdef KDB
 675         /* Try to detect a kernel stack overflow */
 676         mfsrr1  %r31
 677         mtcr    %r31
 678         bt      17,realtrap             /* branch is user mode */
 679         mfsprg1 %r31                    /* get old SP */
 680         clrrwi  %r31,%r31,12            /* Round SP down to nearest page */
 681         sub.    %r30,%r31,%r30          /* SP - DAR */
 682         bge     1f
 683         neg     %r30,%r30               /* modulo value */
 684 1:      cmplwi  %cr0,%r30,4096          /* is DAR within a page of SP? */
 685         bge     %cr0,realtrap           /* no, too far away. */
 686
 687         /* Now convert this DSI into a DDB trap.  */
 688         GET_CPUINFO(%r1)
 689         lwz     %r30,(PC_TEMPSAVE+CPUSAVE_AIM_DAR)(%r1) /* get DAR */
 690         stw     %r30,(PC_DBSAVE  +CPUSAVE_AIM_DAR)(%r1) /* save DAR */
 691         lwz     %r31,(PC_TEMPSAVE+CPUSAVE_AIM_DSISR)(%r1) /* get DSISR */
 692         stw     %r31,(PC_DBSAVE  +CPUSAVE_AIM_DSISR)(%r1) /* save DSISR */
 693         lwz     %r30,(PC_DISISAVE+CPUSAVE_R28)(%r1) /* get  r28 */
 694         stw     %r30,(PC_DBSAVE  +CPUSAVE_R28)(%r1) /* save r28 */
 695         lwz     %r31,(PC_DISISAVE+CPUSAVE_R29)(%r1) /* get  r29 */
 696         stw     %r31,(PC_DBSAVE  +CPUSAVE_R29)(%r1) /* save r29 */
 697         lwz     %r30,(PC_DISISAVE+CPUSAVE_R30)(%r1) /* get  r30 */
 698         stw     %r30,(PC_DBSAVE  +CPUSAVE_R30)(%r1) /* save r30 */
 699         lwz     %r31,(PC_DISISAVE+CPUSAVE_R31)(%r1) /* get  r31 */
 700         stw     %r31,(PC_DBSAVE  +CPUSAVE_R31)(%r1) /* save r31 */
 701         b       dbtrap
 702 #endif
 703
 704         /* XXX need stack probe here */
 705 realtrap:
 706 /* Test whether we already had PR set */
 707         mfsrr1  %r1
 708         mtcr    %r1
 709         mfsprg1 %r1                     /* restore SP (might have been
 710                                            overwritten) */
 711         bf      17,k_trap               /* branch if PSL_PR is false */
 712         GET_CPUINFO(%r1)
 713         lwz     %r1,PC_CURPCB(%r1)
 714         RESTORE_KERN_SRS(%r30,%r31)     /* enable kernel mapping */
 715         ba s_trap
 716
 717 /*
 718  * generictrap does some standard setup for trap handling to minimize
 719  * the code that need be installed in the actual vectors. It expects
 720  * the following conditions.
 721  *
 722  * R1 - Trap vector = LR & (0xff00 | R1)
 723  * SPRG1 - Original R1 contents
 724  * SPRG2 - Original LR
 725  */
 726
 727 generictrap64:
 728         mtsprg3 %r31
 729         mfmsr   %r31
 730         clrldi  %r31,%r31,1
 731         mtmsrd  %r31
 732         mfsprg3 %r31
 733         isync
 734
 735 generictrap:
 736         /* Save R1 for computing the exception vector */
 737         mtsprg3 %r1
 738
 739         /* Save interesting registers */
 740         GET_CPUINFO(%r1)
 741         stw     %r28,(PC_TEMPSAVE+CPUSAVE_R28)(%r1)     /* free r28-r31 */
 742         stw     %r29,(PC_TEMPSAVE+CPUSAVE_R29)(%r1)
 743         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R30)(%r1)
 744         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R31)(%r1)
 745         mfsprg1 %r1                     /* restore SP, in case of branch */
 746         mfsprg2 %r28                    /* save LR */
 747         mfcr    %r29                    /* save CR */
 748
 749         /* Compute the exception vector from the link register */
 750         mfsprg3 %r31
 751         ori     %r31,%r31,0xff00
 752         mflr    %r30
 753         and     %r30,%r30,%r31
 754         mtsprg3 %r30
 755
 756         /* Test whether we already had PR set */
 757         mfsrr1  %r31
 758         mtcr    %r31
 759
 760 s_trap:
 761         bf      17,k_trap               /* branch if PSL_PR is false */
 762         GET_CPUINFO(%r1)
 763 u_trap:
 764         lwz     %r1,PC_CURPCB(%r1)
 765         RESTORE_KERN_SRS(%r30,%r31)     /* enable kernel mapping */
 766
 767 /*
 768  * Now the common trap catching code.
 769  */
 770 k_trap:
 771         FRAME_SETUP(PC_TEMPSAVE)
 772         /* Restore USER_SR */
 773         GET_CPUINFO(%r30)
 774         lwz     %r30,PC_CURPCB(%r30)
 775         lwz     %r30,PCB_AIM_USR_VSID(%r30)
 776         mtsr    USER_SR,%r30; sync; isync
 777 /* Call C interrupt dispatcher: */
 778 trapagain:
 779         addi    %r3,%r1,8
 780         bl      CNAME(powerpc_interrupt)
 781         .globl  CNAME(trapexit)         /* backtrace code sentinel */
 782 CNAME(trapexit):
 783
 784 /* Disable interrupts: */
 785         mfmsr   %r3
 786         andi.   %r3,%r3,~PSL_EE@l
 787         mtmsr   %r3
 788 /* Test AST pending: */
 789         lwz     %r5,FRAME_SRR1+8(%r1)
 790         mtcr    %r5
 791         bf      17,1f                   /* branch if PSL_PR is false */
 792
 793         GET_CPUINFO(%r3)                /* get per-CPU pointer */
 794         lwz     %r4, TD_FLAGS(%r2)      /* get thread flags value
 795                                          * (r2 is curthread) */
 796         lis     %r5, (TDF_ASTPENDING|TDF_NEEDRESCHED)@h
 797         ori     %r5,%r5, (TDF_ASTPENDING|TDF_NEEDRESCHED)@l
 798         and.    %r4,%r4,%r5
 799         beq     1f
 800         mfmsr   %r3                     /* re-enable interrupts */
 801         ori     %r3,%r3,PSL_EE@l
 802         mtmsr   %r3
 803         isync
 804         addi    %r3,%r1,8
 805         bl      CNAME(ast)
 806         .globl  CNAME(asttrapexit)      /* backtrace code sentinel #2 */
 807 CNAME(asttrapexit):
 808         b       trapexit                /* test ast ret value ? */
 809 1:
 810         FRAME_LEAVE(PC_TEMPSAVE)
 811
 812         .globl  CNAME(rfi_patch1)       /* replace rfi with rfid on ppc64 */
 813 CNAME(rfi_patch1):
 814         rfi
 815
 816         .globl  CNAME(rfid_patch)
 817 CNAME(rfid_patch):
 818         rfid
 819
 820 #if defined(KDB)
 821 /*
 822  * Deliberate entry to dbtrap
 823  */
 824         .globl  CNAME(breakpoint)
 825 CNAME(breakpoint):
 826         mtsprg1 %r1
 827         mfmsr   %r3
 828         mtsrr1  %r3
 829         andi.   %r3,%r3,~(PSL_EE|PSL_ME)@l
 830         mtmsr   %r3                     /* disable interrupts */
 831         isync
 832         GET_CPUINFO(%r3)
 833         stw     %r28,(PC_DBSAVE+CPUSAVE_R28)(%r3)
 834         stw     %r29,(PC_DBSAVE+CPUSAVE_R29)(%r3)
 835         stw     %r30,(PC_DBSAVE+CPUSAVE_R30)(%r3)
 836         stw     %r31,(PC_DBSAVE+CPUSAVE_R31)(%r3)
 837         mflr    %r28
 838         li      %r29,EXC_BPT
 839         mtlr    %r29
 840         mfcr    %r29
 841         mtsrr0  %r28
 842
 843 /*
 844  * Now the kdb trap catching code.
 845  */
 846 dbtrap:
 847         /* Write the trap vector to SPRG3 by computing LR & 0xff00 */
 848         mflr    %r1
 849         andi.   %r1,%r1,0xff00
 850         mtsprg3 %r1
 851
 852         lis     %r1,(tmpstk+TMPSTKSZ-16)@ha     /* get new SP */
 853         addi    %r1,%r1,(tmpstk+TMPSTKSZ-16)@l
 854
 855         FRAME_SETUP(PC_DBSAVE)
 856 /* Call C trap code: */
 857         addi    %r3,%r1,8
 858         bl      CNAME(db_trap_glue)
 859         or.     %r3,%r3,%r3
 860         bne     dbleave
 861 /* This wasn't for KDB, so switch to real trap: */
 862         lwz     %r3,FRAME_EXC+8(%r1)    /* save exception */
 863         GET_CPUINFO(%r4)
 864         stw     %r3,(PC_DBSAVE+CPUSAVE_R31)(%r4)
 865         FRAME_LEAVE(PC_DBSAVE)
 866         mtsprg1 %r1                     /* prepare for entrance to realtrap */
 867         GET_CPUINFO(%r1)
 868         stw     %r28,(PC_TEMPSAVE+CPUSAVE_R28)(%r1)
 869         stw     %r29,(PC_TEMPSAVE+CPUSAVE_R29)(%r1)
 870         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R30)(%r1)
 871         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R31)(%r1)
 872         mflr    %r28
 873         mfcr    %r29
 874         lwz     %r31,(PC_DBSAVE+CPUSAVE_R31)(%r1)
 875         mtsprg3 %r31                    /* SPRG3 was clobbered by FRAME_LEAVE */
 876         mfsprg1 %r1
 877         b       realtrap
 878 dbleave:
 879         FRAME_LEAVE(PC_DBSAVE)
 880         .globl  CNAME(rfi_patch2)       /* replace rfi with rfid on ppc64 */
 881 CNAME(rfi_patch2):
 882         rfi
 883
 884 /*
 885  * In case of KDB we want a separate trap catcher for it
 886  */
 887         .globl  CNAME(dblow),CNAME(dbsize)
 888 CNAME(dblow):
 889         mtsprg1 %r1                     /* save SP */
 890         mtsprg2 %r29                    /* save r29 */
 891         mfcr    %r29                    /* save CR in r29 */
 892         mfsrr1  %r1
 893         mtcr    %r1
 894         bf      17,2f                   /* branch if privileged */
 895 1:
 896         /* Unprivileged case */
 897         mtcr    %r29                    /* put the condition register back */
 898         mfsprg2 %r29                    /* ... and r29 */
 899         mflr    %r1                     /* save LR */
 900         mtsprg2 %r1                     /* And then in SPRG2 */
 901         li      %r1, 0                  /* How to get the vector from LR */
 902
 903         bla     generictrap             /* and we look like a generic trap */
 904 2:
 905 #ifdef KDTRACE_HOOKS
 906         /* Privileged, so drop to KDB */
 907         mfsrr0  %r1
 908         mtsprg3 %r3
 909         lwz     %r1,0(%r1)
 910         /* Check if it's a DTrace trap. */
 911         li      %r3,0x0808
 912         addis   %r3,%r3,0x7c81
 913         cmplw   %cr0,%r3,%r1
 914         mfsprg3 %r3
 915         beq     %cr0,1b
 916 #endif
 917         /* Privileged, so drop to KDB */
 918         GET_CPUINFO(%r1)
 919         stw     %r28,(PC_DBSAVE+CPUSAVE_R28)(%r1)       /* free r28 */
 920         mfsprg2 %r28                            /* r29 holds cr...  */
 921         stw     %r28,(PC_DBSAVE+CPUSAVE_R29)(%r1)       /* free r29 */
 922         stw     %r30,(PC_DBSAVE+CPUSAVE_R30)(%r1)       /* free r30 */
 923         stw     %r31,(PC_DBSAVE+CPUSAVE_R31)(%r1)       /* free r31 */
 924         mflr    %r28                                    /* save LR */
 925         bla     dbtrap
 926 CNAME(dbsize) = .-CNAME(dblow)
 927 #endif /* KDB */