sys/boot/ia64/ski/ldscript.ia64

   1 /* $FreeBSD$ */
   2 OUTPUT_FORMAT("elf64-ia64-little", "elf64-ia64-little", "elf64-ia64-little")
   3 OUTPUT_ARCH(ia64)
   4 ENTRY(_start)
   5 SECTIONS
   6 {
   7   /* Read-only sections, merged into text segment: */
   8   . = 0x100000;
   9   .text         : {
  10     *(.text .stub .text.* .gnu.linkonce.t.*)
  11     /* .gnu.warning sections are handled specially by elf32.em. */
  12     *(.gnu.warning)
  13     *(.plt)
  14   } =0x00300000010070000002000001000400
  15   .data         : {
  16     *(.rodata .rodata.* .gnu.linkonce.r.*)
  17     *(.rodata1)
  18     *(.sdata2 .sdata2.* .gnu.linkonce.s2.*)
  19     *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*)
  20     *(.opd)
  21     *(.IA_64.unwind_info* .gnu.linkonce.ia64unwi.*)
  22     *(.IA_64.unwind* .gnu.linkonce.ia64unw.*)
  23     __start_set_Xcommand_set = .;
  24     *(set_Xcommand_set)
  25     __stop_set_Xcommand_set = .;
  26     *(.data .data.* .gnu.linkonce.d.*)
  27     *(.data1)
  28     *(.plabel)
  29     *(.dynbss)
  30     *(.bss .bss.* .gnu.linkonce.b.*)
  31     *(COMMON)
  32   }
  33   __gp = .;
  34   .sdata        : {
  35     *(.got.plt .got)
  36     *(.IA_64.pltoff)
  37     *(.sdata .sdata.* .gnu.linkonce.s.*)
  38     *(dynsbss)
  39     *(.sbss .sbss.* .gnu.linkonce.sb.*)
  40     *(.scommon)
  41   }
  42   .dynamic      : { *(.dynamic) }
  43   .rela         : {
  44     *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*)
  45     *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*)
  46     *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*)
  47     *(.rela.got)
  48     *(.rela.sdata .rela.sdata.* .rela.gnu.linkonce.s.*)
  49     *(.rela.sbss .rela.sbss.* .rela.gnu.linkonce.sb.*)
  50     *(.rela.sdata2 .rela.sdata2.* .rela.gnu.linkonce.s2.*)
  51     *(.rela.sbss2 .rela.sbss2.* .rela.gnu.linkonce.sb2.*)
  52     *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*)
  53     *(.rela.plt)
  54     *(.rela.IA_64.pltoff)
  55     *(.relaset_*)
  56     *(.rela.dyn .rela.dyn.*)
  57   }
  58   .hash         : { *(.hash) }
  59   .dynsym       : { *(.dynsym) }
  60   .dynstr       : { *(.dynstr) }
  61 }