contrib/libf2c/libF77/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998, 2001 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU Fortran.
   6 #
   7 #GNU Fortran is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU Fortran is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU Fortran; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.13)
  23 AC_INIT(getarg_.c)
  24
  25 dnl Checks for programs.
  26
  27 dnl FIXME AC_PROG_CC wants CC to be able to link things, but it may
  28 dnl not be able to.
  29 define([AC_PROG_CC_WORKS],[])
  30
  31 # For g77 we'll set CC to point at the built gcc, but this will get it into
  32 # the makefiles
  33 AC_PROG_CC
  34
  35 LIBTOOL='$(SHELL) ../libtool'
  36 AC_SUBST(LIBTOOL)
  37
  38 test "$AR" || AR=ar
  39 AC_SUBST(AR)
  40 if test "$RANLIB"; then :
  41   AC_SUBST(RANLIB)
  42 else
  43   AC_PROG_RANLIB
  44 fi
  45 AC_PROG_MAKE_SET
  46
  47 dnl Checks for libraries.
  48
  49 dnl Checks for header files.
  50 # Sanity check for the cross-compilation case:
  51 AC_CHECK_HEADER(stdio.h,:,
  52   [AC_MSG_ERROR([Can't find stdio.h.
  53 You must have a usable C system for the target already installed, at least
  54 including headers and, preferably, the library, before you can configure
  55 the G77 runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  56 then the target library, then build with \`LANGUAGES=f77'.])])
  57
  58 AC_HEADER_STDC
  59 AC_MSG_CHECKING(for posix)
  60 AC_CACHE_VAL(g77_cv_header_posix,
  61   AC_EGREP_CPP(yes,
  62   [#include <sys/types.h>
  63 #include <unistd.h>
  64 #ifdef _POSIX_VERSION
  65   yes
  66 #endif
  67 ],
  68   g77_cv_header_posix=yes,
  69   g77_cv_header_posix=no))
  70 AC_MSG_RESULT($g77_cv_header_posix)
  71
  72 # We can rely on the GNU library being posix-ish.  I guess checking the
  73 # header isn't actually like checking the functions, though...
  74 AC_MSG_CHECKING(for GNU library)
  75 AC_CACHE_VAL(g77_cv_lib_gnu,
  76   AC_EGREP_CPP(yes,
  77     [#include <stdio.h>
  78 #ifdef __GNU_LIBRARY__
  79   yes
  80 #endif
  81 ],
  82   g77_cv_lib_gnu=yes, g77_cv_lib_gnu=no))
  83 AC_MSG_RESULT($g77_cv_lib_gnu)
  84
  85 dnl Checks for library functions.
  86 AC_TYPE_SIGNAL
  87 # we'll get atexit by default
  88 if test $ac_cv_header_stdc != yes; then
  89 AC_CHECK_FUNC(atexit,
  90   AC_DEFINE(onexit,atexit),dnl just in case
  91   [AC_DEFINE(NO_ONEXIT)
  92   AC_CHECK_FUNC(onexit,,
  93     [AC_CHECK_FUNC(on_exit,
  94      AC_DEFINE(onexit,on_exit),)])])
  95 else true
  96 fi
  97
  98 dnl perhaps should check also for remainder
  99 dnl Unfortunately, the message implies we're just checking for -lm...
 100 AC_CHECK_LIB(m,drem,AC_DEFINE(IEEE_drem))
 101
 102 AC_DEFINE(Skip_f2c_Undefs)
 103 AC_DEFINE(IEEE_COMPLEX_DIVIDE)
 104
 105 AC_OUTPUT(Makefile)
 106
 107 dnl Local Variables:
 108 dnl comment-start: "dnl "
 109 dnl comment-end: ""
 110 dnl comment-start-skip: "\\bdnl\\b\\s *"
 111 dnl End: