sys/powerpc/aim/trap_subr.S

   1 /* $FreeBSD$ */
   2 /* $NetBSD: trap_subr.S,v 1.20 2002/04/22 23:20:08 kleink Exp $ */
   3
   4 /*-
   5  * Copyright (C) 1995, 1996 Wolfgang Solfrank.
   6  * Copyright (C) 1995, 1996 TooLs GmbH.
   7  * All rights reserved.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed by TooLs GmbH.
  20  * 4. The name of TooLs GmbH may not be used to endorse or promote products
  21  *    derived from this software without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY TOOLS GMBH ``AS IS'' AND ANY EXPRESS OR
  24  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  25  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  26  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  27  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  28  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  29  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  30  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  31  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  32  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  33  */
  34
  35 /*
  36  * NOTICE: This is not a standalone file.  to use it, #include it in
  37  * your port's locore.S, like so:
  38  *
  39  *      #include <powerpc/aim/trap_subr.S>
  40  */
  41
  42 /*
  43  * Save/restore segment registers
  44  */
  45 #define RESTORE_SRS(pmap,sr)    mtsr    0,sr; \
  46         lwz     sr,1*4(pmap);   mtsr    1,sr; \
  47         lwz     sr,2*4(pmap);   mtsr    2,sr; \
  48         lwz     sr,3*4(pmap);   mtsr    3,sr; \
  49         lwz     sr,4*4(pmap);   mtsr    4,sr; \
  50         lwz     sr,5*4(pmap);   mtsr    5,sr; \
  51         lwz     sr,6*4(pmap);   mtsr    6,sr; \
  52         lwz     sr,7*4(pmap);   mtsr    7,sr; \
  53         lwz     sr,8*4(pmap);   mtsr    8,sr; \
  54         lwz     sr,9*4(pmap);   mtsr    9,sr; \
  55         lwz     sr,10*4(pmap);  mtsr    10,sr; \
  56         lwz     sr,11*4(pmap);  mtsr    11,sr; \
  57         lwz     sr,12*4(pmap);  mtsr    12,sr; \
  58         lwz     sr,13*4(pmap);  mtsr    13,sr; \
  59         lwz     sr,14*4(pmap);  mtsr    14,sr; \
  60         lwz     sr,15*4(pmap);  mtsr    15,sr; isync;
  61
  62 /*
  63  * User SRs are loaded through a pointer to the current pmap.
  64  */
  65 #define RESTORE_USER_SRS(pmap,sr) \
  66         GET_CPUINFO(pmap); \
  67         lwz     pmap,PC_CURPMAP(pmap); \
  68         lwzu    sr,PM_SR(pmap); \
  69         RESTORE_SRS(pmap,sr)
  70
  71 /*
  72  * Kernel SRs are loaded directly from kernel_pmap_
  73  */
  74 #define RESTORE_KERN_SRS(pmap,sr) \
  75         lis     pmap,CNAME(kernel_pmap_store)@ha; \
  76         lwzu    sr,CNAME(kernel_pmap_store)+PM_SR@l(pmap); \
  77         RESTORE_SRS(pmap,sr)
  78
  79 /*
  80  * FRAME_SETUP assumes:
  81  *      SPRG1           SP (1)
  82  *      SPRG3           trap type
  83  *      savearea        r28-r31,DAR,DSISR   (DAR & DSISR only for DSI traps)
  84  *      r28             LR
  85  *      r29             CR
  86  *      r30             scratch
  87  *      r31             scratch
  88  *      r1              kernel stack
  89  *      SRR0/1          as at start of trap
  90  */
  91 #define FRAME_SETUP(savearea)                                           \
  92 /* Have to enable translation to allow access of kernel stack: */       \
  93         GET_CPUINFO(%r31);                                              \
  94         mfsrr0  %r30;                                                   \
  95         stw     %r30,(savearea+CPUSAVE_SRR0)(%r31);     /* save SRR0 */ \
  96         mfsrr1  %r30;                                                   \
  97         stw     %r30,(savearea+CPUSAVE_SRR1)(%r31);     /* save SRR1 */ \
  98         mfmsr   %r30;                                                   \
  99         ori     %r30,%r30,(PSL_DR|PSL_IR|PSL_RI)@l; /* relocation on */ \
 100         mtmsr   %r30;                   /* stack can now be accessed */ \
 101         isync;                                                          \
 102         mfsprg1 %r31;                   /* get saved SP */              \
 103         stwu    %r31,-FRAMELEN(%r1);    /* save it in the callframe */  \
 104         stw     %r0, FRAME_0+8(%r1);    /* save r0 in the trapframe */  \
 105         stw     %r31,FRAME_1+8(%r1);    /* save SP   "      "       */  \
 106         stw     %r2, FRAME_2+8(%r1);    /* save r2   "      "       */  \
 107         stw     %r28,FRAME_LR+8(%r1);   /* save LR   "      "       */  \
 108         stw     %r29,FRAME_CR+8(%r1);   /* save CR   "      "       */  \
 109         GET_CPUINFO(%r2);                                               \
 110         lwz     %r28,(savearea+CPUSAVE_R28)(%r2); /* get saved r28 */   \
 111         lwz     %r29,(savearea+CPUSAVE_R29)(%r2); /* get saved r29 */   \
 112         lwz     %r30,(savearea+CPUSAVE_R30)(%r2); /* get saved r30 */   \
 113         lwz     %r31,(savearea+CPUSAVE_R31)(%r2); /* get saved r31 */   \
 114         stw     %r3,  FRAME_3+8(%r1);   /* save r3-r31 */               \
 115         stw     %r4,  FRAME_4+8(%r1);                                   \
 116         stw     %r5,  FRAME_5+8(%r1);                                   \
 117         stw     %r6,  FRAME_6+8(%r1);                                   \
 118         stw     %r7,  FRAME_7+8(%r1);                                   \
 119         stw     %r8,  FRAME_8+8(%r1);                                   \
 120         stw     %r9,  FRAME_9+8(%r1);                                   \
 121         stw     %r10, FRAME_10+8(%r1);                                  \
 122         stw     %r11, FRAME_11+8(%r1);                                  \
 123         stw     %r12, FRAME_12+8(%r1);                                  \
 124         stw     %r13, FRAME_13+8(%r1);                                  \
 125         stw     %r14, FRAME_14+8(%r1);                                  \
 126         stw     %r15, FRAME_15+8(%r1);                                  \
 127         stw     %r16, FRAME_16+8(%r1);                                  \
 128         stw     %r17, FRAME_17+8(%r1);                                  \
 129         stw     %r18, FRAME_18+8(%r1);                                  \
 130         stw     %r19, FRAME_19+8(%r1);                                  \
 131         stw     %r20, FRAME_20+8(%r1);                                  \
 132         stw     %r21, FRAME_21+8(%r1);                                  \
 133         stw     %r22, FRAME_22+8(%r1);                                  \
 134         stw     %r23, FRAME_23+8(%r1);                                  \
 135         stw     %r24, FRAME_24+8(%r1);                                  \
 136         stw     %r25, FRAME_25+8(%r1);                                  \
 137         stw     %r26, FRAME_26+8(%r1);                                  \
 138         stw     %r27, FRAME_27+8(%r1);                                  \
 139         stw     %r28, FRAME_28+8(%r1);                                  \
 140         stw     %r29, FRAME_29+8(%r1);                                  \
 141         stw     %r30, FRAME_30+8(%r1);                                  \
 142         stw     %r31, FRAME_31+8(%r1);                                  \
 143         lwz     %r28,(savearea+CPUSAVE_AIM_DAR)(%r2);  /* saved DAR */  \
 144         lwz     %r29,(savearea+CPUSAVE_AIM_DSISR)(%r2);/* saved DSISR */\
 145         lwz     %r30,(savearea+CPUSAVE_SRR0)(%r2); /* saved SRR0 */     \
 146         lwz     %r31,(savearea+CPUSAVE_SRR1)(%r2); /* saved SRR1 */     \
 147         mfxer   %r3;                                                    \
 148         mfctr   %r4;                                                    \
 149         mfsprg3 %r5;                                                    \
 150         stw     %r3, FRAME_XER+8(1);    /* save xer/ctr/exc */          \
 151         stw     %r4, FRAME_CTR+8(1);                                    \
 152         stw     %r5, FRAME_EXC+8(1);                                    \
 153         stw     %r28,FRAME_AIM_DAR+8(1);                                \
 154         stw     %r29,FRAME_AIM_DSISR+8(1); /* save dsisr/srr0/srr1 */   \
 155         stw     %r30,FRAME_SRR0+8(1);                                   \
 156         stw     %r31,FRAME_SRR1+8(1)
 157
 158 #define FRAME_LEAVE(savearea)                                           \
 159 /* Now restore regs: */                                                 \
 160         lwz     %r2,FRAME_SRR0+8(%r1);                                  \
 161         lwz     %r3,FRAME_SRR1+8(%r1);                                  \
 162         lwz     %r4,FRAME_CTR+8(%r1);                                   \
 163         lwz     %r5,FRAME_XER+8(%r1);                                   \
 164         lwz     %r6,FRAME_LR+8(%r1);                                    \
 165         GET_CPUINFO(%r7);                                               \
 166         stw     %r2,(savearea+CPUSAVE_SRR0)(%r7); /* save SRR0 */       \
 167         stw     %r3,(savearea+CPUSAVE_SRR1)(%r7); /* save SRR1 */       \
 168         lwz     %r7,FRAME_CR+8(%r1);                                    \
 169         mtctr   %r4;                                                    \
 170         mtxer   %r5;                                                    \
 171         mtlr    %r6;                                                    \
 172         mtsprg1 %r7;                    /* save cr */                   \
 173         lwz     %r31,FRAME_31+8(%r1);   /* restore r0-31 */             \
 174         lwz     %r30,FRAME_30+8(%r1);                                   \
 175         lwz     %r29,FRAME_29+8(%r1);                                   \
 176         lwz     %r28,FRAME_28+8(%r1);                                   \
 177         lwz     %r27,FRAME_27+8(%r1);                                   \
 178         lwz     %r26,FRAME_26+8(%r1);                                   \
 179         lwz     %r25,FRAME_25+8(%r1);                                   \
 180         lwz     %r24,FRAME_24+8(%r1);                                   \
 181         lwz     %r23,FRAME_23+8(%r1);                                   \
 182         lwz     %r22,FRAME_22+8(%r1);                                   \
 183         lwz     %r21,FRAME_21+8(%r1);                                   \
 184         lwz     %r20,FRAME_20+8(%r1);                                   \
 185         lwz     %r19,FRAME_19+8(%r1);                                   \
 186         lwz     %r18,FRAME_18+8(%r1);                                   \
 187         lwz     %r17,FRAME_17+8(%r1);                                   \
 188         lwz     %r16,FRAME_16+8(%r1);                                   \
 189         lwz     %r15,FRAME_15+8(%r1);                                   \
 190         lwz     %r14,FRAME_14+8(%r1);                                   \
 191         lwz     %r13,FRAME_13+8(%r1);                                   \
 192         lwz     %r12,FRAME_12+8(%r1);                                   \
 193         lwz     %r11,FRAME_11+8(%r1);                                   \
 194         lwz     %r10,FRAME_10+8(%r1);                                   \
 195         lwz     %r9, FRAME_9+8(%r1);                                    \
 196         lwz     %r8, FRAME_8+8(%r1);                                    \
 197         lwz     %r7, FRAME_7+8(%r1);                                    \
 198         lwz     %r6, FRAME_6+8(%r1);                                    \
 199         lwz     %r5, FRAME_5+8(%r1);                                    \
 200         lwz     %r4, FRAME_4+8(%r1);                                    \
 201         lwz     %r3, FRAME_3+8(%r1);                                    \
 202         lwz     %r2, FRAME_2+8(%r1);                                    \
 203         lwz     %r0, FRAME_0+8(%r1);                                    \
 204         lwz     %r1, FRAME_1+8(%r1);                                    \
 205 /* Can't touch %r1 from here on */                                      \
 206         mtsprg2 %r2;                    /* save r2 & r3 */              \
 207         mtsprg3 %r3;                                                    \
 208 /* Disable translation, machine check and recoverability: */            \
 209         mfmsr   %r2;                                                    \
 210         andi.   %r2,%r2,~(PSL_DR|PSL_IR|PSL_EE|PSL_ME|PSL_RI)@l;        \
 211         mtmsr   %r2;                                                    \
 212         isync;                                                          \
 213 /* Decide whether we return to user mode: */                            \
 214         GET_CPUINFO(%r2);                                               \
 215         lwz     %r3,(savearea+CPUSAVE_SRR1)(%r2);                       \
 216         mtcr    %r3;                                                    \
 217         bf      17,1f;                  /* branch if PSL_PR is false */ \
 218 /* Restore user SRs */                                                  \
 219         RESTORE_USER_SRS(%r2,%r3);                                      \
 220 1:      mfsprg1 %r2;                    /* restore cr */                \
 221         mtcr    %r2;                                                    \
 222         GET_CPUINFO(%r2);                                               \
 223         lwz     %r3,(savearea+CPUSAVE_SRR0)(%r2); /* restore srr0 */    \
 224         mtsrr0  %r3;                                                    \
 225         lwz     %r3,(savearea+CPUSAVE_SRR1)(%r2); /* restore srr1 */    \
 226                                                                         \
 227         /* Make sure HV bit of MSR propagated to SRR1 */                \
 228         mfmsr   %r2;                                                    \
 229         or      %r3,%r2,%r3;                                            \
 230                                                                         \
 231         mtsrr1  %r3;                                                    \
 232         mfsprg2 %r2;                    /* restore r2 & r3 */           \
 233         mfsprg3 %r3
 234
 235 /*
 236  * The next two routines are 64-bit glue code. The first is used to test if
 237  * we are on a 64-bit system. By copying it to the illegal instruction
 238  * handler, we can test for 64-bit mode by trying to execute a 64-bit
 239  * instruction and seeing what happens. The second gets copied in front
 240  * of all the other handlers to restore 32-bit bridge mode when traps
 241  * are taken.
 242  */
 243
 244 /* 64-bit test code. Sets SPRG2 to 0 if an illegal instruction is executed */
 245
 246         .globl  CNAME(testppc64),CNAME(testppc64size)
 247 CNAME(testppc64):
 248         mtsprg1 %r31
 249         mfsrr0  %r31
 250         addi    %r31, %r31, 4
 251         mtsrr0  %r31
 252
 253         li      %r31, 0
 254         mtsprg2 %r31
 255         mfsprg1 %r31
 256
 257         rfi
 258 CNAME(testppc64size) = .-CNAME(testppc64)
 259
 260
 261 /* 64-bit bridge mode restore snippet. Gets copied in front of everything else
 262  * on 64-bit systems. */
 263
 264         .globl  CNAME(restorebridge),CNAME(restorebridgesize)
 265 CNAME(restorebridge):
 266         mtsprg1 %r31
 267         mfmsr   %r31
 268         clrldi  %r31,%r31,1
 269         mtmsrd  %r31
 270         mfsprg1 %r31
 271         isync
 272 CNAME(restorebridgesize) = .-CNAME(restorebridge)
 273
 274 #ifdef SMP
 275 /*
 276  * Processor reset exception handler. These are typically
 277  * the first instructions the processor executes after a
 278  * software reset. We do this in two bits so that we are
 279  * not still hanging around in the trap handling region
 280  * once the MMU is turned on.
 281  */
 282         .globl  CNAME(rstcode), CNAME(rstsize)
 283 CNAME(rstcode):
 284         ba      cpu_reset
 285 CNAME(rstsize) = . - CNAME(rstcode)
 286
 287 cpu_reset:
 288         bl      1f
 289
 290         .space  124
 291
 292 1:
 293         mflr    %r1
 294         addi    %r1,%r1,(124-16)@l
 295
 296         lis     %r3,1@l
 297         bla     CNAME(pmap_cpu_bootstrap)
 298         bla     CNAME(cpudep_ap_bootstrap)
 299         mr      %r1,%r3
 300         bla     CNAME(machdep_ap_bootstrap)
 301
 302         /* Should not be reached */
 303 9:
 304         b       9b
 305 #endif
 306
 307 /*
 308  * This code gets copied to all the trap vectors
 309  * (except ISI/DSI, ALI, and the interrupts)
 310  */
 311
 312         .globl  CNAME(trapcode),CNAME(trapsize)
 313 CNAME(trapcode):
 314         mtsprg1 %r1                     /* save SP */
 315         mflr    %r1                     /* Save the old LR in r1 */
 316         mtsprg2 %r1                     /* And then in SPRG2 */
 317         li      %r1, 0x20               /* How to get the vector from LR */
 318         bla     generictrap             /* LR & SPRG3 is exception # */
 319 CNAME(trapsize) = .-CNAME(trapcode)
 320
 321 /*
 322  * 64-bit version of trapcode. Identical, except it calls generictrap64.
 323  */
 324         .globl  CNAME(trapcode64)
 325 CNAME(trapcode64):
 326         mtsprg1 %r1                     /* save SP */
 327         mflr    %r1                     /* Save the old LR in r1 */
 328         mtsprg2 %r1                     /* And then in SPRG2 */
 329         li      %r1, 0x20               /* How to get the vector from LR */
 330         bla     generictrap64           /* LR & SPRG3 is exception # */
 331
 332 /*
 333  * For ALI: has to save DSISR and DAR
 334  */
 335         .globl  CNAME(alitrap),CNAME(alisize)
 336 CNAME(alitrap):
 337         mtsprg1 %r1                     /* save SP */
 338         GET_CPUINFO(%r1)
 339         stw     %r28,(PC_TEMPSAVE+CPUSAVE_R28)(%r1)     /* free r28-r31 */
 340         stw     %r29,(PC_TEMPSAVE+CPUSAVE_R29)(%r1)
 341         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R30)(%r1)
 342         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R31)(%r1)
 343         mfdar   %r30
 344         mfdsisr %r31
 345         stw     %r30,(PC_TEMPSAVE+CPUSAVE_AIM_DAR)(%r1)
 346         stw     %r31,(PC_TEMPSAVE+CPUSAVE_AIM_DSISR)(%r1)
 347         mfsprg1 %r1                     /* restore SP, in case of branch */
 348         mflr    %r28                    /* save LR */
 349         mfcr    %r29                    /* save CR */
 350
 351         /* Put our exception vector in SPRG3 */
 352         li      %r31, EXC_ALI
 353         mtsprg3 %r31
 354
 355         /* Test whether we already had PR set */
 356         mfsrr1  %r31
 357         mtcr    %r31
 358         bla     s_trap
 359 CNAME(alisize) = .-CNAME(alitrap)
 360
 361 /*
 362  * Similar to the above for DSI
 363  * Has to handle BAT spills
 364  * and standard pagetable spills
 365  */
 366         .globl  CNAME(dsitrap),CNAME(dsisize)
 367 CNAME(dsitrap):
 368         mtsprg1 %r1                     /* save SP */
 369         GET_CPUINFO(%r1)
 370         stw     %r28,(PC_DISISAVE+CPUSAVE_R28)(%r1)     /* free r28-r31 */
 371         stw     %r29,(PC_DISISAVE+CPUSAVE_R29)(%r1)
 372         stw     %r30,(PC_DISISAVE+CPUSAVE_R30)(%r1)
 373         stw     %r31,(PC_DISISAVE+CPUSAVE_R31)(%r1)
 374         mfsprg1 %r1                     /* restore SP */
 375         mfcr    %r29                    /* save CR */
 376         mfxer   %r30                    /* save XER */
 377         mtsprg2 %r30                    /* in SPRG2 */
 378         mfsrr1  %r31                    /* test kernel mode */
 379         mtcr    %r31
 380         bt      17,1f                   /* branch if PSL_PR is set */
 381         mfdar   %r31                    /* get fault address */
 382         rlwinm  %r31,%r31,7,25,28       /* get segment * 8 */
 383
 384         /* get batu */
 385         addis   %r31,%r31,CNAME(battable)@ha
 386         lwz     %r30,CNAME(battable)@l(31)
 387         mtcr    %r30
 388         bf      30,1f                   /* branch if supervisor valid is
 389                                            false */
 390         /* get batl */
 391         lwz     %r31,CNAME(battable)+4@l(31)
 392 /* We randomly use the highest two bat registers here */
 393         mftb    %r28
 394         andi.   %r28,%r28,1
 395         bne     2f
 396         mtdbatu 2,%r30
 397         mtdbatl 2,%r31
 398         b       3f
 399 2:
 400         mtdbatu 3,%r30
 401         mtdbatl 3,%r31
 402 3:
 403         mfsprg2 %r30                    /* restore XER */
 404         mtxer   %r30
 405         mtcr    %r29                    /* restore CR */
 406         mtsprg1 %r1
 407         GET_CPUINFO(%r1)
 408         lwz     %r28,(PC_DISISAVE+CPUSAVE_R28)(%r1)     /* restore r28-r31 */
 409         lwz     %r29,(PC_DISISAVE+CPUSAVE_R29)(%r1)
 410         lwz     %r30,(PC_DISISAVE+CPUSAVE_R30)(%r1)
 411         lwz     %r31,(PC_DISISAVE+CPUSAVE_R31)(%r1)
 412         mfsprg1 %r1
 413         rfi                             /* return to trapped code */
 414 1:
 415         mflr    %r28                    /* save LR (SP already saved) */
 416         bla     disitrap
 417 CNAME(dsisize) = .-CNAME(dsitrap)
 418
 419 /*
 420  * Preamble code for DSI/ISI traps
 421  */
 422 disitrap:
 423         /* Write the trap vector to SPRG3 by computing LR & 0xff00 */
 424         mflr    %r1
 425         andi.   %r1,%r1,0xff00
 426         mtsprg3 %r1
 427
 428         GET_CPUINFO(%r1)
 429         lwz     %r30,(PC_DISISAVE+CPUSAVE_R28)(%r1)
 430         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R28)(%r1)
 431         lwz     %r31,(PC_DISISAVE+CPUSAVE_R29)(%r1)
 432         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R29)(%r1)
 433         lwz     %r30,(PC_DISISAVE+CPUSAVE_R30)(%r1)
 434         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R30)(%r1)
 435         lwz     %r31,(PC_DISISAVE+CPUSAVE_R31)(%r1)
 436         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R31)(%r1)
 437         mfdar   %r30
 438         mfdsisr %r31
 439         stw     %r30,(PC_TEMPSAVE+CPUSAVE_AIM_DAR)(%r1)
 440         stw     %r31,(PC_TEMPSAVE+CPUSAVE_AIM_DSISR)(%r1)
 441
 442 #ifdef KDB
 443         /* Try and detect a kernel stack overflow */
 444         mfsrr1  %r31
 445         mtcr    %r31
 446         bt      17,realtrap             /* branch is user mode */
 447         mfsprg1 %r31                    /* get old SP */
 448         sub.    %r30,%r31,%r30          /* SP - DAR */
 449         bge     1f
 450         neg     %r30,%r30               /* modulo value */
 451 1:      cmplwi  %cr0,%r30,4096          /* is DAR within a page of SP? */
 452         bge     %cr0,realtrap           /* no, too far away. */
 453
 454         /* Now convert this DSI into a DDB trap.  */
 455         GET_CPUINFO(%r1)
 456         lwz     %r30,(PC_TEMPSAVE+CPUSAVE_AIM_DAR)(%r1) /* get DAR */
 457         stw     %r30,(PC_DBSAVE  +CPUSAVE_AIM_DAR)(%r1) /* save DAR */
 458         lwz     %r30,(PC_TEMPSAVE+CPUSAVE_AIM_DSISR)(%r1) /* get DSISR */
 459         stw     %r30,(PC_DBSAVE  +CPUSAVE_AIM_DSISR)(%r1) /* save DSISR */
 460         lwz     %r30,(PC_DISISAVE+CPUSAVE_R28)(%r1) /* get  r28 */
 461         stw     %r30,(PC_DBSAVE  +CPUSAVE_R28)(%r1) /* save r28 */
 462         lwz     %r31,(PC_DISISAVE+CPUSAVE_R29)(%r1) /* get  r29 */
 463         stw     %r31,(PC_DBSAVE  +CPUSAVE_R29)(%r1) /* save r29 */
 464         lwz     %r30,(PC_DISISAVE+CPUSAVE_R30)(%r1) /* get  r30 */
 465         stw     %r30,(PC_DBSAVE  +CPUSAVE_R30)(%r1) /* save r30 */
 466         lwz     %r31,(PC_DISISAVE+CPUSAVE_R31)(%r1) /* get  r31 */
 467         stw     %r31,(PC_DBSAVE  +CPUSAVE_R31)(%r1) /* save r31 */
 468         b       dbtrap
 469 #endif
 470
 471         /* XXX need stack probe here */
 472 realtrap:
 473 /* Test whether we already had PR set */
 474         mfsrr1  %r1
 475         mtcr    %r1
 476         mfsprg1 %r1                     /* restore SP (might have been
 477                                            overwritten) */
 478         bf      17,k_trap               /* branch if PSL_PR is false */
 479         GET_CPUINFO(%r1)
 480         lwz     %r1,PC_CURPCB(%r1)
 481         RESTORE_KERN_SRS(%r30,%r31)     /* enable kernel mapping */
 482         ba s_trap
 483
 484 /*
 485  * generictrap does some standard setup for trap handling to minimize
 486  * the code that need be installed in the actual vectors. It expects
 487  * the following conditions.
 488  *
 489  * R1 - Trap vector = LR & (0xff00 | R1)
 490  * SPRG1 - Original R1 contents
 491  * SPRG2 - Original LR
 492  */
 493
 494 generictrap64:
 495         mtsprg3 %r31
 496         mfmsr   %r31
 497         clrldi  %r31,%r31,1
 498         mtmsrd  %r31
 499         mfsprg3 %r31
 500         isync
 501
 502 generictrap:
 503         /* Save R1 for computing the exception vector */
 504         mtsprg3 %r1
 505
 506         /* Save interesting registers */
 507         GET_CPUINFO(%r1)
 508         stw     %r28,(PC_TEMPSAVE+CPUSAVE_R28)(%r1)     /* free r28-r31 */
 509         stw     %r29,(PC_TEMPSAVE+CPUSAVE_R29)(%r1)
 510         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R30)(%r1)
 511         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R31)(%r1)
 512         mfsprg1 %r1                     /* restore SP, in case of branch */
 513         mfsprg2 %r28                    /* save LR */
 514         mfcr    %r29                    /* save CR */
 515
 516         /* Compute the exception vector from the link register */
 517         mfsprg3 %r31
 518         ori     %r31,%r31,0xff00
 519         mflr    %r30
 520         and     %r30,%r30,%r31
 521         mtsprg3 %r30
 522
 523         /* Test whether we already had PR set */
 524         mfsrr1  %r31
 525         mtcr    %r31
 526
 527 s_trap:
 528         bf      17,k_trap               /* branch if PSL_PR is false */
 529         GET_CPUINFO(%r1)
 530 u_trap:
 531         lwz     %r1,PC_CURPCB(%r1)
 532         RESTORE_KERN_SRS(%r30,%r31)     /* enable kernel mapping */
 533
 534 /*
 535  * Now the common trap catching code.
 536  */
 537 k_trap:
 538         FRAME_SETUP(PC_TEMPSAVE)
 539 /* Call C interrupt dispatcher: */
 540 trapagain:
 541         addi    %r3,%r1,8
 542         bl      CNAME(powerpc_interrupt)
 543         .globl  CNAME(trapexit)         /* backtrace code sentinel */
 544 CNAME(trapexit):
 545
 546 /* Disable interrupts: */
 547         mfmsr   %r3
 548         andi.   %r3,%r3,~PSL_EE@l
 549         mtmsr   %r3
 550 /* Test AST pending: */
 551         lwz     %r5,FRAME_SRR1+8(%r1)
 552         mtcr    %r5
 553         bf      17,1f                   /* branch if PSL_PR is false */
 554
 555         GET_CPUINFO(%r3)                /* get per-CPU pointer */
 556         lwz     %r4, PC_CURTHREAD(%r3)  /* deref to get curthread */
 557         lwz     %r4, TD_FLAGS(%r4)      /* get thread flags value */
 558         lis     %r5, (TDF_ASTPENDING|TDF_NEEDRESCHED)@h
 559         ori     %r5,%r5, (TDF_ASTPENDING|TDF_NEEDRESCHED)@l
 560         and.    %r4,%r4,%r5
 561         beq     1f
 562         mfmsr   %r3                     /* re-enable interrupts */
 563         ori     %r3,%r3,PSL_EE@l
 564         mtmsr   %r3
 565         isync
 566         addi    %r3,%r1,8
 567         bl      CNAME(ast)
 568         .globl  CNAME(asttrapexit)      /* backtrace code sentinel #2 */
 569 CNAME(asttrapexit):
 570         b       trapexit                /* test ast ret value ? */
 571 1:
 572         FRAME_LEAVE(PC_TEMPSAVE)
 573
 574         .globl  CNAME(rfi_patch1)       /* replace rfi with rfid on ppc64 */
 575 CNAME(rfi_patch1):
 576         rfi
 577
 578         .globl  CNAME(rfid_patch)
 579 CNAME(rfid_patch):
 580         rfid
 581
 582 #if defined(KDB)
 583 /*
 584  * Deliberate entry to dbtrap
 585  */
 586         .globl  CNAME(breakpoint)
 587 CNAME(breakpoint):
 588         mtsprg1 %r1
 589         mfmsr   %r3
 590         mtsrr1  %r3
 591         andi.   %r3,%r3,~(PSL_EE|PSL_ME)@l
 592         mtmsr   %r3                     /* disable interrupts */
 593         isync
 594         GET_CPUINFO(%r3)
 595         stw     %r28,(PC_DBSAVE+CPUSAVE_R28)(%r3)
 596         stw     %r29,(PC_DBSAVE+CPUSAVE_R29)(%r3)
 597         stw     %r30,(PC_DBSAVE+CPUSAVE_R30)(%r3)
 598         stw     %r31,(PC_DBSAVE+CPUSAVE_R31)(%r3)
 599         mflr    %r28
 600         li      %r29,EXC_BPT
 601         mtlr    %r29
 602         mfcr    %r29
 603         mtsrr0  %r28
 604
 605 /*
 606  * Now the kdb trap catching code.
 607  */
 608 dbtrap:
 609         /* Write the trap vector to SPRG3 by computing LR & 0xff00 */
 610         mflr    %r1
 611         andi.   %r1,%r1,0xff00
 612         mtsprg3 %r1
 613
 614         lis     %r1,(tmpstk+TMPSTKSZ-16)@ha     /* get new SP */
 615         addi    %r1,%r1,(tmpstk+TMPSTKSZ-16)@l
 616
 617         FRAME_SETUP(PC_DBSAVE)
 618 /* Call C trap code: */
 619         addi    %r3,%r1,8
 620         bl      CNAME(db_trap_glue)
 621         or.     %r3,%r3,%r3
 622         bne     dbleave
 623 /* This wasn't for KDB, so switch to real trap: */
 624         lwz     %r3,FRAME_EXC+8(%r1)    /* save exception */
 625         GET_CPUINFO(%r4)
 626         stw     %r3,(PC_DBSAVE+CPUSAVE_R31)(%r4)
 627         FRAME_LEAVE(PC_DBSAVE)
 628         mtsprg1 %r1                     /* prepare for entrance to realtrap */
 629         GET_CPUINFO(%r1)
 630         stw     %r28,(PC_TEMPSAVE+CPUSAVE_R28)(%r1)
 631         stw     %r29,(PC_TEMPSAVE+CPUSAVE_R29)(%r1)
 632         stw     %r30,(PC_TEMPSAVE+CPUSAVE_R30)(%r1)
 633         stw     %r31,(PC_TEMPSAVE+CPUSAVE_R31)(%r1)
 634         mflr    %r28
 635         mfcr    %r29
 636         lwz     %r31,(PC_DBSAVE+CPUSAVE_R31)(%r1)
 637         mtsprg3 %r31                    /* SPRG3 was clobbered by FRAME_LEAVE */
 638         mfsprg1 %r1
 639         b       realtrap
 640 dbleave:
 641         FRAME_LEAVE(PC_DBSAVE)
 642         .globl  CNAME(rfi_patch2)       /* replace rfi with rfid on ppc64 */
 643 CNAME(rfi_patch2):
 644         rfi
 645
 646 /*
 647  * In case of KDB we want a separate trap catcher for it
 648  */
 649         .globl  CNAME(dblow),CNAME(dbsize)
 650 CNAME(dblow):
 651         mtsprg1 %r1                     /* save SP */
 652         mtsprg2 %r29                    /* save r29 */
 653         mfcr    %r29                    /* save CR in r29 */
 654         mfsrr1  %r1
 655         mtcr    %r1
 656         bf      17,1f                   /* branch if privileged */
 657
 658         /* Unprivileged case */
 659         mtcr    %r29                    /* put the condition register back */
 660         mfsprg2 %r29                    /* ... and r29 */
 661         mflr    %r1                     /* save LR */
 662         mtsprg2 %r1                     /* And then in SPRG2 */
 663         li      %r1, 0                  /* How to get the vector from LR */
 664
 665         bla     generictrap             /* and we look like a generic trap */
 666 1:
 667         /* Privileged, so drop to KDB */
 668         GET_CPUINFO(%r1)
 669         stw     %r28,(PC_DBSAVE+CPUSAVE_R28)(%r1)       /* free r28 */
 670         mfsprg2 %r28                            /* r29 holds cr...  */
 671         stw     %r28,(PC_DBSAVE+CPUSAVE_R29)(%r1)       /* free r29 */
 672         stw     %r30,(PC_DBSAVE+CPUSAVE_R30)(%r1)       /* free r30 */
 673         stw     %r31,(PC_DBSAVE+CPUSAVE_R31)(%r1)       /* free r31 */
 674         mflr    %r28                                    /* save LR */
 675         bla     dbtrap
 676 CNAME(dbsize) = .-CNAME(dblow)
 677 #endif /* KDB */