usr.sbin/config/lang.l

   1 %{
   2 /*-
   3  * Copyright (c) 1980, 1993
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  * 4. Neither the name of the University nor the names of its contributors
  15  *    may be used to endorse or promote products derived from this software
  16  *    without specific prior written permission.
  17  *
  18  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  19  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  22  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  24  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  25  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  26  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  27  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  28  * SUCH DAMAGE.
  29  *
  30  *      @(#)lang.l      8.1 (Berkeley) 6/6/93
  31  * $FreeBSD$
  32  */
  33
  34 #include <assert.h>
  35 #include <ctype.h>
  36 #include <err.h>
  37 #include <string.h>
  38 #include "y.tab.h"
  39 #include "config.h"
  40
  41 #define YY_NO_UNPUT
  42 #define YY_NO_INPUT
  43
  44 /*
  45  * Data for returning to previous files from include files.
  46  */
  47 struct incl {
  48         struct  incl *in_prev;  /* previous includes in effect, if any */
  49         YY_BUFFER_STATE in_buf; /* previous lex state */
  50         const   char *in_fname; /* previous file name */
  51         int     in_lineno;      /* previous line number */
  52         int     in_ateof;       /* token to insert at EOF */
  53 };
  54 static struct   incl *inclp;
  55 static const    char *lastfile;
  56
  57 /*
  58  * Key word table
  59  */
  60
  61 struct kt {
  62         const char *kt_name;
  63         int kt_val;
  64 } key_words[] = {
  65         { "config",     CONFIG },
  66         { "cpu",        CPU },
  67         { "nocpu",      NOCPU },
  68         { "device",     DEVICE },
  69         { "devices",    DEVICE },
  70         { "nodevice",   NODEVICE },
  71         { "nodevices",  NODEVICE },
  72         { "env",        ENV },
  73         { "hints",      HINTS },
  74         { "ident",      IDENT },
  75         { "machine",    ARCH }, /* MACHINE is defined in /sys/param.h */
  76         { "makeoption", MAKEOPTIONS },
  77         { "makeoptions", MAKEOPTIONS },
  78         { "nomakeoption", NOMAKEOPTION },
  79         { "nomakeoptions", NOMAKEOPTION },
  80         { "maxusers",   MAXUSERS },
  81         { "profile",    PROFILE },
  82         { "option",     OPTIONS },
  83         { "options",    OPTIONS },
  84         { "nooption",   NOOPTION },
  85         { "nooptions",  NOOPTION },
  86         { "include",    INCLUDE },
  87         { "files",      FILES },
  88         { 0, 0 },
  89 };
  90
  91
  92 static int endinclude(void);
  93 int include(const char *, int);
  94 int kw_lookup(char *);
  95 unsigned int octal(const char *);
  96 unsigned int hex(const char *);
  97 int yyerror(const char *);
  98
  99 %}
 100 ID      [A-Za-z_][-A-Za-z_0-9]*
 101 PATH    [./][-/.%^A-Za-z_0-9]+
 102 %START TOEOL
 103 %%
 104 {ID}            {
 105                         int i;
 106
 107                         BEGIN 0;
 108                         if ((i = kw_lookup(yytext)) == -1)
 109                         {
 110                                 yylval.str = strdup(yytext);
 111                                 return ID;
 112                         }
 113                         return i;
 114                 }
 115 \\\"[^"]+\\\"   {
 116                         BEGIN 0;
 117                         yytext[yyleng-2] = '"';
 118                         yytext[yyleng-1] = '\0';
 119                         yylval.str = strdup(yytext + 1);
 120                         return ID;
 121                 }
 122 \"[^"]+\"       {
 123                         BEGIN 0;
 124                         yytext[yyleng-1] = '\0';
 125                         yylval.str = strdup(yytext + 1);
 126                         return ID;
 127                 }
 128 <TOEOL>[^# \t\n]*       {
 129                         BEGIN 0;
 130                         yylval.str = strdup(yytext);
 131                         return ID;
 132                 }
 133 0[0-7]*         {
 134                         yylval.val = octal(yytext);
 135                         return NUMBER;
 136                 }
 137 0x[0-9a-fA-F]+  {
 138                         yylval.val = hex(yytext);
 139                         return NUMBER;
 140                 }
 141 -?[1-9][0-9]*   {
 142                         yylval.val = atoi(yytext);
 143                         return NUMBER;
 144                 }
 145 "?"             {
 146                         yylval.val = -1;
 147                         return NUMBER;
 148                 }
 149 \n/[ \t]        {
 150                         yyline++;
 151                 }
 152 \n              {
 153                         yyline++;
 154                         return SEMICOLON;
 155                 }
 156 #.*             {       /* Ignored (comment) */;        }
 157 [ \t\f]*        {       /* Ignored (white space) */;    }
 158 ";"             {       return SEMICOLON;               }
 159 ","             {       return COMMA;                   }
 160 "="             {       BEGIN TOEOL; return EQUALS;     }
 161 "+="            {       BEGIN TOEOL; return PLUSEQUALS; }
 162 <<EOF>>         {
 163                         int tok;
 164
 165                         if (inclp == NULL)
 166                                 return YY_NULL;
 167                         tok = endinclude();
 168                         if (tok != 0)
 169                                 return tok;
 170                         /* otherwise continue scanning */
 171                 }
 172 {PATH}          {
 173                         BEGIN 0;
 174                         yylval.str = strdup(yytext);
 175                         return PATH;
 176                 }
 177 .               {       return yytext[0];               }
 178
 179 %%
 180 /*
 181  * kw_lookup
 182  *      Look up a string in the keyword table.  Returns a -1 if the
 183  *      string is not a keyword otherwise it returns the keyword number
 184  */
 185
 186 int
 187 kw_lookup(char *word)
 188 {
 189         struct kt *kp;
 190
 191         for (kp = key_words; kp->kt_name != 0; kp++)
 192                 if (eq(word, kp->kt_name))
 193                         return kp->kt_val;
 194         return -1;
 195 }
 196
 197 /*
 198  * Number conversion routines
 199  */
 200
 201 unsigned int
 202 octal(const char *str)
 203 {
 204         unsigned int num;
 205
 206         (void) sscanf(str, "%o", &num);
 207         return num;
 208 }
 209
 210 unsigned int
 211 hex(const char *str)
 212 {
 213         unsigned int num;
 214
 215         (void) sscanf(str+2, "%x", &num);
 216         return num;
 217 }
 218
 219 void
 220 cfgfile_add(const char *fname)
 221 {
 222         struct cfgfile *cf;
 223
 224         cf = calloc(1, sizeof(*cf));
 225         if (cf == NULL)
 226                 err(EXIT_FAILURE, "calloc");
 227         assert(cf != NULL);
 228         asprintf(&cf->cfg_path, "%s", fname);
 229         STAILQ_INSERT_TAIL(&cfgfiles, cf, cfg_next);
 230 }
 231
 232 void
 233 cfgfile_removeall(void)
 234 {
 235         struct cfgfile *cf;
 236
 237         while (!STAILQ_EMPTY(&cfgfiles)) {
 238                 cf = STAILQ_FIRST(&cfgfiles);
 239                 STAILQ_REMOVE_HEAD(&cfgfiles, cfg_next);
 240                 if (cf->cfg_path != NULL)
 241                         free(cf->cfg_path);
 242                 free(cf);
 243         }
 244 }
 245
 246 /*
 247  * Open the named file for inclusion at the current point.  Returns 0 on
 248  * success (file opened and previous state pushed), nonzero on failure
 249  * (fopen failed, complaint made).  The `ateof' parameter controls the
 250  * token to be inserted at the end of the include file. If ateof == 0,
 251  * then nothing is inserted.
 252  */
 253 int
 254 include(const char *fname, int ateof)
 255 {
 256         FILE *fp;
 257         struct incl *in;
 258         char *fnamebuf;
 259
 260         fnamebuf = NULL;
 261         fp = fopen(fname, "r");
 262         if (fp == NULL && fname[0] != '.' && fname[0] != '/') {
 263                 asprintf(&fnamebuf, "../../conf/%s", fname);
 264                 if (fnamebuf != NULL) {
 265                         fp = fopen(fnamebuf, "r");
 266                         free(fnamebuf);
 267                 }
 268         }
 269         if (fp == NULL) {
 270                 yyerror("cannot open included file");
 271                 return (-1);
 272         }
 273         cfgfile_add(fnamebuf == NULL ? fname : fnamebuf);
 274         in = malloc(sizeof(*in));
 275         assert(in != NULL);
 276         in->in_prev = inclp;
 277         in->in_buf = YY_CURRENT_BUFFER;
 278         in->in_fname = yyfile;
 279         in->in_lineno = yyline;
 280         in->in_ateof = ateof;
 281         inclp = in;
 282         yy_switch_to_buffer(yy_create_buffer(fp, YY_BUF_SIZE));
 283         yyfile = fname;
 284         yyline = 0;
 285         return (0);
 286 }
 287
 288 /*
 289  * Terminate the most recent inclusion.
 290  */
 291 static int
 292 endinclude(void)
 293 {
 294         struct incl *in;
 295         int ateof;
 296
 297         in = inclp;
 298         assert(in != NULL);
 299         inclp = in->in_prev;
 300         lastfile = yyfile;
 301         yy_delete_buffer(YY_CURRENT_BUFFER);
 302         (void)fclose(yyin);
 303         yy_switch_to_buffer(in->in_buf);
 304         yyfile = in->in_fname;
 305         yyline = in->in_lineno;
 306         ateof  = in->in_ateof;
 307         free(in);
 308
 309         return (ateof);
 310 }