contrib/compiler-rt/lib/arm/modsi3.S

   1 /*===-- modsi3.S - 32-bit signed integer modulus --------------------------===//
   2  *
   3  *                     The LLVM Compiler Infrastructure
   4  *
   5  * This file is dual licensed under the MIT and the University of Illinois Open
   6  * Source Licenses. See LICENSE.TXT for details.
   7  *
   8  *===----------------------------------------------------------------------===//
   9  *
  10  * This file implements the __modsi3 (32-bit signed integer modulus) function
  11  * for the ARM architecture as a wrapper around the unsigned routine.
  12  *
  13  *===----------------------------------------------------------------------===*/
  14
  15 #include "../assembly.h"
  16
  17 #define ESTABLISH_FRAME \
  18     push   {r4, r7, lr}    ;\
  19     add     r7,     sp, #4
  20 #define CLEAR_FRAME_AND_RETURN \
  21     pop    {r4, r7, pc}
  22
  23 .syntax unified
  24 .align 3
  25 DEFINE_COMPILERRT_FUNCTION(__modsi3)
  26     ESTABLISH_FRAME
  27     //  Set aside the sign of the dividend.
  28     mov     r4,     r0
  29     //  Take absolute value of a and b via abs(x) = (x^(x >> 31)) - (x >> 31).
  30     eor     r2,     r0, r0, asr #31
  31     eor     r3,     r1, r1, asr #31
  32     sub     r0,     r2, r0, asr #31
  33     sub     r1,     r3, r1, asr #31
  34     //  abs(a) % abs(b)
  35     bl     SYMBOL_NAME(__umodsi3)
  36     //  Apply sign of dividend to result and return.
  37     eor     r0,     r0, r4, asr #31
  38     sub     r0,     r0, r4, asr #31
  39     CLEAR_FRAME_AND_RETURN