lib/libc/mips/string/bzero.S

   1 /*      $NetBSD: bzero.S,v 1.8 2003/08/07 16:42:16 agc Exp $    */
   2
   3 /*-
   4  * Copyright (c) 1991, 1993
   5  *      The Regents of the University of California.  All rights reserved.
   6  *
   7  * This code is derived from software contributed to Berkeley by
   8  * Ralph Campbell.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include <machine/asm.h>
  36 __FBSDID("$FreeBSD$");
  37
  38 #if defined(LIBC_SCCS) && !defined(lint)
  39         ASMSTR("from: @(#)bzero.s       8.1 (Berkeley) 6/4/93")
  40         ASMSTR("$NetBSD: bzero.S,v 1.8 2003/08/07 16:42:16 agc Exp $")
  41 #endif /* LIBC_SCCS and not lint */
  42
  43
  44 #ifdef __ABICALLS__
  45         .abicalls
  46 #endif
  47
  48 /* bzero(s1, n) */
  49
  50 LEAF(bzero)
  51         .set    noreorder
  52         blt     a1, 12, smallclr        # small amount to clear?
  53         subu    a3, zero, a0            # compute # bytes to word align address
  54         and     a3, a3, 3
  55         beq     a3, zero, 1f            # skip if word aligned
  56         subu    a1, a1, a3              # subtract from remaining count
  57 #ifdef __MIPSEB__
  58         swl     zero, 0(a0)             # clear 1, 2, or 3 bytes to align
  59 #else
  60         swr     zero, 0(a0)             # clear 1, 2, or 3 bytes to align
  61 #endif
  62         addu    a0, a0, a3
  63 1:
  64         and     v0, a1, 3               # compute number of words left
  65         subu    a3, a1, v0
  66         move    a1, v0
  67         addu    a3, a3, a0              # compute ending address
  68 2:
  69         addu    a0, a0, 4               # clear words
  70         bne     a0, a3, 2b              #   unrolling loop doesnt help
  71         sw      zero, -4(a0)            #   since we are limited by memory speed
  72 smallclr:
  73         ble     a1, zero, 2f
  74         addu    a3, a1, a0              # compute ending address
  75 1:
  76         addu    a0, a0, 1               # clear bytes
  77         bne     a0, a3, 1b
  78         sb      zero, -1(a0)
  79 2:
  80         j       ra
  81         nop
  82 END(bzero)