sys/powerpc/aim/trap_subr.S

   1 /* $FreeBSD$ */
   2 /* $NetBSD: trap_subr.S,v 1.20 2002/04/22 23:20:08 kleink Exp $ */
   3
   4 /*-
   5  * Copyright (C) 1995, 1996 Wolfgang Solfrank.
   6  * Copyright (C) 1995, 1996 TooLs GmbH.
   7  * All rights reserved.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed by TooLs GmbH.
  20  * 4. The name of TooLs GmbH may not be used to endorse or promote products
  21  *    derived from this software without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY TOOLS GMBH ``AS IS'' AND ANY EXPRESS OR
  24  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  25  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  26  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  27  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  28  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  29  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  30  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  31  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  32  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  33  */
  34
  35 /*
  36  * NOTICE: This is not a standalone file.  to use it, #include it in
  37  * your port's locore.S, like so:
  38  *
  39  *      #include <powerpc/aim/trap_subr.S>
  40  */
  41
  42 /*
  43  * Save/restore segment registers
  44  */
  45 #define RESTORE_SRS(pmap,sr)    mtsr    0,sr; \
  46         lwz     sr,1*4(pmap);   mtsr    1,sr; \
  47         lwz     sr,2*4(pmap);   mtsr    2,sr; \
  48         lwz     sr,3*4(pmap);   mtsr    3,sr; \
  49         lwz     sr,4*4(pmap);   mtsr    4,sr; \
  50         lwz     sr,5*4(pmap);   mtsr    5,sr; \
  51         lwz     sr,6*4(pmap);   mtsr    6,sr; \
  52         lwz     sr,7*4(pmap);   mtsr    7,sr; \
  53         lwz     sr,8*4(pmap);   mtsr    8,sr; \
  54         lwz     sr,9*4(pmap);   mtsr    9,sr; \
  55         lwz     sr,10*4(pmap);  mtsr    10,sr; \
  56         lwz     sr,11*4(pmap);  mtsr    11,sr; \
  57         lwz     sr,12*4(pmap);  mtsr    12,sr; \
  58         lwz     sr,13*4(pmap);  mtsr    13,sr; \
  59         lwz     sr,14*4(pmap);  mtsr    14,sr; \
  60         lwz     sr,15*4(pmap);  mtsr    15,sr; isync;
  61
  62 /*
  63  * User SRs are loaded through a pointer to the current pmap.
  64  */
  65 #define RESTORE_USER_SRS(pmap,sr) \
  66         GET_CPUINFO(pmap); \
  67         lwz     pmap,PC_CURPMAP(pmap); \
  68         lwzu    sr,PM_SR(pmap); \
  69         RESTORE_SRS(pmap,sr)
  70
  71 /*
  72  * Kernel SRs are loaded directly from kernel_pmap_
  73  */
  74 #define RESTORE_KERN_SRS(pmap,sr) \
  75         lis     pmap,CNAME(kernel_pmap_store)@ha; \
  76         lwzu    sr,CNAME(kernel_pmap_store)+PM_SR@l(pmap); \
  77         RESTORE_SRS(pmap,sr)
  78
  79 /*
  80  * FRAME_SETUP assumes:
  81  *      SPRG1           SP (1)
  82  *      SPRG3           trap type
  83  *      savearea        r28-r31,DAR,DSISR   (DAR & DSISR only for DSI traps)
  84  *      r28             LR
  85  *      r29             CR
  86  *      r30             scratch
  87  *      r31             scratch
  88  *      r1              kernel stack
  89  *      SRR0/1          as at start of trap
  90  */
  91 #define FRAME_SETUP(savearea)                                           \
  92 /* Have to enable translation to allow access of kernel stack: */       \
  93         GET_CPUINFO(%r31);                                              \
  94         mfsrr0  %r30;                                                   \
  95         stw     %r30,(savearea+CPUSAVE_SRR0)(%r31);     /* save SRR0 */ \
  96         mfsrr1  %r30;                                                   \
  97         stw     %r30,(savearea+CPUSAVE_SRR1)(%r31);     /* save SRR1 */ \
  98         mfmsr   %r30;                                                   \
  99         ori     %r30,%r30,(PSL_DR|PSL_IR|PSL_RI)@l; /* relocation on */ \
 100         mtmsr   %r30;                   /* stack can now be accessed */ \
 101         isync;                                                          \
 102         mfsprg1 %r31;                   /* get saved SP */              \
 103         stwu    %r31,-FRAMELEN(%r1);    /* save it in the callframe */  \
 104         stw     %r0, FRAME_0+8(%r1);    /* save r0 in the trapframe */  \
 105         stw     %r31,FRAME_1+8(%r1);    /* save SP   "      "       */  \
 106         stw     %r2, FRAME_2+8(%r1);    /* save r2   "      "       */  \
 107         stw     %r28,FRAME_LR+8(%r1);   /* save LR   "      "       */  \
 108         stw     %r29,FRAME_CR+8(%r1);   /* save CR   "      "       */  \
 109         GET_CPUINFO(%r2);                                               \
 110         lwz     %r28,(savearea+CPUSAVE_R28)(%r2); /* get saved r28 */   \
 111         lwz     %r29,(savearea+CPUSAVE_R29)(%r2); /* get saved r29 */   \
 112         lwz     %r30,(savearea+CPUSAVE_R30)(%r2); /* get saved r30 */   \
 113         lwz     %r31,(savearea+CPUSAVE_R31)(%r2); /* get saved r31 */   \
 114         stw     %r3,  FRAME_3+8(%r1);   /* save r3-r31 */               \
 115         stw     %r4,  FRAME_4+8(%r1);                                   \
 116         stw     %r5,  FRAME_5+8(%r1);                                   \
 117         stw     %r6,  FRAME_6+8(%r1);                                   \
 118         stw     %r7,  FRAME_7+8(%r1);                                   \
 119         stw     %r8,  FRAME_8+8(%r1);                                   \
 120         stw     %r9,  FRAME_9+8(%r1);                                   \
 121         stw     %r10, FRAME_10+8(%r1);                                  \
 122         stw     %r11, FRAME_11+8(%r1);                                  \
 123         stw     %r12, FRAME_12+8(%r1);                                  \
 124         stw     %r13, FRAME_13+8(%r1);                                  \
 125         stw     %r14, FRAME_14+8(%r1);                                  \
 126         stw     %r15, FRAME_15+8(%r1);                                  \
 127         stw     %r16, FRAME_16+8(%r1);                                  \
 128         stw     %r17, FRAME_17+8(%r1);                                  \
 129         stw     %r18, FRAME_18+8(%r1);                                  \
 130         stw     %r19, FRAME_19+8(%r1);                                  \
 131         stw     %r20, FRAME_20+8(%r1);                                  \
 132         stw     %r21, FRAME_21+8(%r1);                                  \
 133         stw     %r22, FRAME_22+8(%r1);                                  \
 134         stw     %r23, FRAME_23+8(%r1);                                  \
 135         stw     %r24, FRAME_24+8(%r1);                                  \
 136         stw     %r25, FRAME_25+8(%r1);                                  \
 137         stw     %r26, FRAME_26+8(%r1);                                  \
 138         stw     %r27, FRAME_27+8(%r1);                                  \
 139         stw     %r28, FRAME_28+8(%r1);                                  \
 140         stw     %r29, FRAME_29+8(%r1);                                  \
 141         stw     %r30, FRAME_30+8(%r1);                                  \
 142         stw     %r31, FRAME_31+8(%r1);                                  \
 143         lwz     %r28,(savearea+CPUSAVE_AIM_DAR)(%r2);  /* saved DAR */  \
 144         lwz     %r29,(savearea+CPUSAVE_AIM_DSISR)(%r2);/* saved DSISR */\
 145         lwz     %r30,(savearea+CPUSAVE_SRR0)(%r2); /* saved SRR0 */     \
 146         lwz     %r31,(savearea+CPUSAVE_SRR1)(%r2); /* saved SRR1 */     \
 147         mfxer   %r3;                                                    \
 148         mfctr   %r4;                                                    \
 149         mfsprg3 %r5;                                                    \
 150         stw     %r3, FRAME_XER+8(1);    /* save xer/ctr/exc */          \
 151         stw     %r4, FRAME_CTR+8(1);                                    \
 152         stw     %r5, FRAME_EXC+8(1);                                    \
 153         stw     %r28,FRAME_AIM_DAR+8(1);                                \
 154         stw     %r29,FRAME_AIM_DSISR+8(1); /* save dsisr/srr0/srr1 */   \
 155         stw     %r30,FRAME_SRR0+8(1);                                   \
 156         stw     %r31,FRAME_SRR1+8(1)
 157
 158 #define FRAME_LEAVE(savearea)                                           \
 159 /* Now restore regs: */                                                 \
 160         lwz     %r2,FRAME_SRR0+8(%r1);                                  \
 161         lwz     %r3,FRAME_SRR1+8(%r1);                                  \
 162         lwz     %r4,FRAME_CTR+8(%r1);                                   \
 163         lwz     %r5,FRAME_XER+8(%r1);                                   \
 164         lwz     %r6,FRAME_LR+8(%r1);                                    \
 165         GET_CPUINFO(%r7);                                               \
 166         stw     %r2,(savearea+CPUSAVE_SRR0)(%r7); /* save SRR0 */       \
 167         stw     %r3,(savearea+CPUSAVE_SRR1)(%r7); /* save SRR1 */       \
 168         lwz     %r7,FRAME_CR+8(%r1);                                    \
 169         mtctr   %r4;                                                    \
 170         mtxer   %r5;                                                    \
 171         mtlr    %r6;                                                    \
 172         mtsprg1 %r7;                    /* save cr */                   \
 173         lwz     %r31,FRAME_31+8(%r1);   /* restore r0-31 */             \
 174         lwz     %r30,FRAME_30+8(%r1);                                   \
 175         lwz     %r29,FRAME_29+8(%r1);                                   \
 176         lwz     %r28,FRAME_28+8(%r1);                                   \
 177         lwz     %r27,FRAME_27+8(%r1);                                   \
 178         lwz     %r26,FRAME_26+8(%r1);                                   \
 179         lwz     %r25,FRAME_25+8(%r1);                                   \
 180         lwz     %r24,FRAME_24+8(%r1);                                   \
 181         lwz     %r23,FRAME_23+8(%r1);                                   \
 182         lwz     %r22,FRAME_22+8(%r1);                                   \
 183         lwz     %r21,FRAME_21+8(%r1);                                   \
 184         lwz     %r20,FRAME_20+8(%r1);                                   \
 185         lwz     %r19,FRAME_19+8(%r1);                                   \
 186         lwz     %r18,FRAME_18+8(%r1);                                   \
 187         lwz     %r17,FRAME_17+8(%r1);                                   \
 188         lwz     %r16,FRAME_16+8(%r1);                                   \
 189         lwz     %r15,FRAME_15+8(%r1);                                   \
 190         lwz     %r14,FRAME_14+8(%r1);                                   \
 191         lwz     %r13,FRAME_13+8(%r1);                                   \
 192         lwz     %r12,FRAME_12+8(%r1);                                   \
 193         lwz     %r11,FRAME_11+8(%r1);                                   \
 194         lwz     %r10,FRAME_10+8(%r1);                                   \
 195         lwz     %r9, FRAME_9+8(%r1);                                    \
 196         lwz     %r8, FRAME_8+8(%r1);                                    \
 197         lwz     %r7, FRAME_7+8(%r1);                                    \
 198         lwz     %r6, FRAME_6+8(%r1);                                    \
 199         lwz     %r5, FRAME_5+8(%r1);                                    \
 200         lwz     %r4, FRAME_4+8(%r1);                                    \
 201         lwz     %r3, FRAME_3+8(%r1);                                    \
 202         lwz     %r2, FRAME_2+8(%r1);                                    \
 203         lwz     %r0, FRAME_0+8(%r1);                                    \
 204         lwz     %r1, FRAME_1+8(%r1);                                    \
 205 /* Can't touch %r1 from here on */                                      \
 206         mtsprg2 %r2;                    /* save r2 & r3 */              \
 207         mtsprg3 %r3;                                                    \
 208 /* Disable translation, machine check and recoverability: */            \
 209         mfmsr   %r2;                                                    \
 210         andi.   %r2,%r2,~(PSL_DR|PSL_IR|PSL_EE|PSL_ME|PSL_RI)@l;        \
 211         mtmsr   %r2;                                                    \
 212         isync;                                                          \
 213 /* Decide whether we return to user mode: */                            \
 214         GET_CPUINFO(%r2);                                               \
 215         lwz     %r3,(savearea+CPUSAVE_SRR1)(%r2);                       \
 216         mtcr    %r3;                                                    \
 217         bf      17,1f;                  /* branch if PSL_PR is false */ \
 218 /* Restore user SRs */                                                  \
 219         RESTORE_USER_SRS(%r2,%r3);                                      \
 220 1:      mfsprg1 %r2;                    /* restore cr */                \
 221         mtcr    %r2;                                                    \
 222         GET_CPUINFO(%r2);                                               \
 223         lwz     %r3,(savearea+CPUSAVE_SRR0)(%r2); /* restore srr0 */    \
 224         mtsrr0  %r3;                                                    \
 225         lwz     %r3,(savearea+CPUSAVE_SRR1)(%r2); /* restore srr1 */    \
 226                                                                         \
 227         /* Make sure HV bit of MSR propagated to SRR1 */                \
 228         mfmsr   %r2;                                                    \
 229         or      %r3,%r2,%r3;                                            \
 230                                                                         \
 231         mtsrr1  %r3;                                                    \
 232         mfsprg2 %r2;                    /* restore r2 & r3 */           \
 233         mfsprg3 %r3
 234
 235 /*
 236  * The next two routines are 64-bit glue code. The first is used to test if
 237  * we are on a 64-bit system. By copying it to the illegal instruction
 238  * handler, we can test for 64-bit mode by trying to execute a 64-bit
 239  * instruction and seeing what happens. The second gets copied in front
 240  * of all the other handlers to restore 32-bit bridge mode when traps
 241  * are taken.
 242  */
 243
 244 /* 64-bit test code. Sets SPRG2 to 0 if an illegal instruction is executed */
 245
 246         .globl  CNAME(testppc64),CNAME(testppc64size)
 247 CNAME(testppc64):
 248         mtsprg1 %r31
 249         mfsrr0  %r31
 250         addi    %r31, %r31, 4
 251         mtsrr0  %r31
 252
 253         li      %r31, 0
 254         mtsprg2 %r31
 255         mfsprg1 %r31
 256
 257         rfi
 258 CNAME(testppc64size) = .-CNAME(testppc64)
 259
 260
 261 /* 64-bit bridge mode restore snippet. Gets copied in front of everything else
 262  * on 64-bit systems. */
 263
 264         .globl  CNAME(restorebridge),CNAME(restorebridgesize)
 265 CNAME(restorebridge):
 266         mtsprg1 %r31
 267         mfmsr   %r31
 268         clrldi  %r31,%r31,1
 269         mtmsrd  %r31
 270         mfsprg1 %r31
 271         isync
 272 CNAME(restorebridgesize) = .-CNAME(restorebridge)
 273
 274 #ifdef SMP
 275 /*
 276  * Processor reset exception handler. These are typically
 277  * the first instructions the processor executes after a
 278  * software reset.
 279  */
 280         .globl  CNAME(rstcode), CNAME(rstsize)
 281 CNAME(rstcode):
 282         bl      1f
 283
 284         .space  124
 285
 286 1:
 287         mflr    %r1
 288         addi    %r1,%r1,(124-16)@l
 289
 290         lis     %r3,1@l
 291         bla     CNAME(pmap_cpu_bootstrap)
 292         bla     CNAME(cpudep_ap_bootstrap)
 293         mr      %r1,%r3
 294         bla     CNAME(machdep_ap_bootstrap)
 295
 296         /* Should not be reached */
 297 9:
 298         b       9b
 299 CNAME(rstsize) = . - CNAME(rstcode)
 300 #endif
 301
 302 /*
 303  * This code gets copied to all the trap vectors
 304  * (except ISI/DSI, ALI, and the interrupts)
 305  */
 306
 307         .globl  CNAME(trapcode),CNAME(trapsize)
 308 CNAME(trapcode):
 309         mtsprg1 %r1                     /* save SP */
 310         mflr    %r1                     /* Save the old LR in r1 */
 311         mtsprg2 %r1                     /* And then in SPRG2 */
 312         li      %r1, 0x20               /* How to get the vector from LR */
 313         bla     generictrap             /* LR & SPRG3 is exception # */
 314 CNAME(trapsize) = .-CNAME(trapcode)
 315
 316 /*
 317  * 64-bit version of trapcode. Identical, except it calls generictrap64.
 318  */
 319         .globl  CNAME(trapcode64)
 320 CNAME(trapcode64):
 321         mtsprg1 %r1                     /* save SP */
 322         mflr    %r1                     /* Save the old LR in r1 */
 323         mtsprg2 %r1                     /* And then in SPRG2 */
 324         li      %r1, 0x20               /* How to get the vector from LR */
 325         bla     generictrap64           /* LR & SPRG3 is exception # */
 326
 327 /*
 328  * For ALI: has to save DSISR and DAR
 329  */
 330         .globl  CNAME(alitrap),CNAME(alisize)
 331 CNAME(alitrap):
 332         mtsprg1 %r1                     /* save SP */
 333         GET_CPUINFO(%r1)
 334         stw     %r28,(PC_TEMPSAVE+CPUSAVE_R28)(%r1)     /* free r28-r31 */
 335         stw     %r29,(PC_TEMPSAVE+CPUSAVE_R29)(%r1)
 336         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R30)(%r1)
 337         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R31)(%r1)
 338         mfdar   %r30
 339         mfdsisr %r31
 340         stw     %r30,(PC_TEMPSAVE+CPUSAVE_AIM_DAR)(%r1)
 341         stw     %r31,(PC_TEMPSAVE+CPUSAVE_AIM_DSISR)(%r1)
 342         mfsprg1 %r1                     /* restore SP, in case of branch */
 343         mflr    %r28                    /* save LR */
 344         mfcr    %r29                    /* save CR */
 345
 346         /* Put our exception vector in SPRG3 */
 347         li      %r31, EXC_ALI
 348         mtsprg3 %r31
 349
 350         /* Test whether we already had PR set */
 351         mfsrr1  %r31
 352         mtcr    %r31
 353         bla     s_trap
 354 CNAME(alisize) = .-CNAME(alitrap)
 355
 356 /*
 357  * Similar to the above for DSI
 358  * Has to handle BAT spills
 359  * and standard pagetable spills
 360  */
 361         .globl  CNAME(dsitrap),CNAME(dsisize)
 362 CNAME(dsitrap):
 363         mtsprg1 %r1                     /* save SP */
 364         GET_CPUINFO(%r1)
 365         stw     %r28,(PC_DISISAVE+CPUSAVE_R28)(%r1)     /* free r28-r31 */
 366         stw     %r29,(PC_DISISAVE+CPUSAVE_R29)(%r1)
 367         stw     %r30,(PC_DISISAVE+CPUSAVE_R30)(%r1)
 368         stw     %r31,(PC_DISISAVE+CPUSAVE_R31)(%r1)
 369         mfsprg1 %r1                     /* restore SP */
 370         mfcr    %r29                    /* save CR */
 371         mfxer   %r30                    /* save XER */
 372         mtsprg2 %r30                    /* in SPRG2 */
 373         mfsrr1  %r31                    /* test kernel mode */
 374         mtcr    %r31
 375         bt      17,1f                   /* branch if PSL_PR is set */
 376         mfdar   %r31                    /* get fault address */
 377         rlwinm  %r31,%r31,7,25,28       /* get segment * 8 */
 378
 379         /* get batu */
 380         addis   %r31,%r31,CNAME(battable)@ha
 381         lwz     %r30,CNAME(battable)@l(31)
 382         mtcr    %r30
 383         bf      30,1f                   /* branch if supervisor valid is
 384                                            false */
 385         /* get batl */
 386         lwz     %r31,CNAME(battable)+4@l(31)
 387 /* We randomly use the highest two bat registers here */
 388         mftb    %r28
 389         andi.   %r28,%r28,1
 390         bne     2f
 391         mtdbatu 2,%r30
 392         mtdbatl 2,%r31
 393         b       3f
 394 2:
 395         mtdbatu 3,%r30
 396         mtdbatl 3,%r31
 397 3:
 398         mfsprg2 %r30                    /* restore XER */
 399         mtxer   %r30
 400         mtcr    %r29                    /* restore CR */
 401         mtsprg1 %r1
 402         GET_CPUINFO(%r1)
 403         lwz     %r28,(PC_DISISAVE+CPUSAVE_R28)(%r1)     /* restore r28-r31 */
 404         lwz     %r29,(PC_DISISAVE+CPUSAVE_R29)(%r1)
 405         lwz     %r30,(PC_DISISAVE+CPUSAVE_R30)(%r1)
 406         lwz     %r31,(PC_DISISAVE+CPUSAVE_R31)(%r1)
 407         mfsprg1 %r1
 408         rfi                             /* return to trapped code */
 409 1:
 410         mflr    %r28                    /* save LR (SP already saved) */
 411         bla     disitrap
 412 CNAME(dsisize) = .-CNAME(dsitrap)
 413
 414 /*
 415  * Preamble code for DSI/ISI traps
 416  */
 417 disitrap:
 418         /* Write the trap vector to SPRG3 by computing LR & 0xff00 */
 419         mflr    %r1
 420         andi.   %r1,%r1,0xff00
 421         mtsprg3 %r1
 422
 423         GET_CPUINFO(%r1)
 424         lwz     %r30,(PC_DISISAVE+CPUSAVE_R28)(%r1)
 425         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R28)(%r1)
 426         lwz     %r31,(PC_DISISAVE+CPUSAVE_R29)(%r1)
 427         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R29)(%r1)
 428         lwz     %r30,(PC_DISISAVE+CPUSAVE_R30)(%r1)
 429         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R30)(%r1)
 430         lwz     %r31,(PC_DISISAVE+CPUSAVE_R31)(%r1)
 431         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R31)(%r1)
 432         mfdar   %r30
 433         mfdsisr %r31
 434         stw     %r30,(PC_TEMPSAVE+CPUSAVE_AIM_DAR)(%r1)
 435         stw     %r31,(PC_TEMPSAVE+CPUSAVE_AIM_DSISR)(%r1)
 436
 437 #ifdef KDB
 438         /* Try and detect a kernel stack overflow */
 439         mfsrr1  %r31
 440         mtcr    %r31
 441         bt      17,realtrap             /* branch is user mode */
 442         mfsprg1 %r31                    /* get old SP */
 443         sub.    %r30,%r31,%r30          /* SP - DAR */
 444         bge     1f
 445         neg     %r30,%r30               /* modulo value */
 446 1:      cmplwi  %cr0,%r30,4096          /* is DAR within a page of SP? */
 447         bge     %cr0,realtrap           /* no, too far away. */
 448
 449         /* Now convert this DSI into a DDB trap.  */
 450         GET_CPUINFO(%r1)
 451         lwz     %r30,(PC_TEMPSAVE+CPUSAVE_AIM_DAR)(%r1) /* get DAR */
 452         stw     %r30,(PC_DBSAVE  +CPUSAVE_AIM_DAR)(%r1) /* save DAR */
 453         lwz     %r30,(PC_TEMPSAVE+CPUSAVE_AIM_DSISR)(%r1) /* get DSISR */
 454         lwz     %r30,(PC_DBSAVE  +CPUSAVE_AIM_DSISR)(%r1) /* save DSISR */
 455         lwz     %r30,(PC_DISISAVE+CPUSAVE_R28)(%r1) /* get  r28 */
 456         stw     %r30,(PC_DBSAVE  +CPUSAVE_R28)(%r1) /* save r28 */
 457         lwz     %r31,(PC_DISISAVE+CPUSAVE_R29)(%r1) /* get  r29 */
 458         stw     %r31,(PC_DBSAVE  +CPUSAVE_R29)(%r1) /* save r29 */
 459         lwz     %r30,(PC_DISISAVE+CPUSAVE_R30)(%r1) /* get  r30 */
 460         stw     %r30,(PC_DBSAVE  +CPUSAVE_R30)(%r1) /* save r30 */
 461         lwz     %r31,(PC_DISISAVE+CPUSAVE_R31)(%r1) /* get  r31 */
 462         stw     %r31,(PC_DBSAVE  +CPUSAVE_R31)(%r1) /* save r31 */
 463         b       dbtrap
 464 #endif
 465
 466         /* XXX need stack probe here */
 467 realtrap:
 468 /* Test whether we already had PR set */
 469         mfsrr1  %r1
 470         mtcr    %r1
 471         mfsprg1 %r1                     /* restore SP (might have been
 472                                            overwritten) */
 473         bf      17,k_trap               /* branch if PSL_PR is false */
 474         GET_CPUINFO(%r1)
 475         lwz     %r1,PC_CURPCB(%r1)
 476         RESTORE_KERN_SRS(%r30,%r31)     /* enable kernel mapping */
 477         ba s_trap
 478
 479 /*
 480  * generictrap does some standard setup for trap handling to minimize
 481  * the code that need be installed in the actual vectors. It expects
 482  * the following conditions.
 483  *
 484  * R1 - Trap vector = LR & (0xff00 | R1)
 485  * SPRG1 - Original R1 contents
 486  * SPRG2 - Original LR
 487  */
 488
 489 generictrap64:
 490         mtsprg3 %r31
 491         mfmsr   %r31
 492         clrldi  %r31,%r31,1
 493         mtmsrd  %r31
 494         mfsprg3 %r31
 495         isync
 496
 497 generictrap:
 498         /* Save R1 for computing the exception vector */
 499         mtsprg3 %r1
 500
 501         /* Save interesting registers */
 502         GET_CPUINFO(%r1)
 503         stw     %r28,(PC_TEMPSAVE+CPUSAVE_R28)(%r1)     /* free r28-r31 */
 504         stw     %r29,(PC_TEMPSAVE+CPUSAVE_R29)(%r1)
 505         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R30)(%r1)
 506         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R31)(%r1)
 507         mfsprg1 %r1                     /* restore SP, in case of branch */
 508         mfsprg2 %r28                    /* save LR */
 509         mfcr    %r29                    /* save CR */
 510
 511         /* Compute the exception vector from the link register */
 512         mfsprg3 %r31
 513         ori     %r31,%r31,0xff00
 514         mflr    %r30
 515         and     %r30,%r30,%r31
 516         mtsprg3 %r30
 517
 518         /* Test whether we already had PR set */
 519         mfsrr1  %r31
 520         mtcr    %r31
 521
 522 s_trap:
 523         bf      17,k_trap               /* branch if PSL_PR is false */
 524         GET_CPUINFO(%r1)
 525 u_trap:
 526         lwz     %r1,PC_CURPCB(%r1)
 527         RESTORE_KERN_SRS(%r30,%r31)     /* enable kernel mapping */
 528
 529 /*
 530  * Now the common trap catching code.
 531  */
 532 k_trap:
 533         FRAME_SETUP(PC_TEMPSAVE)
 534 /* Call C interrupt dispatcher: */
 535 trapagain:
 536         addi    %r3,%r1,8
 537         bl      CNAME(powerpc_interrupt)
 538         .globl  CNAME(trapexit)         /* backtrace code sentinel */
 539 CNAME(trapexit):
 540
 541 /* Disable interrupts: */
 542         mfmsr   %r3
 543         andi.   %r3,%r3,~PSL_EE@l
 544         mtmsr   %r3
 545 /* Test AST pending: */
 546         lwz     %r5,FRAME_SRR1+8(%r1)
 547         mtcr    %r5
 548         bf      17,1f                   /* branch if PSL_PR is false */
 549
 550         GET_CPUINFO(%r3)                /* get per-CPU pointer */
 551         lwz     %r4, PC_CURTHREAD(%r3)  /* deref to get curthread */
 552         lwz     %r4, TD_FLAGS(%r4)      /* get thread flags value */
 553         lis     %r5, (TDF_ASTPENDING|TDF_NEEDRESCHED)@h
 554         ori     %r5,%r5, (TDF_ASTPENDING|TDF_NEEDRESCHED)@l
 555         and.    %r4,%r4,%r5
 556         beq     1f
 557         mfmsr   %r3                     /* re-enable interrupts */
 558         ori     %r3,%r3,PSL_EE@l
 559         mtmsr   %r3
 560         isync
 561         addi    %r3,%r1,8
 562         bl      CNAME(ast)
 563         .globl  CNAME(asttrapexit)      /* backtrace code sentinel #2 */
 564 CNAME(asttrapexit):
 565         b       trapexit                /* test ast ret value ? */
 566 1:
 567         FRAME_LEAVE(PC_TEMPSAVE)
 568
 569         .globl  CNAME(rfi_patch1)       /* replace rfi with rfid on ppc64 */
 570 CNAME(rfi_patch1):
 571         rfi
 572
 573         .globl  CNAME(rfid_patch)
 574 CNAME(rfid_patch):
 575         rfid
 576
 577 #if defined(KDB)
 578 /*
 579  * Deliberate entry to dbtrap
 580  */
 581         .globl  CNAME(breakpoint)
 582 CNAME(breakpoint):
 583         mtsprg1 %r1
 584         mfmsr   %r3
 585         mtsrr1  %r3
 586         andi.   %r3,%r3,~(PSL_EE|PSL_ME)@l
 587         mtmsr   %r3                     /* disable interrupts */
 588         isync
 589         GET_CPUINFO(%r3)
 590         stw     %r28,(PC_DBSAVE+CPUSAVE_R28)(%r3)
 591         stw     %r29,(PC_DBSAVE+CPUSAVE_R29)(%r3)
 592         stw     %r30,(PC_DBSAVE+CPUSAVE_R30)(%r3)
 593         stw     %r31,(PC_DBSAVE+CPUSAVE_R31)(%r3)
 594         mflr    %r28
 595         li      %r29,EXC_BPT
 596         mtlr    %r29
 597         mfcr    %r29
 598         mtsrr0  %r28
 599
 600 /*
 601  * Now the kdb trap catching code.
 602  */
 603 dbtrap:
 604         /* Write the trap vector to SPRG3 by computing LR & 0xff00 */
 605         mflr    %r1
 606         andi.   %r1,%r1,0xff00
 607         mtsprg3 %r1
 608
 609         lis     %r1,(tmpstk+TMPSTKSZ-16)@ha     /* get new SP */
 610         addi    %r1,%r1,(tmpstk+TMPSTKSZ-16)@l
 611
 612         FRAME_SETUP(PC_DBSAVE)
 613 /* Call C trap code: */
 614         addi    %r3,%r1,8
 615         bl      CNAME(db_trap_glue)
 616         or.     %r3,%r3,%r3
 617         bne     dbleave
 618 /* This wasn't for KDB, so switch to real trap: */
 619         lwz     %r3,FRAME_EXC+8(%r1)    /* save exception */
 620         GET_CPUINFO(%r4)
 621         stw     %r3,(PC_DBSAVE+CPUSAVE_R31)(%r4)
 622         FRAME_LEAVE(PC_DBSAVE)
 623         mtsprg1 %r1                     /* prepare for entrance to realtrap */
 624         GET_CPUINFO(%r1)
 625         stw     %r28,(PC_TEMPSAVE+CPUSAVE_R28)(%r1)
 626         stw     %r29,(PC_TEMPSAVE+CPUSAVE_R29)(%r1)
 627         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R30)(%r1)
 628         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R31)(%r1)
 629         mflr    %r28
 630         mfcr    %r29
 631         lwz     %r31,(PC_DBSAVE+CPUSAVE_R31)(%r1)
 632         mtsprg3 %r31                    /* SPRG3 was clobbered by FRAME_LEAVE */
 633         mfsprg1 %r1
 634         b       realtrap
 635 dbleave:
 636         FRAME_LEAVE(PC_DBSAVE)
 637         .globl  CNAME(rfi_patch2)       /* replace rfi with rfid on ppc64 */
 638 CNAME(rfi_patch2):
 639         rfi
 640
 641 /*
 642  * In case of KDB we want a separate trap catcher for it
 643  */
 644         .globl  CNAME(dblow),CNAME(dbsize)
 645 CNAME(dblow):
 646         mtsprg1 %r1                     /* save SP */
 647         mtsprg2 %r29                    /* save r29 */
 648         mfcr    %r29                    /* save CR in r29 */
 649         mfsrr1  %r1
 650         mtcr    %r1
 651         bf      17,1f                   /* branch if privileged */
 652
 653         /* Unprivileged case */
 654         mtcr    %r29                    /* put the condition register back */
 655         mfsprg2 %r29                    /* ... and r29 */
 656         mflr    %r1                     /* save LR */
 657         mtsprg2 %r1                     /* And then in SPRG2 */
 658         li      %r1, 0                  /* How to get the vector from LR */
 659
 660         bla     generictrap             /* and we look like a generic trap */
 661 1:
 662         /* Privileged, so drop to KDB */
 663         GET_CPUINFO(%r1)
 664         stw     %r28,(PC_DBSAVE+CPUSAVE_R28)(%r1)       /* free r28 */
 665         mfsprg2 %r28                            /* r29 holds cr...  */
 666         stw     %r28,(PC_DBSAVE+CPUSAVE_R29)(%r1)       /* free r29 */
 667         stw     %r30,(PC_DBSAVE+CPUSAVE_R30)(%r1)       /* free r30 */
 668         stw     %r31,(PC_DBSAVE+CPUSAVE_R31)(%r1)       /* free r31 */
 669         mflr    %r28                                    /* save LR */
 670         bla     dbtrap
 671 CNAME(dbsize) = .-CNAME(dblow)
 672 #endif /* KDB */