lib/libelf/libelf_fsize.m4

   1 /*-
   2  * Copyright (c) 2006 Joseph Koshy
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  * $FreeBSD$
  27  */
  28
  29 #include <libelf.h>
  30 #include <osreldate.h>
  31
  32 #include "_libelf.h"
  33
  34 /*
  35  * Create an array of file sizes from the elf_type definitions
  36  */
  37
  38 divert(-1)
  39 include(SRCDIR`/elf_types.m4')
  40
  41 /*
  42  * Translations from structure definitions to the size of their file
  43  * representations.
  44  */
  45
  46 /* `Basic' types */
  47 define(`BYTE_SIZE',     1)
  48 define(`IDENT_SIZE',    `EI_NIDENT')
  49 define(`NOTE_SIZE',     1) /* Elf_Note structures have variable length. */
  50
  51 /* Currently unimplemented types */
  52 define(`MOVEP_SIZE',    0)
  53
  54 /* Overrides for 32 bit types that do not exist */
  55 define(`XWORD_SIZE32',  0)
  56 define(`SXWORD_SIZE32', 0)
  57
  58 /*
  59  * FSZ{32,64} define the sizes of 32 and 64 bit file structures respectively.
  60  */
  61
  62 define(`FSZ32',`_FSZ32($1_DEF)')
  63 define(`_FSZ32',
  64   `ifelse($#,1,0,
  65     `_BSZ32($1)+_FSZ32(shift($@))')')
  66 define(`_BSZ32',`$2_SIZE32')
  67
  68 define(`FSZ64',`_FSZ64($1_DEF)')
  69 define(`_FSZ64',
  70   `ifelse($#,1,0,
  71     `_BSZ64($1)+_FSZ64(shift($@))')')
  72 define(`_BSZ64',`$2_SIZE64')
  73
  74 /*
  75  * DEFINE_ELF_FSIZES(TYPE,NAME)
  76  *
  77  * Shorthand for defining  for 32 and 64 versions
  78  * of elf type TYPE.
  79  *
  80  * If TYPE`'_SIZE is defined, use its value for both 32 bit and 64 bit
  81  * sizes.
  82  *
  83  * Otherwise, look for a explicit 32/64 bit size definition for TYPE,
  84  * TYPE`'_SIZE32 or TYPE`'_SIZE64. If this definition is present, there
  85  * is nothing further to do.
  86  *
  87  * Otherwise, if an Elf{32,64}_`'NAME structure definition is known,
  88  * compute an expression that adds up the sizes of the structure's
  89  * constituents.
  90  *
  91  * If such a structure definition is not known, treat TYPE as a primitive
  92  * (i.e., integral) type and use sizeof(Elf{32,64}_`'NAME) to get its
  93  * file representation size.
  94  */
  95
  96 define(`DEFINE_ELF_FSIZE',
  97   `ifdef($1`_SIZE',
  98     `define($1_SIZE32,$1_SIZE)
  99      define($1_SIZE64,$1_SIZE)',
 100     `ifdef($1`_SIZE32',`',
 101       `ifdef(`Elf32_'$2`_DEF',
 102         `define($1_SIZE32,FSZ32(Elf32_$2))',
 103         `define($1_SIZE32,`sizeof(Elf32_'$2`)')')')
 104      ifdef($1`_SIZE64',`',
 105       `ifdef(`Elf64_'$2`_DEF',
 106         `define($1_SIZE64,FSZ64(Elf64_$2))',
 107         `define($1_SIZE64,`sizeof(Elf64_'$2`)')')')')')
 108
 109 define(`DEFINE_ELF_FSIZES',
 110   `ifelse($#,1,`',
 111     `DEFINE_ELF_FSIZE($1)
 112      DEFINE_ELF_FSIZES(shift($@))')')
 113
 114 DEFINE_ELF_FSIZES(ELF_TYPE_LIST)
 115 DEFINE_ELF_FSIZE(`IDENT',`')    # `IDENT' is a pseudo type
 116
 117 define(`FSIZE',
 118   `#if  __FreeBSD_version >= $3
 119     [ELF_T_$1] = { .fsz32 = $1_SIZE32, .fsz64 = $1_SIZE64 },
 120 #endif')
 121 define(`FSIZES',
 122   `ifelse($#,1,`',
 123     `FSIZE($1)
 124 FSIZES(shift($@))')')
 125
 126 divert(0)
 127
 128 struct fsize {
 129         size_t fsz32;
 130         size_t fsz64;
 131 };
 132
 133 static struct fsize fsize[ELF_T_NUM] = {
 134 FSIZES(ELF_TYPE_LIST)
 135 };
 136
 137 size_t
 138 _libelf_fsize(Elf_Type t, int ec, unsigned int v, size_t c)
 139 {
 140         size_t sz;
 141
 142         sz = 0;
 143         if (v != EV_CURRENT)
 144                 LIBELF_SET_ERROR(VERSION, 0);
 145         else if ((int) t < ELF_T_FIRST || t > ELF_T_LAST)
 146                 LIBELF_SET_ERROR(ARGUMENT, 0);
 147         else {
 148                 sz = ec == ELFCLASS64 ? fsize[t].fsz64 : fsize[t].fsz32;
 149                 if (sz == 0)
 150                         LIBELF_SET_ERROR(UNIMPL, 0);
 151         }
 152
 153         return (sz*c);
 154 }
 155