sys/powerpc/aim/swtch.S

   1 /* $FreeBSD$ */
   2 /* $NetBSD: locore.S,v 1.24 2000/05/31 05:09:17 thorpej Exp $ */
   3
   4 /*-
   5  * Copyright (C) 2001 Benno Rice
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY Benno Rice ``AS IS'' AND ANY EXPRESS OR
  18  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  19  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  21  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  22  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  23  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  24  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  25  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  26  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27 */
  28 /*-
  29  * Copyright (C) 1995, 1996 Wolfgang Solfrank.
  30  * Copyright (C) 1995, 1996 TooLs GmbH.
  31  * All rights reserved.
  32  *
  33  * Redistribution and use in source and binary forms, with or without
  34  * modification, are permitted provided that the following conditions
  35  * are met:
  36  * 1. Redistributions of source code must retain the above copyright
  37  *    notice, this list of conditions and the following disclaimer.
  38  * 2. Redistributions in binary form must reproduce the above copyright
  39  *    notice, this list of conditions and the following disclaimer in the
  40  *    documentation and/or other materials provided with the distribution.
  41  * 3. All advertising materials mentioning features or use of this software
  42  *    must display the following acknowledgement:
  43  *      This product includes software developed by TooLs GmbH.
  44  * 4. The name of TooLs GmbH may not be used to endorse or promote products
  45  *    derived from this software without specific prior written permission.
  46  *
  47  * THIS SOFTWARE IS PROVIDED BY TOOLS GMBH ``AS IS'' AND ANY EXPRESS OR
  48  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  49  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  50  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  51  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  52  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  53  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  54  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  55  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  56  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  57  */
  58
  59 #include "assym.s"
  60
  61 #include <sys/syscall.h>
  62
  63 #include <machine/trap.h>
  64 #include <machine/param.h>
  65 #include <machine/sr.h>
  66 #include <machine/psl.h>
  67 #include <machine/asm.h>
  68
  69 /*
  70  * void cpu_throw(struct thread *old, struct thread *new)
  71  */
  72 ENTRY(cpu_throw)
  73         mr      %r15, %r4
  74         b       cpu_switchin
  75
  76 /*
  77  * void cpu_switch(struct thread *old,
  78  *                 struct thread *new,
  79  *                 struct mutex *mtx);
  80  *
  81  * Switch to a new thread saving the current state in the old thread.
  82  */
  83 ENTRY(cpu_switch)
  84         stw     %r5,TD_LOCK(%r3)        /* ULE: update old thread's lock */
  85                                         /* XXX needs to change for MP */
  86
  87         lwz     %r5,TD_PCB(%r3)         /* Get the old thread's PCB ptr */
  88         mr      %r12,%r2
  89         stmw    %r12,PCB_CONTEXT(%r5)   /* Save the non-volatile GP regs.
  90                                            These can now be used for scratch */
  91
  92         mfcr    %r16                    /* Save the condition register */
  93         stw     %r16,PCB_CR(%r5)
  94         mflr    %r16                    /* Save the link register */
  95         stw     %r16,PCB_LR(%r5)
  96         mfsr    %r16,USER_SR            /* Save USER_SR for copyin/out */
  97         isync
  98         stw     %r16,PCB_AIM_USR(%r5)
  99         stw     %r1,PCB_SP(%r5)         /* Save the stack pointer */
 100
 101         mr      %r14,%r3                /* Copy the old thread ptr... */
 102         mr      %r15,%r4                /* and the new thread ptr in scratch */
 103
 104         lwz     %r6,PCB_FLAGS(%r5)
 105         /* Save FPU context if needed */
 106         andi.   %r6, %r6, PCB_FPU
 107         beq     .L1
 108         bl      save_fpu
 109
 110 .L1:
 111         lwz     %r6,PCB_FLAGS(%r5)
 112         /* Save Altivec context if needed */
 113         andi.   %r6, %r6, PCB_VEC
 114         beq     .L2
 115         bl      save_vec
 116
 117 .L2:
 118         mr      %r3,%r14                /* restore old thread ptr */
 119         bl      pmap_deactivate         /* Deactivate the current pmap */
 120
 121 cpu_switchin:
 122         mfsprg  %r7,0                   /* Get the pcpu pointer */
 123         stw     %r15,PC_CURTHREAD(%r7)  /* Store new current thread */
 124         lwz     %r17,TD_PCB(%r15)       /* Store new current PCB */
 125         stw     %r17,PC_CURPCB(%r7)
 126
 127         mr      %r3,%r15                /* Get new thread ptr */
 128         bl      pmap_activate           /* Activate the new address space */
 129
 130         lwz     %r6, PCB_FLAGS(%r17)
 131         /* Restore FPU context if needed */
 132         andi.   %r6, %r6, PCB_FPU
 133         beq     .L3
 134         mr      %r3,%r15                /* Pass curthread to enable_fpu */
 135         bl      enable_fpu
 136
 137 .L3:
 138         lwz     %r6, PCB_FLAGS(%r17)
 139         /* Restore Altivec context if needed */
 140         andi.   %r6, %r6, PCB_VEC
 141         beq     .L4
 142         mr      %r3,%r15                /* Pass curthread to enable_vec */
 143         bl      enable_vec
 144
 145         /* thread to restore is in r3 */
 146 .L4:
 147         mr      %r3,%r17                /* Recover PCB ptr */
 148         lmw     %r12,PCB_CONTEXT(%r3)   /* Load the non-volatile GP regs */
 149         mr      %r2,%r12
 150         lwz     %r5,PCB_CR(%r3)         /* Load the condition register */
 151         mtcr    %r5
 152         lwz     %r5,PCB_LR(%r3)         /* Load the link register */
 153         mtlr    %r5
 154         lwz     %r5,PCB_AIM_USR(%r3)    /* Load the USER_SR segment reg */
 155         mtsr    USER_SR,%r5
 156         isync
 157         lwz     %r1,PCB_SP(%r3)         /* Load the stack pointer */
 158         /*
 159          * Perform a dummy stwcx. to clear any reservations we may have
 160          * inherited from the previous thread. It doesn't matter if the
 161          * stwcx succeeds or not. pcb_context[0] can be clobbered.
 162          */
 163         stwcx.  %r1, 0, %r3
 164         blr
 165
 166 /*
 167  * savectx(pcb)
 168  * Update pcb, saving current processor state
 169  */
 170 ENTRY(savectx)
 171         mr      %r12,%r2
 172         stmw    %r12,PCB_CONTEXT(%r3)   /* Save the non-volatile GP regs */
 173         mfcr    %r4                     /* Save the condition register */
 174         stw     %r4,PCB_CONTEXT(%r3)
 175         blr
 176
 177 /*
 178  * fork_trampoline()
 179  * Set up the return from cpu_fork()
 180  */
 181 ENTRY(fork_trampoline)
 182         lwz     %r3,CF_FUNC(%r1)
 183         lwz     %r4,CF_ARG0(%r1)
 184         lwz     %r5,CF_ARG1(%r1)
 185         bl      fork_exit
 186         addi    %r1,%r1,CF_SIZE-FSP     /* Allow 8 bytes in front of
 187                                            trapframe to simulate FRAME_SETUP
 188                                            does when allocating space for
 189                                            a frame pointer/saved LR */
 190         b       trapexit