lib/libc/mips/string/bcmp.S

   1 /*      $NetBSD: bcmp.S,v 1.8 2003/08/07 16:42:16 agc Exp $     */
   2
   3 /*-
   4  * Copyright (c) 1991, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * Ralph Campbell.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/asm.h>
  36 __FBSDID("$FreeBSD$");
  37
  38 #if defined(LIBC_SCCS) && !defined(lint)
  39         ASMSTR("from: @(#)bcmp.s        8.1 (Berkeley) 6/4/93")
  40         ASMSTR("$NetBSD: bcmp.S,v 1.8 2003/08/07 16:42:16 agc Exp $")
  41 #endif /* LIBC_SCCS and not lint */
  42
  43 #ifdef __ABICALLS__
  44         .abicalls
  45 #endif
  46
  47 /* bcmp(s1, s2, n) */
  48
  49
  50 LEAF(bcmp)
  51         .set    noreorder
  52         blt     a2, 16, small           # is it worth any trouble?
  53         xor     v0, a0, a1              # compare low two bits of addresses
  54         and     v0, v0, 3
  55         subu    a3, zero, a1            # compute # bytes to word align address
  56         bne     v0, zero, unaligned     # not possible to align addresses
  57         and     a3, a3, 3
  58
  59         beq     a3, zero, 1f
  60         subu    a2, a2, a3              # subtract from remaining count
  61         move    v0, v1                  # init v0,v1 so unmodified bytes match
  62 #ifdef __MIPSEB__
  63         lwl     v0, 0(a0)               # read 1, 2, or 3 bytes
  64         lwl     v1, 0(a1)
  65 #else
  66         lwr     v0, 0(a0)               # read 1, 2, or 3 bytes
  67         lwr     v1, 0(a1)
  68 #endif
  69         addu    a1, a1, a3
  70         bne     v0, v1, nomatch
  71         addu    a0, a0, a3
  72 1:
  73         and     a3, a2, ~3              # compute number of whole words left
  74         subu    a2, a2, a3              #   which has to be >= (16-3) & ~3
  75         addu    a3, a3, a0              # compute ending address
  76 2:
  77         lw      v0, 0(a0)               # compare words
  78         lw      v1, 0(a1)
  79         addu    a0, a0, 4
  80         bne     v0, v1, nomatch
  81         addu    a1, a1, 4
  82         bne     a0, a3, 2b
  83         nop
  84         b       small                   # finish remainder
  85         nop
  86 unaligned:
  87         beq     a3, zero, 2f
  88         subu    a2, a2, a3              # subtract from remaining count
  89         addu    a3, a3, a0              # compute ending address
  90 1:
  91         lbu     v0, 0(a0)               # compare bytes until a1 word aligned
  92         lbu     v1, 0(a1)
  93         addu    a0, a0, 1
  94         bne     v0, v1, nomatch
  95         addu    a1, a1, 1
  96         bne     a0, a3, 1b
  97         nop
  98 2:
  99         and     a3, a2, ~3              # compute number of whole words left
 100         subu    a2, a2, a3              #   which has to be >= (16-3) & ~3
 101         addu    a3, a3, a0              # compute ending address
 102 3:
 103 #ifdef __MIPSEB__
 104         lwl     v0, 0(a0)               # compare words a0 unaligned, a1 aligned
 105         lwr     v0, 3(a0)
 106 #else
 107         lwr     v0, 0(a0)               # compare words a0 unaligned, a1 aligned
 108         lwl     v0, 3(a0)
 109 #endif
 110         lw      v1, 0(a1)
 111         addu    a0, a0, 4
 112         bne     v0, v1, nomatch
 113         addu    a1, a1, 4
 114         bne     a0, a3, 3b
 115         nop
 116 small:
 117         ble     a2, zero, match
 118         addu    a3, a2, a0              # compute ending address
 119 1:
 120         lbu     v0, 0(a0)
 121         lbu     v1, 0(a1)
 122         addu    a0, a0, 1
 123         bne     v0, v1, nomatch
 124         addu    a1, a1, 1
 125         bne     a0, a3, 1b
 126         nop
 127 match:
 128         j       ra
 129         move    v0, zero
 130 nomatch:
 131         j       ra
 132         li      v0, 1
 133         .set    reorder
 134 END(bcmp)