sbin/devd/token.l

   1 %{
   2 /*-
   3  * DEVD (Device action daemon)
   4  *
   5  * Copyright (c) 2002 M. Warner Losh <imp@freebsd.org>.
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  *
  29  * $FreeBSD$
  30  */
  31
  32 #include <ctype.h>
  33 #include <stdlib.h>
  34 #include <string.h>
  35 #include <syslog.h>
  36 #include "devd.h"
  37 #include "y.tab.h"
  38
  39 int lineno = 1;
  40 #define YY_NO_UNPUT
  41
  42 static void
  43 update_lineno(const char *cp)
  44 {
  45         while (*cp)
  46                 if (*cp++ == '\n')
  47                         lineno++;
  48 }
  49
  50 %}
  51
  52 %%
  53
  54 [ \t]+                  ;
  55 \n                      lineno++;
  56 ;                       { return SEMICOLON; }
  57 #.*$                    ;
  58 \/\/.*$                 ;
  59 \/\*([^*]|(\*+([^*\/])))*\*+\/ { update_lineno(yytext); }
  60 \{                      { return BEGINBLOCK; }
  61 \}                      { return ENDBLOCK; }
  62 [0-9]+                  { yylval.i = atoi(yytext); return NUMBER; }
  63 \"[^"]+\"               {
  64                                 int len = strlen(yytext) - 2;
  65                                 char *walker;
  66                                 int i;
  67                                 update_lineno(yytext);
  68                                 if ((yylval.str = (char *) malloc(len + 1)) == NULL)
  69                                         goto out;
  70                                 walker = yylval.str;
  71                                 for (i = 1; i <= len; i++) {
  72                                         if (yytext[i] == '\\' &&
  73                                             yytext[i + 1] == '\n') {
  74                                                 i += 2;
  75                                                 while(isspace(yytext[i]))
  76                                                         i++;
  77                                         }
  78                                         *walker++ = yytext[i];
  79                                 }
  80                                 *walker++ = '\0';
  81                         out:;
  82                                 return STRING;
  83                         }
  84
  85
  86 options                 { return OPTIONS; }
  87 set                     { return SET; }
  88 directory               { return DIRECTORY; }
  89 pid-file                { return PID_FILE; }
  90 attach                  { return ATTACH; }
  91 detach                  { return DETACH; }
  92 device-name             { return DEVICE_NAME; }
  93 media-type              { return MEDIA_TYPE; }
  94 class                   { return CLASS; }
  95 subdevice               { return SUBDEVICE; }
  96 action                  { return ACTION; }
  97 match                   { return MATCH; }
  98 nomatch                 { return NOMATCH; }
  99 notify                  { return NOTIFY; }
 100 [A-Za-z][A-Za-z0-9_-]*  {
 101                                 yylval.str = strdup(yytext);
 102                                 return ID;
 103                         }
 104 %%
 105
 106 void
 107 yyerror(const char *s)
 108 {
 109         syslog(LOG_ERR, "line %d: %s%s %s.\n", lineno, yytext, yytext?":":"", s);
 110 }