sys/powerpc/aim/swtch.S

   1 /* $FreeBSD$ */
   2 /* $NetBSD: locore.S,v 1.24 2000/05/31 05:09:17 thorpej Exp $ */
   3
   4 /*-
   5  * Copyright (C) 2001 Benno Rice
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY Benno Rice ``AS IS'' AND ANY EXPRESS OR
  18  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  19  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  21  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  22  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  23  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  24  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  25  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  26  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27 */
  28 /*-
  29  * Copyright (C) 1995, 1996 Wolfgang Solfrank.
  30  * Copyright (C) 1995, 1996 TooLs GmbH.
  31  * All rights reserved.
  32  *
  33  * Redistribution and use in source and binary forms, with or without
  34  * modification, are permitted provided that the following conditions
  35  * are met:
  36  * 1. Redistributions of source code must retain the above copyright
  37  *    notice, this list of conditions and the following disclaimer.
  38  * 2. Redistributions in binary form must reproduce the above copyright
  39  *    notice, this list of conditions and the following disclaimer in the
  40  *    documentation and/or other materials provided with the distribution.
  41  * 3. All advertising materials mentioning features or use of this software
  42  *    must display the following acknowledgement:
  43  *      This product includes software developed by TooLs GmbH.
  44  * 4. The name of TooLs GmbH may not be used to endorse or promote products
  45  *    derived from this software without specific prior written permission.
  46  *
  47  * THIS SOFTWARE IS PROVIDED BY TOOLS GMBH ``AS IS'' AND ANY EXPRESS OR
  48  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  49  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  50  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  51  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  52  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  53  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  54  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  55  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  56  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  57  */
  58
  59 #include "assym.s"
  60 #include "opt_sched.h"
  61
  62 #include <sys/syscall.h>
  63
  64 #include <machine/trap.h>
  65 #include <machine/param.h>
  66 #include <machine/sr.h>
  67 #include <machine/psl.h>
  68 #include <machine/asm.h>
  69
  70 /*
  71  * void cpu_throw(struct thread *old, struct thread *new)
  72  */
  73 ENTRY(cpu_throw)
  74         mr      %r15, %r4
  75         b       cpu_switchin
  76
  77 /*
  78  * void cpu_switch(struct thread *old,
  79  *                 struct thread *new,
  80  *                 struct mutex *mtx);
  81  *
  82  * Switch to a new thread saving the current state in the old thread.
  83  */
  84 ENTRY(cpu_switch)
  85         lwz     %r6,TD_PCB(%r3)         /* Get the old thread's PCB ptr */
  86         mr      %r12,%r2
  87         stmw    %r12,PCB_CONTEXT(%r6)   /* Save the non-volatile GP regs.
  88                                            These can now be used for scratch */
  89
  90         mfcr    %r16                    /* Save the condition register */
  91         stw     %r16,PCB_CR(%r6)
  92         mflr    %r16                    /* Save the link register */
  93         stw     %r16,PCB_LR(%r6)
  94         mfsr    %r16,USER_SR            /* Save USER_SR for copyin/out */
  95         isync
  96         stw     %r16,PCB_AIM_USR(%r6)
  97         stw     %r1,PCB_SP(%r6)         /* Save the stack pointer */
  98
  99         mr      %r14,%r3                /* Copy the old thread ptr... */
 100         mr      %r15,%r4                /* and the new thread ptr in scratch */
 101         mr      %r16,%r5                /* and the new lock */
 102         mr      %r17,%r6                /* and the PCB */
 103
 104         lwz     %r7,PCB_FLAGS(%r17)
 105         /* Save FPU context if needed */
 106         andi.   %r7, %r7, PCB_FPU
 107         beq     .L1
 108         bl      save_fpu
 109
 110 .L1:
 111         mr      %r3,%r14                /* restore old thread ptr */
 112         lwz     %r7,PCB_FLAGS(%r17)
 113         /* Save Altivec context if needed */
 114         andi.   %r7, %r7, PCB_VEC
 115         beq     .L2
 116         bl      save_vec
 117
 118 .L2:
 119         mr      %r3,%r14                /* restore old thread ptr */
 120         bl      pmap_deactivate         /* Deactivate the current pmap */
 121
 122         stw     %r16,TD_LOCK(%r14)      /* ULE: update old thread's lock */
 123
 124 cpu_switchin:
 125 #if defined(SMP) && defined(SCHED_ULE)
 126         /* Wait for the new thread to become unblocked */
 127         lis     %r6,blocked_lock@ha
 128         addi    %r6,%r6,blocked_lock@l
 129 blocked_loop:
 130         lwz     %r7,TD_LOCK(%r15)
 131         cmpw    %r6,%r7
 132         beq     blocked_loop
 133 #endif
 134
 135         mfsprg  %r7,0                   /* Get the pcpu pointer */
 136         stw     %r15,PC_CURTHREAD(%r7)  /* Store new current thread */
 137         lwz     %r17,TD_PCB(%r15)       /* Store new current PCB */
 138         stw     %r17,PC_CURPCB(%r7)
 139
 140         mr      %r3,%r15                /* Get new thread ptr */
 141         bl      pmap_activate           /* Activate the new address space */
 142
 143         lwz     %r6, PCB_FLAGS(%r17)
 144         /* Restore FPU context if needed */
 145         andi.   %r6, %r6, PCB_FPU
 146         beq     .L3
 147         mr      %r3,%r15                /* Pass curthread to enable_fpu */
 148         bl      enable_fpu
 149
 150 .L3:
 151         lwz     %r6, PCB_FLAGS(%r17)
 152         /* Restore Altivec context if needed */
 153         andi.   %r6, %r6, PCB_VEC
 154         beq     .L4
 155         mr      %r3,%r15                /* Pass curthread to enable_vec */
 156         bl      enable_vec
 157
 158         /* thread to restore is in r3 */
 159 .L4:
 160         mr      %r3,%r17                /* Recover PCB ptr */
 161         lmw     %r12,PCB_CONTEXT(%r3)   /* Load the non-volatile GP regs */
 162         mr      %r2,%r12
 163         lwz     %r5,PCB_CR(%r3)         /* Load the condition register */
 164         mtcr    %r5
 165         lwz     %r5,PCB_LR(%r3)         /* Load the link register */
 166         mtlr    %r5
 167         lwz     %r5,PCB_AIM_USR(%r3)    /* Load the USER_SR segment reg */
 168         mtsr    USER_SR,%r5
 169         isync
 170         lwz     %r1,PCB_SP(%r3)         /* Load the stack pointer */
 171         /*
 172          * Perform a dummy stwcx. to clear any reservations we may have
 173          * inherited from the previous thread. It doesn't matter if the
 174          * stwcx succeeds or not. pcb_context[0] can be clobbered.
 175          */
 176         stwcx.  %r1, 0, %r3
 177         blr
 178
 179 /*
 180  * savectx(pcb)
 181  * Update pcb, saving current processor state
 182  */
 183 ENTRY(savectx)
 184         mr      %r12,%r2
 185         stmw    %r12,PCB_CONTEXT(%r3)   /* Save the non-volatile GP regs */
 186         mfcr    %r4                     /* Save the condition register */
 187         stw     %r4,PCB_CR(%r3)
 188         blr
 189
 190 /*
 191  * fork_trampoline()
 192  * Set up the return from cpu_fork()
 193  */
 194 ENTRY(fork_trampoline)
 195         lwz     %r3,CF_FUNC(%r1)
 196         lwz     %r4,CF_ARG0(%r1)
 197         lwz     %r5,CF_ARG1(%r1)
 198         bl      fork_exit
 199         addi    %r1,%r1,CF_SIZE-FSP     /* Allow 8 bytes in front of
 200                                            trapframe to simulate FRAME_SETUP
 201                                            does when allocating space for
 202                                            a frame pointer/saved LR */
 203         b       trapexit